Changing Default Save Location in Pages?

Question

Recently moved my wife from Microsoft Word to Pages in Lion
All her work docs have been in Word (saved to many different particular folders in Dropbox)
Whenever she opens in pages and edits I would like it to save back to the same folder it was edited from (and ideally overwite the old Word document as a 'default save option' is that possible?
At the moment the default save is to "Documents" and you have to navigate back to the old folder manually and save new pages document. Then you have to  back to finder and deleting the original Word document (otherwise duplicates with same name just without the .doc ending). It is a very awkward workflow which I know will drive her nuts and is open to easy errors of her filing
Any help much appreciated
Nic

Answer 1

When you open a Word document with Pages, you are in the same condition than when you create a new document from a template.
There is no path linked to the created document so, the save dialog will default to the late folder used to save.
I assume that there is at least one third party tool allowing us to behave differently but I don't know which one.
Here is a short script which may help.
It doesn't treat several docs at a time.
Just use it to open a Word document. The script will be aware of the original document so it will be able to save automatically a Pages version in the source folder.
If a Pages document with the same stripped name than the Word doc already exists, the new Pages document will be date_time stamped :
In such case, azerty.doc will be not be saved as azerty.pages but as azerty_20110819_165721.pages
--{code}
--[SCRIPT Doc2pages.app]
Save the script as an Application Bundle.
Run it or drag and drop a Word's doc icon on its icon.
It export the doc file as Pages one in the source folder.
Assuming that we start with:
          trucmuche.doc
it will be exported as:
          trucmuche.pages
If a file with the short name already exists
it is saved as:
          trucmuche_20080128-221639.pages
          the serial number is a packed version of the date/time of the save process:
          2008/01/08-22:16:39 .
Yvan KOENIG (VALLAURIS, France)
2011/08/19
property srcTypeId : "com.microsoft.word.doc"
property deleteWarnings : true
true = close possible warning displayed after Word import
false = don't close possible warning displayed after Word import
--=====
on run (* lignes exécutées si on double clique sur l'icône du script application
• lines executed if one double click the application script's icon *)
          set fichier to choose file of type {srcTypeId} (*
dans un bloc System Events pour avoir un titre de dialogue "localisé"
• in a System Events block to get a localized dialog title. *)
          my main(fichier as text)
end run
--=====
on open (theSelection) (* sel contient une liste d'alias des éléments qu'on a déposés sur l'icône du script (la sélection)
• sel contains a list of aliases of the items dropped on the script's icon (the selection) *)
          my main(item 1 of theSelection as text)
end open
--=====
on main(un_document)
          tell application "System Events" to tell disk item un_document
                    if type identifier is not srcTypeId then
                              if my parleAnglais() then
                                        error "“" & un_document & "” isn’t a Word document !"
                              else
                                        error "“" & un_document & "” isn’t a Word document !"
                              end if
                    end if
                    set dossier_source to path of container
                    set nom_doc to name
                    set name_extension to name extension
                    set mod_date to modification date
          end tell
          if name_extension is "" then
                    set nom_court to name_doc
          else
                    set nom_court to text 1 thru -(2 + (count of name_extension)) of nom_doc
          end if
          tell application "System Events"
                    if exists disk item (dossier_source & nom_court & ".pages") then
                              set nom_pages to nom_court & (do shell script "date +_%Y%m%d_%H%M%S.pages")
                    else
                              set nom_pages to nom_court & ".pages"
                    end if
  make new file at end of folder dossier_source with properties {name:nom_pages}
          end tell
          set new_pages to (dossier_source & nom_pages) as alias
          tell application "Pages"
                    if deleteWarnings then set warnings_avant to my get_warnings()
                    set nbDocs to count of documents
  open file un_document
                    repeat
                              if (count of documents) > nbDocs then exit repeat
                              delay 0.2
                    end repeat
  save document 1 in new_pages
          end tell
          if deleteWarnings then
                    set warnings_apres to my get_warnings()
                    if (count of warnings_apres) > (count of warnings_avant) then
                              repeat with f in warnings_apres
                                        if f is not in warnings_avant then
                                                  my close_warnings(f)
                                                  exit repeat
                                        end if -- f is not
                              end repeat
                    end if -- (count of warnings_apres
          end if -- deleteWarnings…
end main
--=====
on get_warnings()
          tell application "Pages" to activate
          tell application "System Events" to tell application process "Pages"
                    return (get name of every window whose subrole is "AXSystemFloatingWindow")
          end tell
end get_warnings
--=====
on close_warnings(w)
          tell application "Pages" to activate
          tell application "System Events" to tell application process "Pages"
                    tell window w to click first button
          end tell
end close_warnings
--===== 
on parleAnglais()
          local z
          try
                    tell application "Pages" to set z to localized string "Cancel"
          on error
                    set z to "Cancel"
          end try
          return (z is not "Annuler")
end parleAnglais
--=====
--[/SCRIPT]
--{code}
Yvan KOENIG (VALLAURIS, France) vendredi 19 août 2011 17:16:31
iMac 21”5, i7, 2.8 GHz, 4 Gbytes, 1 Tbytes, mac OS X 10.6.8 and 10.7.0
My iDisk is : <http://public.me.com/koenigyvan>
Please : Search for questions similar to your own before submitting them to the community
To be the AW6 successor, iWork MUST integrate a TRUE DB, not a list organizer !