Conditional highlighting the lowest 5 numbers out of 10 in a row of numbers

Question

Can this be done?  I can do it in Excel but have not figured out how to do it in Numbers.
39 40  38 41  41  38  39  39  40  36

Answer 1

Or even simpler, if you don't want to fuss with adding extra columns and such, you can just select the cells with the numbers and click a button to color the lowest 5 numbers red. Six are colored here because of a tie:
SG
Copy this script into AppleScript Editor, select the cells, and click the green triangle 'Run' button:
--colors text of selected cells with lowest five values red
tell application "Numbers"
          set t to front document's active sheet's first table whose selection range's class is range
          set selectedCells to t's selection range
          set sortedNumbers to my sortNumbers(selectedCells's cells's value)
          set lowestFive to sortedNumbers's items 1 thru 5
          repeat with aCell in selectedCells's cells
                    if (aCell's value as string) is in lowestFive then
                              set aCell's text color to "red"
                    else
                              set aCell's text color to "black"
                    end if
          end repeat
end tell
to sortNumbers(theList)
          set oTIDs to text item delimiters of AppleScript
          set text item delimiters of AppleScript to ASCII character 10
          set theList to "" & theList
          set text item delimiters of AppleScript to oTIDs
          do shell script "echo " & quoted form of theList & " | sort --general-numeric-sort"
          set theList to paragraphs of result
end sortNumbers
--end of script
(NB: for VERY long lists of numbers, this would need modifying)