Can I issue this command in PL/SQL: EXECUTE IMMEDIATE '@filename.sql';

Question

can I issue this command in PL/SQL: EXECUTE IMMEDIATE '@filename.sql';

Answer 1

Hi,
Rather the opening a new process (sqlplus), a new connection (need password) etc... I would rather read and execute the file in pl/sql.
I do not know if someone wrote it already, but here is a quick and dirty code for doing that with UTL_FILE.GET_LINE
Here, I am only processing some DML statements and no SELECT statements. Correct it as you like !
CREATE OR REPLACE PROCEDURE run_script ( dir_name IN VARCHAR2,file_name IN VARCHAR2)
IS
vSFile UTL_FILE.FILE_TYPE;
vCmd VARCHAR2(200);
vNewLine VARCHAR2(200);
BEGIN
    vSFile := UTL_FILE.FOPEN(dir_name, file_name,'r');
    vCmd := NULL;
    IF UTL_FILE.IS_OPEN(vSFile) THEN
    LOOP
        BEGIN
            UTL_FILE.GET_LINE(vSFile, vNewLine);
            if (vCmd is null) THEN
                if (upper(vNewLine) like 'INSERT%' or upper(vNewLine) like 'UPDATE%' or upper(vNewLine) like 'DELETE%') THEN
                    if (vNewLine like '%;') THEN
                        /* we have a single line command, execute it now */
                        dbms_output.put_line(substr(vNewLine,1, length(vNewLine)-1));
                        execute immediate substr(vNewLine,1, length(vNewLine)-1);
                    else
                        /* we have a command over multiple line, set vCmd */
                        vCmd := vNewLine;
                    end if;
                else
                    /* ignore the rest like spool, prompt, accept, errors, host, @, ... */
                    null;
                end if;
            else
                if (vNewLine like '%;') THEN
                    /* we have a the last line of the command, execute it now */
                    vCmd := vCmd || ' ' || substr(vNewLine,1, length(vNewLine)-1);
                    dbms_output.put_line(vCmd);
                    execute immediate vCmd;
                    vCmd := null;
                else
                    /* keep concatenating to vCmd */
                    vCmd := vCmd ||' '|| vNewLine;
                end if;
            end if;
        EXCEPTION
            WHEN NO_DATA_FOUND THEN
                EXIT;
            END;
    END LOOP;
    COMMIT;
    END IF;
    UTL_FILE.FCLOSE(vSFile);
EXCEPTION
    WHEN utl_file.invalid_path THEN
        RAISE_APPLICATION_ERROR (-20052, 'Invalid File Location');
    WHEN utl_file.read_error THEN
        RAISE_APPLICATION_ERROR (-20055, 'Read Error');
    WHEN others THEN
        RAISE_APPLICATION_ERROR (-20099, 'Unknown Error');
END run_script;
set serverout on
create directory scriptdir as '/home/oracle';
grant read,write on directory to scott;
exec run_script('SCRIPTDIR', 'test.sql')