Calling the ASP page through a BSP application

Question

Hi,
We are in the process of implementing Digital signature for SRM cFolders.
BSP application : CFX_RFC_UI
Pages with flow logic : doc_de_download
The digitally signed files are uploaded to the cFolders.On click of a
particular file in cFolders, the 'ASP' page residing on the server in IIS
vertual directory i.e. 'verifyfile.asp' should get called.This ASP page has
the logic to verify the signed file.
The signed file resides on the file system in the same vertual directory.
As a result we want to post a message on the screen which
will be the output of the ASP page logic.
Please suggest the way to achieve this.
Regards,
Nilesh
Message : ---
<b>Verification Successful</b>
  Certificate Details
The certificate is valid
CRL Status: Certificate Revocation Status is Unknown: CRL Not checked
Email Id: [email protected]
Issuer Name: ock Demo Certification Authority
Serial Number: 15 65 7a 0a  00 00 0d d9
Subject Name: Email Address = [email protected] | Country = US
| StateOrProvince = VA | Locality = McLean | Organization = Technologies Corporation | Organizational Unit = ock Demo | Common Name = Valid ock |
ThumbPrint: 16 00 c1 f4 76 aa 57 f2 20 27 0f 21 44 9e 08 9d 61 ca dd 95
Valid From: Monday, April 10 2006,02:19:58
<i><b>The code in OnInitialization event handler is as follows :----</b></i>
* doc_de_download.htm
DATA lp_root_exception   TYPE REF TO cx_root.
DATA lp_doc              TYPE REF TO cl_cfx_document.
DATA l_cur_ver_id        TYPE guid_32.
DATA lp_col_app          TYPE REF TO cl_cfx_col_application.
DATA lp_col              TYPE REF TO cl_cfx_collaboration.
DATA : icontent type table of  sdokcntbin.
data :  w_tmpcontent TYPE sdokcntbin.
**** Data declaration
data : g_folder_path TYPE btcxpgpar value 'usrsapDigitally signed files',
      g_md(100)      TYPE c,
      g_file_path    TYPE string,
      g_system       TYPE rfcdisplay-rfchost,
      g_os           TYPE sxpgcolist-opsystem,
      g_file_size    TYPE string,
      g_mime_type    TYPE string,
      g_file_ext     TYPE string,
      g_len1         TYPE i,
      g_var          TYPE c,
      g_out_file     TYPE c LENGTH 600,
      g_file_count   TYPE p,
      g_table_lines  TYPE p,
      g_counter      TYPE p VALUE 1,
      g_flag         TYPE c.
DATA : i_doc_id TYPE sysuuid_c.
CONSTANTS : c_dot TYPE c VALUE '.'.
TRY.
    IF NOT p_refresh IS INITIAL.
      cl_cfx_ui_application=>delete_instance( ).
    ENDIF.
    TRANSLATE p_col_id TO UPPER CASE. "Just in case...
    TRANSLATE p_area_id TO UPPER CASE. "Just in case...
    TRANSLATE p_topic_id TO UPPER CASE. "Just in case...
    TRANSLATE p_doc_id TO UPPER CASE. "Just in case...
    TRANSLATE p_ver_id TO UPPER CASE. "Just in case...
    TRANSLATE p_save TO UPPER CASE. "Just in case...
*   initialize in case of server state timeout
    IF ( NOT p_col_id IS INITIAL ) AND
       ( NOT p_area_id IS INITIAL ) AND
       ( NOT p_topic_id IS INITIAL ).
      CALL METHOD cl_cfx_context_ui=>initialize
        EXPORTING
          i_col_id      = p_col_id
          i_area_id     = p_area_id
          i_topic_id    = p_topic_id
          i_doc_id      = p_doc_id
          i_object_type = cfxf1_sc_doc_type_document.
    ENDIF.
    IF NOT p_col_id IS INITIAL.
      lp_col_app = cl_cfx_col_application=>get_instance( ).
      lp_col = lp_col_app->get_collaboration( p_col_id ).
    ENDIF.
*   Do we need to prepare to checkout this document?
    cl_cfx_doc_ui=>get_docref_safe(
      EXPORTING
        i_guid        = p_doc_id
      IMPORTING
        ep_docref     = lp_doc ).
    IF ( NOT p_filepath IS INITIAL ) AND ( p_do_lock = 'X' ).
      l_cur_ver_id = lp_doc->if_cfx_versioning~get_current_version( ).
      IF l_cur_ver_id = p_ver_id.
*       OK, prepare checkout
        TRY.
            lp_doc->if_cfx_document~lock( ).
          CATCH cx_root.
        ENDTRY.
      ENDIF.
    ENDIF.
data: lt_formfields type TIHTTPNVP,
      l_formfield   type IHTTPNVP,
      l_request     type STRING.
data: lt_headerfields type TIHTTPNVP,
      l_headerfield   type IHTTPNVP.
CALL METHOD request->get_form_fields
  CHANGING
    fields = lt_formfields.
CALL METHOD request->get_header_fields
  CHANGING
    fields = lt_headerfields.
*    CALL METHOD cl_cfx_doc_ui=>retrieve_content
*      EXPORTING
*        ip_navigation = navigation
*        ip_response   = response
*        ip_runtime    = runtime
*        i_col_id      = p_col_id
*        i_area_id     = p_area_id
*        i_topic_id    = p_topic_id
*        i_doc_id      = p_doc_id
*        i_ver_id      = p_ver_id
*        i_save        = p_save.
*   Do we need to checkout this document?
    cl_cfx_doc_ui=>get_docref_safe(
      EXPORTING
        i_guid        = p_doc_id
      IMPORTING
        ep_docref     = lp_doc ).
    IF ( NOT p_filepath IS INITIAL ) AND ( p_do_lock = 'X' ).
*      l_cur_ver_id = lp_doc->if_cfx_versioning~get_current_version( ).
      IF l_cur_ver_id = p_ver_id.
*       OK, do checkout
        TRY.
            CALL METHOD cl_cfx_doc_ui=>mark_doc_as_checked_out
              EXPORTING
                ip_doc     = lp_doc
                i_filepath = p_filepath.
          CATCH cx_root.
        ENDTRY.
      ENDIF.
    ENDIF.
i_doc_id = p_ver_id.
CALL FUNCTION 'CFX_API_DOC_DOCUMENT_READ'
Exporting
    i_doc_version_id = i_doc_id
  IMPORTING
    e_file_path      = g_file_path
    e_file_size      = g_file_size
    e_mime_type      = g_mime_type
    e_file_ext       = g_file_ext
  TABLES
    et_content       = icontent.
******  Download document
IF NOT icontent[] IS INITIAL.
***  PERFORM sub_download_file USING g_file_path.
  CONCATENATE g_folder_path g_file_path
  INTO g_out_file.
  OPEN DATASET g_out_file FOR OUTPUT IN BINARY MODE.
  IF sy-subrc = 0.
    LOOP AT icontent INTO w_tmpcontent.
      TRANSFER w_tmpcontent TO g_out_file.
    ENDLOOP.
  ENDIF.
  CLOSE DATASET g_out_file.
  CLEAR g_out_file.
ENDIF.
    CLEAR: p_area_id, p_col_id, p_doc_id, p_save,
           p_topic_id, p_ver_id, p_filepath.
** handle other standard exceptions
  CATCH cx_root INTO lp_root_exception.
    CALL METHOD cl_cfx_exception_ui=>handle
      EXPORTING
        ip_exception  = lp_root_exception
        ip_navigation = navigation.
ENDTRY.

Answer 1

Hi,
Something like this should work:
REPORT  zggar_http_client.
PARAMETERS: p_host  TYPE char100 DEFAULT 'http://www.google.fr',
            p_port  TYPE char20.
DATA: wcl_client TYPE REF TO if_http_client.
DATA: w_content    TYPE string,
      w_host       TYPE string,
      w_port       TYPE string,
      w_proxy_host TYPE string,
      w_proxy_port TYPE string,
      w_path       TYPE string.
w_host = p_host.
w_port = p_port.
CALL METHOD cl_http_client=>create
  EXPORTING
    host          = w_host
    service       = w_port
    proxy_host    = w_proxy_host
    proxy_service = w_proxy_port
  IMPORTING
    client        = wcl_client.
wcl_client->request->set_header_field( name  = '~request_uri'
                                   value = w_path ).        "#EC *
wcl_client->request->set_header_field( name  = '~request_method'
                                   value = 'GET' ).         "#EC *
* send and receive
wcl_client->send( ).
wcl_client->receive( ).
* display content
w_content = wcl_client->response->get_cdata( ).
Best regards,
Guillaume