Disable a custom object in dialog ??

Question

hi,
i created a custom container and associated a text object to it.
i want it to be disabled intially. how to set that ??
i create the object as fol
CREATE OBJECT g_editor
      EXPORTING
        parent                     = g_editor_container
        wordwrap_mode        = cl_gui_textedit=>wordwrap_at_fixed_position
        wordwrap_to_linebreak_mode = cl_gui_textediT=>true

Answer 1

check the sample code..
REPORT  zvijay_textedit.
DATA:
  obj_cust     TYPE REF TO cl_gui_custom_container,
  obj_text     TYPE REF TO cl_gui_textedit.
* Internal table to display
DATA:
BEGIN OF i_table OCCURS 0,
  line(132) TYPE c,
END OF i_table.
START-OF-SELECTION.
  CALL SCREEN 100.
*&      Module  STATUS_0100  OUTPUT
*       text
MODULE status_0100 OUTPUT.
* To create the object custom container
* screen
  CREATE OBJECT obj_cust
      EXPORTING
          container_name = 'CONTAINER'
      EXCEPTIONS
          cntl_error = 1
          cntl_system_error = 2
          create_error = 3
          lifetime_error = 4
          lifetime_dynpro_dynpro_link = 5.
  IF sy-subrc NE 0.
  ENDIF.                             " IF sy-subrc NE 0
* create the a TextEdit Control
  CREATE OBJECT obj_text
    EXPORTING
       parent = obj_cust
       wordwrap_mode = cl_gui_textedit=>wordwrap_at_fixed_position
       wordwrap_to_linebreak_mode = cl_gui_textedit=>true
    EXCEPTIONS
        OTHERS = 1.
* put the text box in display mode
  CALL METHOD obj_text->set_readonly_mode
    EXPORTING
      readonly_mode          = 1
    EXCEPTIONS
      error_cntl_call_method = 1
      invalid_parameter      = 2
      OTHERS                 = 3.
  IF sy-subrc NE 0.
  ENDIF.                             " IF sy-subrc NE 0.
  MOVE: 'SDN Sample code' TO i_table.
  APPEND i_table.
  CALL METHOD obj_text->set_text_as_r3table
    EXPORTING
      table  = i_table[]
    EXCEPTIONS
      OTHERS = 1.
* Flush
  CALL METHOD cl_gui_cfw=>flush
    EXCEPTIONS
      OTHERS = 1.
  IF sy-subrc NE 0.
  ENDIF.                               " IF sy-subrc NE 0
ENDMODULE.                 " STATUS_0100  OUTPUT
Regards
Vijay Babu Dudla