Creating customized search helps in Dialog Programming

Question

Hello people I have a little predicament here. I need to create search help restricting the results.
Like lets say I want to create a search help that select material numbers and name for a specific material group. Then use that as a seach help.
Right now Im playing around with function module <b>HELP_VALUES_GET_WITH_TABLE</b> but it seems to open right when you access call screen.
Also Since this is dialog programming I am using screen painter. And I need to assign the search help in an I/O Field.
Well that's all for now take care guys. Take care to you all.

Answer 1

Hi Chad,
Is your problem been resolved .
If not , just try this code
Copy paste as it is and it will work .
TYPES: BEGIN OF values,
         carrid TYPE spfli-carrid,
         connid TYPE spfli-connid,
       END OF values.
DATA: carrier(3) TYPE c,
      connection(4) TYPE c.
DATA: progname TYPE sy-repid,
      dynnum   TYPE sy-dynnr,
      dynpro_values TYPE TABLE OF dynpread,
      field_value LIKE LINE OF dynpro_values,
      values_tab TYPE TABLE OF values.
CALL SCREEN 100.
MODULE init OUTPUT.
  progname = sy-repid.
  dynnum   = sy-dynnr.
  CLEAR: field_value, dynpro_values.
  field_value-fieldname = 'CARRIER'.
  APPEND field_value TO dynpro_values.
ENDMODULE.
MODULE cancel INPUT.
  LEAVE PROGRAM.
ENDMODULE.
MODULE value_carrier INPUT.
  CALL FUNCTION 'F4IF_FIELD_VALUE_REQUEST'
       EXPORTING
            tabname     = 'DEMOF4HELP'
            fieldname   = 'CARRIER1'
            dynpprog    = progname
            dynpnr      = dynnum
            dynprofield = 'CARRIER'.
ENDMODULE.
MODULE value_connection INPUT.
  CALL FUNCTION 'DYNP_VALUES_READ'
       EXPORTING
            dyname             = progname
            dynumb             = dynnum
            translate_to_upper = 'X'
       TABLES
            dynpfields         = dynpro_values.
  READ TABLE dynpro_values INDEX 1 INTO field_value.
  SELECT  carrid connid
    FROM  spfli
    INTO  CORRESPONDING FIELDS OF TABLE values_tab
    WHERE carrid = field_value-fieldvalue.
  CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
       EXPORTING
            retfield    = 'CONNID'
            dynpprog    = progname
            dynpnr      = dynnum
            dynprofield = 'CONNECTION'
            value_org   = 'S'
       TABLES
            value_tab   = values_tab.
ENDMODULE.
<b>For Screen 100 logic:
Copy:</b>
PROCESS BEFORE OUTPUT.
  MODULE INIT.
PROCESS AFTER INPUT.
  MODULE CANCEL AT EXIT-COMMAND.
PROCESS ON VALUE-REQUEST.
  FIELD CARRIER MODULE VALUE_CARRIER.
  FIELD CONNECTION MODULE VALUE_CONNECTION.
<b>Do design the layout also.</b>
I hope this will help you.
If this satisfy  you then please close the thread by rewarding appropriate points to the helpful answers.
Cheers
Sunny
Message was edited by: Sunny