Concatenate fields using vb script

Question

Hi,
we have three text fields tex1,text2 and text3. How to concatenate text2 and text3 to text1 using vb script. we have text1,text2 and text3 in workbook.
Any inputs will be appreciated.

Answer 1

Hi Prasad,
Below is VBA code.  If you really want to do this with VBScript, you will need to use createObject to get a reference to Excel.  I think you probably meant VBA.  Let me know if I am wrong and I will post the VBScript code instead.
- Pete
Sub mergeText()
Dim rng As Range
Dim col1 As Long, col2 As Long
    Set rng = Range("SAPBEXqueries!SAPBEXq0001")
    'make sure that the BW query sheet is the active sheet
    rng.Parent.Activate
    'determine first and last rows and columns
    firstRow = rng.Rows(1).Row
    lastRow = firstRow + rng.Rows.Count - 1
    firstCol = rng.Columns(1).Column
    lastCol = firstCol + rng.Columns.Count - 1
    'locate the columns we want to concatenate
    'are the column headers in the first row???
    For j = firstCol To lastCol
        If Cells(firstRow, j) Like "Sales Person*" Then col1 = j
        If Cells(firstRow, j) Like "Sales Manager*" Then col2 = j
    Next j
    If col1 = 0 Or col2 = 0 Then
        MsgBox "Did not find required columns"
        Exit Sub
    End If
    'if we got here, we found the required columns
    'concatenate
    Cells(firstRow, lastCol + 1) = "Concatenated text"
    For i = firstRow + 1 To lastRow
        Cells(i, lastCol + 1) = Cells(i, col1) & "\" & Cells(i, col2)
    Next i
    'reset result range so that BW will clean up during next query refresh
    Set rng = Range(Cells(firstRow, firstCol), Cells(lastRow, lastCol + 1))
    rng.Name = "SAPBEXqueries!SAPBEXq0001"
End Sub