Download multiple files and rename

Question

I have a folder with 20+ .webloc files, all pointing to Google calendar .ics downloads.  (The URLs all look like "https://www.google.com/calendar/.../basic.ics".)  I want to be able to automate downloading each of these, but the problem is that, no matter what the calendar, the file is always named "basic.ics".  What I'd like to do is 1) iterate through each .webloc in a specific folder, 2) download each one to another folder and 3) name the downloaded file according to the associated .webloc (ie, reed.webloc would download to reed.ics in a different folder).
My AppleScript skills are pretty lousy, and Automator does not seem to be able to manage this sort of renaming of the download.  Anybody got any advice?  Is there an existing script out there somewhere that I can modify for my needs?

Answer 1

I think this will do it:
set basePath to "path:to:folder:where:ics folders live"
set weblocFolderPath to "path:to:folder:with:webloc files"
tell application "Finder"
  -- extract pertinent info from webloc files
          set {locs, filenames} to {location, name} of every internet location file of folder weblocFolderPath
end tell
repeat with i from 1 to count of locs
  --remove .webloc extension from name
          set newName to text 1 thru -8 of item i of filenames
  -- make new folder with webloc file name
          tell application "Finder"
                    if not (exists folder newName of folder basePath) then
              make new folder at folder basePath with properties {name:newName}
                    end if
                    set theFolderPath to folder newName of folder basePath as text
          end tell
  -- download ics file into the folder (replacing if needed) with webloc file name
          tell application "URL Access Scripting"
                    set newFile to download (item i of locs) to (theFolderPath & newName & ".ics") replacing yes
          end tell
end repeat
basePath is the folder where you want to make the folders to store the downloaded ics files
weblocFolderPath is the folder where your 20 weblocs are stored
both paths should be listed as text strings, colon delimited, including the disk name (e.g. "hard disk name:folder name:folder name:final folder name")