Create a package with one function - Error Ora-00907

Question

Hello,
I want to create a package which should store one function.
The code looks like this:
Package Header:
CREATE OR REPLACE
PACKAGE "PCK_REPORT" AS
  TYPE t_varchar2 IS TABLE OF VARCHAR2(4000);
  FUNCTION f_tabtostring(i_varchar2 IN t_varchar2) RETURN VARCHAR2;
END;Package Body:
CREATE OR REPLACE PACKAGE BODY "PCK_REPORT" AS
  FUNCTION f_tabtostring (i_varchar2 IN t_varchar2) RETURN VARCHAR2 IS
                            o_string VARCHAR2(32767);
  BEGIN
    FOR i IN 1 .. i_varchar2.COUNT LOOP
      IF i != i_varchar2.FIRST THEN
        o_string := o_string || ', ';
      END IF;
      o_string := o_string || i_varchar2(i);
    END LOOP;
    RETURN o_string;
  END f_tabtostring;
END;Comilation works fine, but when I try to use the function with the following example:
SELECT pck_report.f_tabtostring(CAST(COLLECT(mytable.col1) as t_varchar2)) as column1
FROM mytable;it only returns an error ORA-00902: Unknown datatype.
When I add the package name to the datatype at the cast in the sql statement, it returns an error ORA-00903.
What is my misstake?
Thanks,
Thomas

Answer 1

create a global type, and not in the package :
1* create or replace type t_varchar2 is table of varchar2(100)
SQL> /
Type created.
1 CREATE OR REPLACE PACKAGE "PCK_REPORT" AS
2 FUNCTION f_tabtostring(i_varchar2 IN t_varchar2) RETURN VARCHAR2;
3* END;
SQL> /
Package created.
1 CREATE OR REPLACE PACKAGE BODY "PCK_REPORT" AS
2 FUNCTION f_tabtostring (i_varchar2 IN t_varchar2) RETURN VARCHAR2 IS
3 o_string VARCHAR2(32767);
4 BEGIN
5 FOR i IN 1 .. i_varchar2.COUNT LOOP
6 IF i != i_varchar2.FIRST THEN
7 o_string := o_string || ', ';
8 END IF;
9 o_string := o_string || i_varchar2(i);
10 END LOOP;
11 RETURN o_string;
12 END f_tabtostring;
13* END;
SQL> /
Package body created.
SQL> select col1 from mytable;
COL1
test1
test2
test3
test4
test5
test6
test7
test8
test9
test10
10 rows selected.
SQL> select pck_report.f_tabtostring(cast(collect(mytable.col1) as t_varchar2)) as col1 from mytable
COL1
test1, test2, test3, test4, test5, test6, test7, test8, test9, test10