Consolidating MSP Files using a variable as the filename

Question

Hi All
I am trying to consolidate a number of MSP Files without having to hardcode the filenames.  Here is what I have so far and it is falling over on the Application.ConsolidateProjects..... line.  Any help/advice would be appreciated:
Sub ImportWorkstreamPlans()
Dim objFSO As Object
Dim objFolder As Object
Dim objFile As Object
Dim i As Integer
Dim Path As String
Application.DisplayAlerts = False
'Create an instance of the FileSystemObject
Set objFSO = CreateObject("Scripting.FileSystemObject")
'Get the folder object
Set objFolder = objFSO.GetFolder("D:\Delivery Assurance\CPP Build")
i = 1
'loops through each file in the directory and prints their names and path
For Each objFile In objFolder.Files
'FName = objFile
Application.ConsolidateProjects Filenames:=objFile, NewWindow:=False, AttachToSources:=False, HideSubtasks:=True
ViewApply Name:="CPP View"
GroupApply Name:="No Group"
SelectRow Row:=1, RowRelative:=False
Next objFile
FilterApply Name:="All Tasks"
OutlineShowAllTasks
SetAutoFilter FieldName:="Flag3", FilterType:=pjAutoFilterIn, Criteria1:="Yes"
GroupApply Name:="Sub Project"
Application.DisplayAlerts = True
End Sub
Thanks in anticipation.
Tony
TKHussar

Answer 1

Tony,
I think you made a typo when you say your individual plans are stored in "D:\CPP Build Template\CPP Plans" because your code is looking for the files in "D:|CPP Build Template\CPP
Build Plans". Maybe that's your runtime error right there.
However, I have to take back something I said previously. The FileName parameter of the ConsolidateProjects Method can, and should in this case, be a full path. I did a little further testing to simulate your configuration. I have a "Y" drive with
a desktop folder. I created a blank Project 2010 template file and a simple test file and placed both of those on the "Y" drive desktop. I am running Project 2010 on the "C" drive of Windows 7 on a virtual PC. The macro code below is in
the Global file. I open the template file and then run the macro. Everything works fine until it attempts to invoke the autofilter. Then it fails and I didn't have time to figure it out so I use a normal custom filter instead.
Sub ImportWorkstreamPlans()
Dim objFSO As Object
Dim objFolder As Object
Dim objFile As Object
Dim i As Integer
Dim Path As String
Dim FName As String
Application.DisplayAlerts = False
'Create an instance of the FileSystemObject
Set objFSO = CreateObject("Scripting.FileSystemObject")
'Get the folder object
Set objFolder = objFSO.GetFolder("Y:\Desktop")
i = 1
'loops through each file in the directory, determines if they are a project file, and then inserts them into a static master
For Each objFile In objFolder.Files
    If InStr(1, objFile.Path, ".mpp") > 0 Then
        FName = objFile.Path
        Application.ConsolidateProjects Filenames:=FName, NewWindow:=False, AttachToSources:=False, HideSubtasks:=True
        ViewApply Name:="Gantt Chart"
        GroupApply Name:="No Group"
        SelectRow Row:=1, RowRelative:=False
    End If
Next objFile
    OutlineShowAllTasks
    FilterApply Name:="All Tasks"
    FilterEdit Name:="TKH", taskfilter:=True, create:=True, overwriteexisting:=True, _
        FieldName:="Flag3", test:="equals", Value:="yes", ShowInMenu:=False, showsummarytasks:=True
    FilterApply Name:="TKH"
    'SetAutoFilter FieldName:="Flag3", FilterType:=pjAutoFilterFlagYes
    GroupApply Name:="Sub Project"
Application.DisplayAlerts = True
End Sub
John