Creating synonys for all table

Question

i want to create synonyms for all atbles.the synonyn name and table name are same.instead creating one by one synonym i wnat to create all synonyms at a time.
1)select 'CREATE PUBLIC SYNONYM'||' '||'test'||' '||'for' ||' '||'test' from dual
2)select OBJECT_NAME from user_objects where OBJECT_TYPE ='TABLE'
in the first query if we replace with test with 2nd query then we can get the script for that.
i replaced that biut its not working how to do it

Answer 1

Here is a generic grant script. If you review it, you will see how it works and can adapt it to your varying needs.
BEGIN
    FOR x IN ( SELECT owner,
                      object_name,
                      DECODE(object_type, 'TABLE' ,   'select, insert, update, delete',
                                          'SEQUENCE', 'select',
                                          'VIEW',     'select',
                                                      'execute') AS privs,
                      DECODE (owner, 'SCHEMA_1', 'USER_1',
                                     'SCHEMA_2', 'ROLE_A'
                                      ) AS app_user
                 FROM dba_objects
                WHERE object_type IN ('TABLE',    'PACKAGE', 'PROCEDURE',
                                      'FUNCTION', 'SEQUENCE', 'VIEW')
                  AND owner       IN ('SCHEMA_1', 'SCHEMA_2' ))
    LOOP
      BEGIN
        EXECUTE IMMEDIATE 'grant ' || x.privs       || ' on ' || x.owner ||
                          '.'      || x.object_name || ' to ' || x.app_user   ;
        EXECUTE IMMEDIATE 'create or replace synonym '|| x.app_user||'.'||x.object_name||
                           ' for ' ||x.owner||'.'||x.object_name ;
      EXCEPTION
        WHEN others THEN
          dbms_output.put_line('Bad owner = '||x.owner||';  Bad app_user='||x.app_user||
                               ';  Bad object_name='||x.object_name);
      END;
    END LOOP;
END;
/