Changing colors in Illustrator--automation

Question

I have 1500 documents that use black, c0,m0,y0,k50 and 0c,0m,0y,0k as their colors. I want to change the 50k to 100m and the 0,0,0,0 to 100y. When I option drag the new color on to the old color in the swatch pallet, it changes the color in the swatch pallet but not in the artwork itself. Is there any way to get it to change the color in the artwork by editing its original color?
I can't use the select/same fill color to globally change the color because it only changes the first color. The action recording doesn't pick up that I have selected a new object color to change, so it just changes the same objects again to the second color, completely ignoring the second set of objects that I want to change.
Very frustrating since Freehand did this out of the box 6 years ago.
Thanks for help.
rich

Answer 1

Here's an AppleScript which does what I think you want.  Copy and paste into a new window in the Apple Script editor and save in Adobe Illustrator CS4>Presets>en_US>Scripts. (or you can just run it from the script editor)
-- BEGIN CODE
set fileTypes to {"EPSF", "PDF ", "ART5", "TEXT"} -- file types available to resave as Illustrator
-- get a sourceFolder that holds the files to resave as AI
set sourceFolder to (choose folder with prompt "Choose a folder with files to resave as Illustrator:") as text
-- get a list of files of the defined type in the sourceFolder
tell application "Finder" to set workingFiles to (every file of folder sourceFolder whose file type is in fileTypes) as alias list
-- now you have your fileList argument
-- get a destinationFolder to hold the PDFs
set destinationFolder to choose folder with prompt "Choose a folder to hold the Illustrator files:"
SaveFilesAsIllustrator14(workingFiles, destinationFolder)
on SaveFilesAsIllustrator14(fileList, destinationFolder)
    set destinationPath to destinationFolder as string
    repeat with aFile in fileList
        tell application "Finder"
            set fileName to displayed name of aFile -- get displayed name
            set AppleScript's text item delimiters to "."
            set newFileName to text item 1 of fileName
            set newFilePath to destinationPath & newFileName & ".ai"
        end tell
        tell application "Adobe Illustrator"
            open aFile forcing CMYK with options {update legacy text:true}
            set theList to every page item of current document
            repeat with k from 1 to count of theList
                if stroke color of item k of theList = {class:CMYK color info, cyan:0.0, magenta:0.0, yellow:0.0, black:50.0} then
                    set stroke color of item k of theList to {class:CMYK color info, cyan:0.0, magenta:100.0, yellow:0.0, black:0.0}
                end if
                if fill color of item k of theList = {class:CMYK color info, cyan:0.0, magenta:0.0, yellow:0.0, black:50.0} then
                    set fill color of item k of theList to {class:CMYK color info, cyan:0.0, magenta:100.0, yellow:0.0, black:0.0}
                end if
                if stroke color of item k of theList = {class:CMYK color info, cyan:0.0, magenta:0.0, yellow:0.0, black:100.0} then
                    set stroke color of item k of theList to {class:CMYK color info, cyan:0.0, magenta:0.0, yellow:100.0, black:0.0}
                end if
                if fill color of item k of theList = {class:CMYK color info, cyan:0.0, magenta:0.0, yellow:0.0, black:100.0} then
                    set fill color of item k of theList to {class:CMYK color info, cyan:0.0, magenta:0.0, yellow:100.0, black:0.0}
                end if
            end repeat
            save current document in file newFilePath as Illustrator with options {class:Illustrator save options, embed linked files:false, PDF compatible:true, font subset threshold:0.0}
            close current document saving no
        end tell
    end repeat
end SaveFilesAsIllustrator14
-- END CODE