DML and collections

Question

Hi,
How can modify a PL/SQL Table, Nested Table or VArray (using DML) that is not stored in the Database? Example: accept a collection as a "In Out parameter" in a function and manipulate this collection using DML.
Anybody have a full example to solve this situation?
Thank's

Answer 1

UPDATE, DELETE etc. are not supported in this way.
Three alternative approaches spring to mind.
Oracle9i Enterprise Edition Release 9.2.0.1.0 - 64bit Production
With the Partitioning, OLAP and Oracle Data Mining options
JServer Release 9.2.0.1.0 - Production
SQL> CREATE TYPE t_rec AS OBJECT (
2 a NUMBER,
3 b NUMBER);
4 /
Type created.
SQL> CREATE TYPE table_rec AS TABLE OF t_rec;
2 /
Type created.
SQL> SET SERVEROUTPUT ON;
1. Use PL/SQL loop to loop through collection setting values.
SQL> DECLARE
2 my_pltable table_rec :=
3 table_rec (t_rec (1, 2), t_rec (1, 2));
4 BEGIN
5 DBMS_OUTPUT.PUT_LINE ('old value: ' || my_pltable (1).a);
6
7 FOR i IN my_pltable.FIRST .. my_pltable.LAST LOOP
8 my_pltable (i).a := my_pltable (i).a + 1;
9 END LOOP;
10
11 DBMS_OUTPUT.PUT_LINE ('new value: ' || my_pltable (1).a);
12 END;
13 /
old value: 1
new value: 2
PL/SQL procedure successfully completed.
2. Use CAST/MULTISET to SELECT new values of collection back into collecion.
SQL> DECLARE
2 my_pltable table_rec :=
3 table_rec (t_rec (1, 2), t_rec (1, 2));
4 BEGIN
5 DBMS_OUTPUT.PUT_LINE ('old value: ' || my_pltable (1).a);
6
7 SELECT CAST (
8 MULTISET (
9 SELECT a + 1, b
10 FROM TABLE (my_pltable)) AS table_rec)
11 INTO my_pltable
12 FROM dual;
13
14 DBMS_OUTPUT.PUT_LINE ('new value: ' || my_pltable (1).a);
15 END;
16 /
old value: 1
new value: 2
PL/SQL procedure successfully completed.
3. Use BULK COLLECT to SELECT new values of collection back into collecion. Note this requires an additional collection.
SQL> DECLARE
2 my_pltable table_rec :=
3 table_rec (t_rec (1, 2), t_rec (1, 2));
4 my_new_pltable table_rec;
5 BEGIN
6 DBMS_OUTPUT.PUT_LINE ('old value: ' || my_pltable (1).a);
7
8 SELECT t_rec (a + 1, b)
9 BULK COLLECT INTO my_new_pltable
10 FROM TABLE (my_pltable);
11
12 DBMS_OUTPUT.PUT_LINE ('new value: ' || my_new_pltable(1).a);
13 END;
14 /
old value: 1
new value: 2
PL/SQL procedure successfully completed.
SQL>
Padders