Creating (view, add, delete, modify) bsp application

Question

Hi gurus,
Could anyone here please help. I am totally a new user in SAP and I would wish to create a small bsp application that could interact with my database in transaction se16.
Below are the requirements.
1) Allow user to<b> view </b>all Database Records
2) Allow user to <b>add</b> records into the Database
3) Allow user to <b>delete</b> records from the Database
4) Allow user to <b>modify</b> records from the Database
My table name in se16 is ZRM_PERIOD_CTRL
and has 4 fields which are : CLASS, FISCPER3, FISCYEAR, ZG_PVER
Can you please provide some direction on this?
Thanks in advance
Message was edited by:
        gary lee
Message was edited by:
        gary lee

Answer 1

Hi Gary,
Lets start...!!!
1) Create a new page <b>page.htm</b>
2) In the<b> layout section</b> of the page put :
<%@page language="abap" %>
<%@extension name="htmlb" prefix="htmlb" %>
<htmlb:content design="design2003" >
  <htmlb:page title="Modify table " >
    <htmlb:form>
      <htmlb:tray id     = "tray1"
                  title  = "Data Tray"
                  design = "BORDER" >
        <htmlb:trayBody>
          <htmlb:tableView id             = "TV"
                           table          = "<%= itab %>"
                           design         = "ALTERNATING"
                           onRowSelection = "MyEventRowSelection"
                           selectionMode  = "MULTILINEEDIT"
                           columnWidth    = "100%"
                           filter         = "SERVER" />
          <br>
          <br>
          <center>
          <htmlb:button id       = "Update"
                        text     = "Update"
                        onClick  = "onInputProcessing"
                        design   = "emphasized"
                        disabled = "false" />
          </center>
        </htmlb:trayBody>
      </htmlb:tray>
    </htmlb:form>
  </htmlb:page>
</htmlb:content>
3) In the <b>TYPE DEFINITIONS</b> : 
TYPES : itab_t type standard table of ZBANCTECPRD,
        wa_t type line of itab_t.
4) Then in <b>page attributes</b> :
itab                      TYPE     ITAB_T
selectedrowindextable TYPE     INT4_TABLE
wa                      TYPE     WA_T
zindex                      TYPE     SY-INDEX
5) In the <b>Event Handler</b> : 
In <i><b>onCreate</b></i> :
select * from ZBANCTECPRD INTO TABLE ITAB.
In <i><b>onInputProcessing</b></i> :
* To get the selected RowIndex...
CLASS cl_htmlb_manager DEFINITION LOAD.
DATA: tv          TYPE REF TO cl_htmlb_tableview,
      event       TYPE REF TO cl_htmlb_event,
      table_event TYPE REF TO cl_htmlb_event_tableview.
FIELD-SYMBOLS <i> LIKE LINE OF selectedrowindextable.
tv  ?= cl_htmlb_manager=>get_data( request = request
                                   name    = 'tableView'
                                   id      = 'TV' ).
IF tv IS NOT INITIAL.
  table_event = tv->data.
  CLEAR selectedrowindextable.
  selectedrowindextable = table_event->prevselectedrowindextable.
  IF table_event->event_type EQ cl_htmlb_event_tableview=>co_row_selection.
    READ TABLE selectedrowindextable WITH KEY table_line = table_event->row_index TRANSPORTING NO FIELDS.
    IF sy-subrc EQ 0.
      DELETE selectedrowindextable INDEX sy-tabix.
    ELSE.
      APPEND INITIAL LINE TO selectedrowindextable ASSIGNING <i>.
      <i> = table_event->row_index.
      zindex = table_event->row_index.
    ENDIF.
  ENDIF.
ENDIF.
* get the button event.
IF event_id = cl_htmlb_manager=>event_id.
  event = cl_htmlb_manager=>get_event( runtime->server->request ).
  IF event->name = 'button' AND event->event_type = 'click'.
    DATA : button_event TYPE REF TO cl_htmlb_event_button.
    button_event ?= event.
  ENDIF.
  CASE event->id.   " Use this for specifying code for different buttons.
    WHEN 'Update'.          " This is the button id.
      tv ?= cl_htmlb_manager=>get_data(
             request      = request
             name         = 'tableView'
             id           = 'TV' ).
      IF tv IS NOT INITIAL.
        DATA : tv_data TYPE REF TO cl_htmlb_event_tableview .
        tv_data = tv->data.
*get values from screen to work-area...get_cell_value is for tableView and get_data is for other objects like inputfield
        wa-scnotify     = tv_data->get_cell_value(
                                         row_index     = zindex
                                         column_index  = 1 ).
        wa-equipmentid  = tv_data->get_cell_value(
                                         row_index     = zindex
                                         column_index  = 2 ).
        wa-clientname   = tv_data->get_cell_value(
                                         row_index     = zindex
                                         column_index  = 3 ).
        wa-sla          = tv_data->get_cell_value(
                                         row_index     = zindex
                                         column_index  = 4 ).
        wa-reference_no    = tv_data->get_cell_value(
                                         row_index     = zindex
                                         column_index  = 5 ).
        wa-district_code    = tv_data->get_cell_value(
                                         row_index     = zindex
                                         column_index  = 6 ).
        DATA : temp_date(10) TYPE c, new_date TYPE d.
        temp_date  = tv_data->get_cell_value(
                               row_index     = zindex
                               column_index  = 7 ).
        CALL FUNCTION 'CONVERT_DATE_TO_INTERNAL'
          EXPORTING
            date_external = temp_date
          IMPORTING
            date_internal = new_date.
        wa-malfuncstdate = new_date.
        temp_date  = tv_data->get_cell_value(
                               row_index     = zindex
                               column_index  = 8 ).
        CALL FUNCTION 'CONVERT_DATE_TO_INTERNAL'
          EXPORTING
            date_external = temp_date
          IMPORTING
            date_internal = new_date.
        wa-malfuncendate = new_date.
        wa-ceid   = tv_data->get_cell_value(
                                         row_index     = zindex
                                         column_index  = 9 ).
        MODIFY itab INDEX  zindex FROM wa .
        MODIFY zbanctecprd FROM wa.
      ENDIF.
  ENDCASE.
ENDIF.
<u><i><b>This is the code to modify a table line.....Try and think on these lines to add or delete a table line....!!</b></i></u>
Also note that i have used my own Ztable....you will have to modify the code a bit for your Ztable....!!
<i>Do reward each useful answer..!</i>
Thanks,
Tatvagna.