Consuming scheduler events

Question

Not too sure what I am doing wrong:
1. Created an agent using:
SQL> exec dbms_scheduler.add_event_queue_subscriber('feedback_agent');
2. Created a table to hold the feedback:
SQL> create table test_event(a timestamp with time zone, b varchar2(100) );
Table created.
SQL> commit;
3. Submitted both the jobs:
v_job_name := 'job_'||p_job_id';
dbms_scheduler.create_job (
job_name => v_job_name,
job_type => 'EXECUTABLE',
job_action => '/home/user/testscript.sh',
number_of_arguments => 2,
start_date => p_start_time,
enabled => false,
auto_drop => true);
-- set the arguments
dbms_scheduler.set_job_argument_value (
job_name => v_job_name,
argument_position => 1,
argument_value => p_arg1_val);
dbms_scheduler.set_job_argument_value (
job_name => v_job_name,
argument_position => 2,
argument_value => p_arg2_val);
DBMS_SCHEDULER.SET_ATTRIBUTE(v_job_name, 'raise_events', DBMS_SCHEDULER.JOB_SUCCEEDED);
dbms_scheduler.create_job('Feedback_'||p_job_id,
job_type=>'plsql_block',
job_action=>
'insert into test_event values(systimestamp, ''second job runs'');commit;',
event_condition => 'tab.user_data.object_name = '''||v_job_name||'''',
queue_spec =>'sys.scheduler$_event_queue,feedback_agent',
enabled=>true);
-- Enable the first job so that it starts running
dbms_scheduler.enable(v_job_name);
4. The actual jobs execute - but the feedback event is never captured. I see the "feedback_x" jobs sitting in the queue with teh following query:
select *
from user_scheduler_jobs

Answer 1

Hi,
I found one bug in your code - in the event condition you are using v_job_name which is e.g. 'job_1' but the actual job name will be canonicalized so the actual job name will be 'JOB_1' . You can fix this in several ways
- start off with v_job_name being uppercased
- put it in double-quotes when creating the job so the job name will remain lowercased
- in the event condition use UPPER()
Here is a simple test case which works (note that we use an uppercased J1 in the event condition).
Hope this helps,
Ravi.
-- simple event job
exec dbms_scheduler.add_event_queue_subscriber('feedback_agent');
create table test_event(a timestamp with time zone, b varchar2(100) );
begin
  dbms_scheduler.create_job (
    job_name => 'j1',job_type => 'plsql_block',
    job_action =>
'insert into test_event values(systimestamp, ''first job runs'');commit;',
    number_of_arguments => 0, enabled => false, auto_drop => true);
  dbms_scheduler.set_attribute('j1', 'raise_events', DBMS_SCHEDULER.JOB_SUCCEEDED);
end;
begin
  dbms_scheduler.create_job('j2',
    job_type=>'plsql_block',
    job_action=>
  'insert into test_event values(systimestamp, ''second job runs'');commit;',
    event_condition => 'tab.user_data.object_name = ''J1''',
    queue_spec =>'sys.scheduler$_event_queue,feedback_agent',
    enabled=>true);
  -- Enable the first job so that it starts running
  dbms_scheduler.enable('j1');
end;
/