CRM Pricing Exits

Question

Hi,
I am new to CRM pricing, and want to port my R/3 exits and ZZ fields to CRM. Would really appreciate if someone can send me some sample code about CRM_COND_COM_BADI and Java-exits, as to how do I manipulate the ZZ fields I have added to CRM Catalog. If there is any documentation available on this also please send me the same at [email protected]
Thanks in Advance,
Indi

Answer 1

Also, have a look at the following BADI implementation for CRM_COND_COM_BADI :
METHOD if_ex_crm_cond_com_badi~item_communication_structure .
  INCLUDE crm_object_names_con.
* Internal Table Declaration
  DATA: lit_header_guid         TYPE crmt_object_guid_tab,
        lit_item_guid           TYPE crmt_object_guid_tab,
        lit_requested_objects   TYPE crmt_object_name_tab,
        lit_partner             TYPE crmt_partner_external_wrkt,
        lit_partner_tmp         TYPE TABLE OF crmt_partner_external_wrk,
        lit_customer_i          TYPE crmt_customer_i_wrkt,
        lit_customer_h          TYPE crmt_customer_h_wrkt,
        lit_orderadm_i          TYPE crmt_orderadm_i_wrkt,
        lit_appointment         TYPE crmt_appointment_wrkt,
        lit_pricing             TYPE crmt_pricing_wrkt,
        lit_pricing_tmp         TYPE TABLE OF crmt_pricing_wrk,
        lit_appointment_tmp     TYPE TABLE OF crmt_appointment_wrk.
* Work Area declaration
  DATA: wa_crmt_partner_external_wrk TYPE crmt_partner_external_wrk,
        wa_crmt_customer_i_wrk       TYPE crmt_customer_i_wrk,
        wa_crmt_customer_h_wrk       TYPE crmt_customer_h_wrk,
        wa_crmt_appointment_wrk      TYPE crmt_appointment_wrk,
        wa_crmt_orderadm_i           TYPE crmt_orderadm_i_wrk,
        wa_pricing                   TYPE crmt_pricing_wrk,
        wa_product_guid              TYPE comt_product_guid,
        wa_zcsme_std                 TYPE zcsme_std,
        wa_partner                   LIKE LINE OF lit_partner,
        wa_utilitydivision           TYPE crm_util_division.
*Variable Declaration
  DATA:   lv_ldz                   TYPE zeew_dataelement0141,
          lv_aqband                TYPE zz_aqband,
          lv_sp_aq                 TYPE zeew_dataelement0139,
          lv_temp                  TYPE i,
          lv_partner_guid          TYPE but000-partner_guid,
          lv_item_guid             TYPE crmt_item_guid,
          lv_pod_id                TYPE guid_22,
          lv_premise_typ           TYPE eui_vbsart,
          lv_but000                TYPE bus000,
          lv_productguid           TYPE comm_producth-product_guid,
*          lv_address               TYPE bus000_ext,
          lv_cst_apr               TYPE zcsme_cst_apr,
          lv_payment_meth          TYPE crmt_buag_paymeth,
          lv_fragment_guid         TYPE comt_frg_guid,
          lv_catid                 TYPE comt_category_id,
          lv_partnerno             TYPE but000-partner,
          lv_dialog                TYPE c.
*Constants Declaration
  CONSTANTS: lc_max_score(6)          TYPE n VALUE 9999,
             lc_cont_dur(10)          TYPE c VALUE 'CONTDURA',
             lc_type_h                TYPE c VALUE 'A',
             lc_type_i                TYPE c VALUE 'B',
             lc_msg_id(10)            TYPE c VALUE 'ZCRM_APPL',
             lc_msg_typ               TYPE c VALUE 'I',
             lc_msg_no_091(3)         TYPE c VALUE '091',
             lc_part_fct_z00001(6)    TYPE c VALUE 'Z00001',
             lc_part_fct_00000001(10) TYPE c VALUE '00000001',
             lc_spec_items            TYPE crmt_boolean VALUE 'X'.
* Check if header information is incomplete......................
  CHECK cs_acs_i_com IS NOT INITIAL.
* Read the contents of the table entries of CRMT_ACS_I_SEL...
  INSERT cs_acs_i_com-header_guid INTO TABLE lit_header_guid.
  INSERT cs_acs_i_com-guid        INTO TABLE lit_item_guid.
* Populate the internal table which will be passed to the function
* module CRM_ORDER_READ so that only the requested information will be
* retrieved.
  INSERT gc_object_name-customer_h  INTO TABLE lit_requested_objects.
  INSERT gc_object_name-customer_i  INTO TABLE lit_requested_objects.
  INSERT gc_object_name-orderadm_i  INTO TABLE lit_requested_objects.
  INSERT gc_object_name-appointment INTO TABLE lit_requested_objects.
  INSERT gc_object_name-partner     INTO TABLE lit_requested_objects.
  INSERT gc_object_name-pricing     INTO TABLE lit_requested_objects.
* Read Order details.........................................
  CALL FUNCTION 'CRM_ORDER_READ'
    EXPORTING
      it_header_guid       = lit_header_guid
      it_item_guid         = lit_item_guid
      it_requested_objects = lit_requested_objects
      iv_only_spec_items   = lc_spec_items
    IMPORTING
      et_orderadm_i        = lit_orderadm_i
      et_customer_h        = lit_customer_h
      et_customer_i        = lit_customer_i
      et_appointment       = lit_appointment
      et_partner           = lit_partner
      et_pricing           = lit_pricing
    EXCEPTIONS
      document_not_found   = 0
      error_occurred       = 0
      document_locked      = 0
      no_change_authority  = 0
      no_display_authority = 0
      no_change_allowed    = 0
      OTHERS               = 0.
* Read Business Partner details
  READ TABLE lit_partner INTO wa_partner
  WITH KEY ref_kind = lc_type_h
           ref_partner_fct   = lc_part_fct_00000001.
  MOVE wa_partner-partner_no TO lv_partnerno.
  IF sy-subrc EQ 0.
    CALL FUNCTION 'BUP_PARTNER_GET'
      EXPORTING
        i_partner         = lv_partnerno
      IMPORTING
        e_but000          = lv_but000
      EXCEPTIONS
        partner_not_found = 1
        wrong_parameters  = 2
        internal_error    = 3
        OTHERS            = 4.
    IF sy-subrc <> 0.
    ENDIF.
  ENDIF.
* Copy the custom fields to IPC
* Determine LDZ and AQBAND..........................................
  IF lit_customer_i[] IS NOT INITIAL.
* Table type is sorted so no need to sort the internal table and use of
* BINARY SEARCH
    READ TABLE lit_customer_i INTO wa_crmt_customer_i_wrk
    WITH KEY guid = cs_acs_i_com-guid.
    IF sy-subrc EQ 0.
      lv_ldz   = wa_crmt_customer_i_wrk-zzcustomer_i0141.
      lv_sp_aq = wa_crmt_customer_i_wrk-zzcustomer_i0139.
      cs_acs_i_com-zz_ldz = lv_ldz(2).       " Copy LDZ...
      IF lv_sp_aq  IS NOT INITIAL.
        SELECT SINGLE zz_aqband
                 FROM ztcrm_aq_to_band
                 INTO lv_aqband
                WHERE zz_aq_from LE lv_sp_aq
                  AND zz_aq_to GE lv_sp_aq.
        IF sy-subrc EQ 0.
          cs_acs_i_com-zz_aqband = lv_aqband.  " Copy AQBAND...
        ENDIF.
      ENDIF.
    ENDIF.
  ENDIF.
* Determine Credit Score
  IF lit_customer_h[] IS NOT INITIAL.
* Table type is sorted so no need to sort the internal table and use of
* BINARY SEARCH
    READ TABLE lit_customer_h INTO wa_crmt_customer_h_wrk
    WITH KEY guid = cs_acs_i_com-guid.
    IF sy-subrc EQ 0.
      IF wa_crmt_customer_h_wrk-zzcustomer_h0311 IS INITIAL.
        cs_acs_i_com-zz_credit_score = lc_max_score.
      ELSE.
        cs_acs_i_com-zz_credit_score
        = wa_crmt_customer_h_wrk-zzcustomer_h0311.
      ENDIF.
    ELSE.
      cs_acs_i_com-zz_credit_score = lc_max_score.
    ENDIF.
  ELSE.
    cs_acs_i_com-zz_credit_score = lc_max_score.
  ENDIF.
* Determine Contract duration.
  IF lit_appointment[] IS NOT INITIAL.
    lit_appointment_tmp[] = lit_appointment[].
    SORT lit_appointment_tmp BY ref_guid ref_kind appt_type.
    READ TABLE lit_appointment_tmp INTO wa_crmt_appointment_wrk
    WITH KEY ref_guid = cs_acs_i_com-header_guid
             ref_kind = lc_type_h
             appt_type = lc_cont_dur
    BINARY SEARCH.
    IF sy-subrc EQ 0 AND
      wa_crmt_appointment_wrk-duration NE space.
      cs_acs_i_com-zz_duration = wa_crmt_appointment_wrk-duration.
    ENDIF.
  ENDIF.
* Copy BP type,  potential value, elasticity index
* and cost to server.
  IF lv_but000 IS NOT INITIAL.
    cs_acs_i_com-zz_bptype        = lv_but000-bpkind.
    IF lv_but000-zzpnt_val0001 IS INITIAL.
      cs_acs_i_com-zz_potentialval = lc_max_score.
    ELSE.
      cs_acs_i_com-zz_potentialval  = lv_but000-zzpnt_val0001.
    ENDIF.
    IF lv_but000-zzei_indx0001 IS INITIAL.
      cs_acs_i_com-zz_elstct_indx   = lc_max_score.
    ELSE.
      cs_acs_i_com-zz_elstct_indx   = lv_but000-zzei_indx0001.
    ENDIF.
    IF lv_but000-zzcost_to_se0001 IS INITIAL.
      cs_acs_i_com-zz_cost_to_serve   = lc_max_score.
    ELSE.
      cs_acs_i_com-zz_cost_to_serve   = lv_but000-zzcost_to_se0001.
    ENDIF.
  ENDIF.
* Determine Broker.
  IF lit_partner[] IS NOT INITIAL.
    lit_partner_tmp[] = lit_partner[].
    SORT lit_partner_tmp BY  ref_guid partner_fct.
    READ TABLE lit_partner_tmp
    INTO wa_crmt_partner_external_wrk
    WITH KEY  ref_guid = cs_acs_i_com-guid
              partner_fct = lc_part_fct_z00001
    BINARY SEARCH.
    IF sy-subrc EQ 0.
      cs_acs_i_com-zz_broker
      = wa_crmt_partner_external_wrk-ref_partner_no.
    ENDIF.
  ENDIF.
* Determine SIC_CODE..........................................
  lv_item_guid = cs_acs_i_com-crm_item_guid.
  IF lv_item_guid IS NOT INITIAL.
    CALL FUNCTION 'ECRM_ISU_GET_PODGUID'   " Retrieve the pod ID
      EXPORTING
        x_orderadm_i_guid = lv_item_guid
      IMPORTING
        y_podguid         = lv_pod_id.
    IF lv_pod_id IS NOT INITIAL.
      SELECT SINGLE vbsart                 " Retrieve the pod
               FROM isu_pod
               INTO lv_premise_typ
              WHERE int_ui = lv_pod_id.
      IF sy-subrc EQ 0.
        cs_acs_i_com-zz_sic_code = lv_premise_typ. " Set the SIC_CODE
        IF cs_acs_i_com-zz_sic_code IS INITIAL.
          cs_acs_i_com-zz_sic_code = lc_max_score.
        ENDIF.
      ENDIF.
    ENDIF.
  ENDIF.
* Determine customer approach,Utility Division and standing charge value
  CALL FUNCTION 'ZCRM_READ_PRODUCT_DTLS'
    EXPORTING
      x_product_guid      = cs_acs_i_com-product
    IMPORTING
      y_sme_product_dtls  = wa_zcsme_std
    EXCEPTIONS
      table_not_found     = 1
      settype_not_found   = 2
      no_authority        = 3
      frg_not_found       = 4
      prod_dtls_not_found = 5
      OTHERS              = 6.
  IF sy-subrc EQ 0.
    cs_acs_i_com-zz_csme_cst_apr = wa_zcsme_std-zz0012.
    cs_acs_i_com-zz_csme_std_chg = wa_zcsme_std-zz0014.
    cs_acs_i_com-zz_utildivision = wa_zcsme_std-zz0015.
  ENDIF.
* Determine Payment Method......................
  IF lit_pricing[] IS NOT INITIAL.
    lit_pricing_tmp[] = lit_pricing[].
    SORT lit_pricing_tmp BY ref_guid.
    READ TABLE lit_pricing_tmp INTO wa_pricing
    WITH KEY ref_guid = cs_acs_i_com-crm_item_guid
    BINARY SEARCH.
    IF sy-subrc EQ 0.
      cs_acs_i_com-zz_paymenthod = wa_pricing-payment_method.
    ENDIF.
  ENDIF.
* Determine Business Partner type
  cs_acs_i_com-zz_bptype = lv_but000-bpkind.
* Set a flag if this module is called in background
  CALL FUNCTION 'DIALOG_GET_STATUS'
    IMPORTING
      dialog_status = lv_dialog.
  cs_acs_i_com-zz_dialog = lv_dialog.
<b>Reward points if it helps.</b>