Dialog program that lists an ALV Grid

Question

Hello Experts,
i want to create a <b>screen divided in two parts</b>. The <b>upper side</b> shows general(Header) information and the <b>lower side</b> shows detail information using ALV grid.
When i select a record in the header of the Upper side grid , then the lower side grid will display the corresponding details.
( Initially the first record should be selected and the details for that first record will be displayed . Later user can choose any other record .........)
Could anyone pls tell me the detailed procedure for developing this..i need help.
Thanks & Best Regards
Sudhansu

Answer 1

This example is implemented using docking containers on a selection screen to give you a cut and paste example.  Simply copy and past the code into a test program and run it.  double click on any line item from the grid at the top.  the grid at the bottom will change.
report  zrich_0001.
data: imara type table of mara.
data: xmara like line of imara.
data: imarc type table of marc.
data: dockingbottom type ref to cl_gui_docking_container,
      dockingtop  type ref to cl_gui_docking_container,
      alv_bottom    type ref to cl_gui_alv_grid,
      alv_top     type ref to cl_gui_alv_grid,
      repid type syrepid.
*       CLASS lcl_event_handler DEFINITION
class lcl_event_handler definition.
  public section.
    class-methods handle_double_click
               for event double_click of cl_gui_alv_grid
                              importing e_row e_column.
endclass.
*       CLASS lcl_event_handler IMPLEMENTATION
class lcl_event_handler implementation.
  method handle_double_click.
    read table imara into xmara index e_row-index.
    select * into table imarc from marc
                  where matnr = xmara-matnr.
    call method alv_bottom->refresh_table_display( ).
  endmethod.
endclass.
parameters: p_check type c.
start-of-selection.
at selection-screen output.
  repid = sy-repid.
  select * into corresponding fields of table imara
              from mara up to 100 rows.
  read table imara into xmara index 1.
  check dockingbottom is initial.
  create object dockingtop
              exporting repid     = repid
                        dynnr     = sy-dynnr
                        side      = dockingtop->dock_at_top
                        extension = 200.
  create object alv_top
              exporting i_parent = dockingtop.
  call method alv_top->set_table_for_first_display
     exporting
          i_structure_name       = 'MARA'
     changing
          it_outtab       = imara[].
*   handler for ALV grid
  set handler lcl_event_handler=>handle_double_click for alv_top.
  create object dockingbottom
              exporting repid     = repid
                        dynnr     = sy-dynnr
                        side      = dockingbottom->dock_at_bottom
                        extension = 200.
  create object alv_bottom
                exporting i_parent = dockingbottom.
  select * into table imarc from marc
               where matnr = xmara-matnr.
  call method alv_bottom->set_table_for_first_display
      exporting
           i_structure_name       = 'MARC'
      changing
           it_outtab       = imarc[].
The implementation in a dialog program is pretty much the same, you do the logic in the PBO and use custom containers instead of docking containers.
Regards,
RIch Heilman