Can we use dbms_output.put_line package with forall statement

Question

Hello Everybody
Can we use dbms_output.put_line package with forall or can we use insert,update and delete only
declare
type emp_rec is table of emp%rowtype
index by binary_integer;
t emp_rec;
begin
select * bulk collect into t from emp;
forall i in t.first..t.last
dbms_output.put_line(t(i).name);
end;Thanks & Regards
peeyush
Edited by: Peeyush on Nov 25, 2010 11:45 PM

Answer 1

MichaelS wrote:
Well as the docs explain (though not very clear and detailed, I admit) you can use a dynamic sql statement (execute immediate) with FORALL.You got me interested in the performance side doing this Michael - running PL/SQL code via a FORALL loop.
It is faster than using a normal FOR loop to execute dynamic PL/SQL - a bit surprising as I expected another context switch to be in there. But seems like the PL/SQL engine is a more clever at optimisation than what I originally credited it with.. ;-)
Of course - pre-compiled/static PL/SQL code in a FOR loop is the fastest, as expected.
SQL> declare
  2          type TNumbers is table of number;
  3 
  4          type TTimes is record(
  5                  for_all number,
  6                  for_dynamic number,
  7                  for_static number
  8          );
  9 
10          type TTimesTable is table of TTimes;
11 
12          MAX_ITERATIONS  constant number := 10;
13 
14          plBlock         varchar2(1000) :=
15          'declare i number;
16          begin i:= :var / 10; end;';
17 
18          performance     TTimesTable;
19          t1              number;
20          bindVar         TNumbers;
21          n               number;
22  begin
23          select
24                  level bulk collect into bindVar
25          from    dual
26          connect by level <= 10000;
27 
28          dbms_output.put_line( 'Iterations: '||bindVar.Count||' for loop cycle(s)' );
29 
30          performance := new TTimesTable();
31          performance.Extend( MAX_ITERATIONS );
32 
33          for j in 1..MAX_ITERATIONS
34          loop
35                  t1 := dbms_utility.get_time;
36                  forall i in 1..bindVar.Count
37                          execute immediate plBlock using bindVar(i);
38                  performance(j).for_all := dbms_utility.get_time-t1;
39 
40                  t1 := dbms_utility.get_time;
41                  for i in 1..bindVar.Count
42                  loop
43                          execute immediate plBlock using bindVar(i);
44                  end loop;
45                  performance(j).for_dynamic := dbms_utility.get_time-t1;
46 
47                  t1 := dbms_utility.get_time;
48                  for i in 1..bindVar.Count
49                  loop
50                          n := bindVar(i) / 10;
51                  end loop;
52                  performance(j).for_static := dbms_utility.get_time-t1;
53          end loop;
54 
55          dbms_output.put_line( 'Times in 100th of a second' );
56          dbms_output.put_line( rpad('for all',15) || rpad('for dynamic',15) || rpad('for static',15) );
57          for i in 1..performance.Count
58          loop
59                  dbms_output.put_line(
60                          rpad( performance(i).for_all, 15 )||' '||
61                          rpad( performance(i).for_dynamic, 15 )||' '||
62                          rpad( performance(i).for_static, 15)
63                  );
64          end loop;
65 
66  end;
67  /
Iterations: 10000 for loop cycle(s)
Times in 100th of a second
for all        for dynamic    for static
10              72              0
6               37              0
6               37              0
6               37              0
6               36              0
6               37              1
5               37              0
5               37              0
6               37              1
5               37              0
PL/SQL procedure successfully completed.
SQL>