Company Code finding

Question

Hi guys: Is there a way in SAP to find out ALL the tables that contain a certain company code? is there a t code where i can specify the co code?
thanks much
Brian

Answer 1

hi,
try this report - but restrict tables by tabclass -
REPORT zbukrs01 .
*data
TABLES dd03l.
DATA: BEGIN OF itab OCCURS 0,
        tabname TYPE dd03vt-tabname,
        tabclass TYPE dd03vt-tabclass,
      END OF itab.
DATA: dwa  TYPE REF TO data.
FIELD-SYMBOLS: <wa> TYPE ANY.
DATA: BEGIN OF wtab OCCURS 0,
        line(72),
      END OF wtab.
FIELD-SYMBOLS <fs>.
PARAMETERS p_fld LIKE dd03l-fieldname DEFAULT 'BUKRS'.
PARAMETERS p_val(50) DEFAULT '1000'.
SELECT-OPTIONS s_class FOR itab-tabclass DEFAULT 'TRANSP'.
*start-of-selection.
START-OF-SELECTION.
SELECT tabname tabclass FROM  dd03vt INTO CORRESPONDING FIELDS OF itab
         WHERE  fieldname  =  p_fld
          AND   tabclass  IN s_class.
    COLLECT itab.
  ENDSELECT.
  IF sy-subrc <> 0.
    MESSAGE e001(00) WITH 'nothing found!'.
  ENDIF.
  CONCATENATE p_fld '=' p_val INTO wtab SEPARATED BY space.
  APPEND wtab.
*output
  sort itab.
  LOOP AT itab.
    WRITE: / itab-tabname.
    CREATE DATA dwa TYPE  (itab-tabname).
    ASSIGN dwa->* TO <wa>.
    SELECT SINGLE * FROM (itab-tabname) INTO <wa>
     WHERE (wtab).
    IF sy-subrc = 0.
      SELECT *  FROM  dd03l
             WHERE  tabname  = itab-tabname
              ORDER BY position.
        ASSIGN COMPONENT dd03l-fieldname OF STRUCTURE <wa> TO <fs>.
        WRITE: / dd03l-fieldname COLOR 4, ':', <fs> COLOR 2.
      ENDSELECT.
    ELSE.
      WRITE: 'entry for table', itab-tabname, 'not found'.
    ENDIF.
    ULINE.
  ENDLOOP.
Andreas
pls reward helpful answers
thank you