Create Directories based on File Names

Question

I have a Folder with all of my digital photos. All of the photos are named using a %Y%m%d_%H%M%S.jpg format. I am trying to write a script that would go through, and create folders based on the %Y%m%d portion of the name. Then move the photos into the appropriate folders. Then, create folders named according to %Y%m of the newly created folders, and move the %Y%m%d folders into the %Y%m folders. So that my folders would be organized as /%Y%m/%Y%m%d/%Y%m%d_%H%M%S.jpg or 200809/20080905/20080905_083026 - for a photo taken today.
Any tips for getting started on this? As always, thanks in advance.

Answer 1

There are a number of ways of doing this, here's one model:
set topFolder to (choose folder with prompt "Please select the folder containing your images")
tell application "Finder"
  repeat with eachFile in (get files of folder topFolder)
    -- get the file name and date elements
    set filename to name of eachFile
    set YMD to characters 1 through ((offset of "_" in filename) - 1) of filename as text
    set YM to characters 1 through 6 of YMD as text
    -- make sure the subfolders exist. If they don't then create them
    if not (exists folder YM of topFolder) then
      make new folder at topFolder with properties {name:YM}
    end if
    if not (exists folder YMD of folder YM of folder topFolder) then
      make new folder at folder YM of folder topFolder with properties {name:YMD}
    end if
    -- now move the file
    move eachFile to folder YMD of folder YM of folder topFolder
  end repeat
end tell