Constant declaration of VARRAY index by varchar2 within package header

Question

Hi there
I'm looking for the correct syntax to declare a constant
of a varray type which is indexed by varchar2. I've tried
the following:
create or replace package nl_types
is
    TYPE nt_assoc_small IS TABLE OF INTEGER INDEX BY VARCHAR2(32);
    nl_bindcnt constant nt_assoc_small ('xml_gkregnl') := 3;
end;
I know this array hat just one element, but there will
be even more when I got this example case to work. As
I tried to compile this package, the compiler said:
13/16 PL/SQL: Declaration ignored
13/25 PLS-00566: type name "NT_ASSOC_SMALL" cannot be constrained
13/70 PLS-00320: the declaration of the type of this expression is
incomplete or malformed
O.K. then: Does anybody know the "wellformed" declaration
for this kind of varray?
Thanx in advance,
Martin.

Answer 1

That's not a VARRAY declaration, it's a PL/SQL table / associative array.
There is no syntax to declare the contents of an associative array in-line.
They can either be assigned to directly or populated by BULK COLLECT (except for associative arrays indexed by VARCHAR2). Perhaps you could assign the return value of a function?
Oracle Database 10g Enterprise Edition Release 10.1.0.2.0 - 64bit Production
With the Partitioning, OLAP and Data Mining options
SQL> CREATE OR REPLACE PACKAGE types AS
  2   
  3    TYPE associative_array_type IS TABLE OF INTEGER
  4      INDEX BY VARCHAR2 (32);
  5 
  6    FUNCTION default_associative_array_type
  7      RETURN associative_array_type;
  8    
  9  END;
10  /
Package created.
SQL> CREATE OR REPLACE PACKAGE BODY types AS
  2 
  3    FUNCTION default_associative_array_type
  4      RETURN associative_array_type
  5    IS
  6      associative_array associative_array_type;
  7    BEGIN
  8      associative_array ('xml_gkregnl') := 3;
  9      RETURN associative_array;
10    END;
11    
12  END;
13  /
Package body created.
SQL> CREATE OR REPLACE PACKAGE constants AS
  2   
  3    associative_array CONSTANT types.associative_array_type :=
  4      types.default_associative_array_type;
  5     
  6  END;
  7  /
Package created.
SQL> SET SERVEROUTPUT ON;
SQL> BEGIN
  2    DBMS_OUTPUT.PUT_LINE (
  3      'constants.associative_array (''xml_gkregnl'') => ' ||
  4        constants.associative_array ('xml_gkregnl'));
  5  END;
  6  /
constants.associative_array ('xml_gkregnl') => 3
PL/SQL procedure successfully completed.
SQL>