Deep DDIC-Structure - Method to get the Comp.Type of a sub-structure

Question

Dear colleagues,
thought the subsequent piece of coding might be helpful for the following problem:
In DDIC you have created a deep/nested Structure e.g. a complete Business Document representation like
s_doc_header type struct_doc_header
     (incl.) item  type tab_item
        (incl) party type tab_party etc.
Now for some purpose you need to access somewhere a sub-part of this structure, e.g. the party-part. You only know (dynamically) the component name "party", but need for dynamic access also the Component Type ("tab_party") (in order to make use of  a "CREATE DATA lr_reftodata TYPE (determined_comp_type)." )
The following piece of coding should help to query any start component type (here "struct_doc_header") for its embedded components.
Its a recursive use of features provided by the very nice class(set) of cl_abap_structdescr.
I implemented it as a static method.
When doing so, you need to ensure, that the TYPE-GROUP "ABAP" is linked to the class (class properties --> forward declarations),
Let me know if you find it useful.
And apologies in advance, if the same problem was already posted in the forum. I did only a rough search before due to a lag of ideas for appropriate search-strings ...
Best regards,
Rudy
Signature:
Importing:
IV_COMPNAME     TYPE ABAP_COMPNAME
IV_START_STRUCTR     TYPE KOMP_TYPE
Exporting/returning
EV_DDIC_STRUCT     TYPE KOMP_TYPE
METHOD search_deep_ddic_by_comp.
* Description      -------------------------------------------
*  Methods looks into a deep DDIC-Structure and returns the
*  corresponding TYPE
*  Prerequsite for usage: Structures component names are unique.
* Local Data Defintions --------------------------------------
* Locals -----------------------------------------------------
* TYPES:
  DATA: lv_compname                 TYPE abap_compname.
  DATA: lt_componenttable           TYPE abap_component_tab.
  DATA: lv_relative_name            TYPE string.
  DATA: lv_ddic_header                  TYPE x030l.
  DATA: lv_ddic_struct              TYPE komp_type.
  DATA: lv_start_struct             TYPE komp_type.
* supporting
  DATA: lv_lines                    TYPE i.
  DATA: lv_message                  TYPE string.
  DATA: lt_selopt                   TYPE sesf_selection_parameters_tab.
  DATA: ls_selopt                   TYPE sesf_selection_parameter.
* References -------------------------------------------------
  DATA: lo_struct_descr             TYPE REF TO cl_abap_structdescr.
  DATA: lo_type_descr               TYPE REF TO cl_abap_typedescr.
* Field-Symbols ----------------------------------------------
  FIELD-SYMBOLS:
        <fs_struct_descr_component> TYPE abap_componentdescr.
  lo_struct_descr ?= cl_abap_structdescr=>describe_by_name( p_name = iv_start_structr ).
  IF lo_struct_descr IS BOUND.
*   get all sub-structures/components of iv_start_structr
    CALL METHOD lo_struct_descr->get_components
      RECEIVING
        p_result = lt_componenttable.
    lv_compname = iv_compname.
    READ TABLE lt_componenttable ASSIGNING <fs_struct_descr_component>
                                           WITH KEY  name = lv_compname.
    IF sy-subrc = 0.
*     matching component found - search for DDIC structure
      CALL METHOD <fs_struct_descr_component>-type->get_relative_name
        RECEIVING
          p_relative_name = lv_relative_name.
      ASSERT lv_relative_name IS NOT INITIAL.
      CASE <fs_struct_descr_component>-type->type_kind.
        WHEN 'u' OR 'v'. "structure
          ev_ddic_struct = lv_relative_name.
          RETURN.
        WHEN 'h'. "table type - derive the line type
          lo_type_descr ?= cl_abap_datadescr=>describe_by_name( p_name = lv_relative_name ).
          CALL METHOD lo_type_descr->get_ddic_header
            RECEIVING
              p_header = lv_ddic_header.
          IF sy-subrc = 0.
            ev_ddic_struct   = lv_ddic_header-refname.
            RETURN.
          ELSE.
            "error
          ENDIF.
        WHEN OTHERS.
          "error
      ENDCASE.
    ELSE.
*     go deeper into structure and look into each sub-structure via recursion
      LOOP AT lt_componenttable ASSIGNING <fs_struct_descr_component>.
        CALL METHOD <fs_struct_descr_component>-type->get_relative_name
          RECEIVING
            p_relative_name = lv_relative_name.
        ASSERT lv_relative_name IS NOT INITIAL.
        CASE <fs_struct_descr_component>-type->type_kind.
          WHEN 'u' OR 'v'. "structure
          WHEN 'h'. "table type - derive the line type
            lo_type_descr ?= cl_abap_datadescr=>describe_by_name( p_name = lv_relative_name ).
            CALL METHOD lo_type_descr->get_ddic_header
              RECEIVING
                p_header = lv_ddic_header.
            IF sy-subrc = 0.
              lv_relative_name = lv_ddic_header-refname.
            ELSE.
              "error
            ENDIF.
          WHEN OTHERS.
            EXIT. "next loop, investigate only struct and table
        ENDCASE.
*        lv_compname     = <fs_struct_descr_component>-name.
        lv_start_struct = lv_relative_name.
        CALL METHOD /scmtms/cl_ddic_utility=>search_deep_ddic_by_comp
          EXPORTING
            iv_compname      = iv_compname
            iv_start_structr = lv_start_struct
          IMPORTING
            ev_ddic_struct   = lv_ddic_struct.
        IF lv_ddic_struct IS NOT INITIAL.
          ev_ddic_struct = lv_ddic_struct.
          EXIT.
        ENDIF.
      ENDLOOP.
    ENDIF.
  ENDIF.
ENDMETHOD.

Answer 1

Using command:
ASSIGN COMPONENT idx OF STRUCTURE struc TO <fs>.
For example:
DESCRIBE FIELD pi_output TYPE pi_output COMPONENTS lv_columns. "For number of columns
DO lv_columns TIMES.
ASSIGN COMPONENT SY-INDEX OF
STRUCTURE (name of structure) TO <l_fs_output>. "<l_fs_output> - field of structure
DESCRIBE FIELD <l_fs_output>... "with other options.
ENDDO.