Drag & Drop Video Flip Appelscript--Debug Help Needed!

Question

property type_list : {"Movie", "MOV"} -- eg: {"PICT", "JPEG", "TIFF", "GIFf"}
property extension_list : {"MOV", "MP4"} -- eg: {"txt", "text", "jpg", "jpeg"}, NOT: {".txt", ".text", ".jpg", ".jpeg"}
property typeIDs_list : {"public.mov", "public.mp4"} -- eg: {"public.jpeg", "public.tiff", "public.png"}
-- This droplet processes files dropped onto the applet
on open these_items
          repeat with i from 1 to the count of these_items
                    set this_item to item i of these_items
                    set the item_info to info for this_item
                    if folder of the item_info is true then
  process_folder(this_item)
                    else
                              try
                                        set this_extension to the name extension of item_info
                              on error
                                        set this_extension to ""
                              end try
                              try
                                        set this_filetype to the file type of item_info
                              on error
                                        set this_filetype to ""
                              end try
                              try
                                        set this_typeID to the type identifier of item_info
                              on error
                                        set this_typeID to ""
                              end try
                              if (folder of the item_info is false) and (alias of the item_info is false) and ¬
                                        ((this_filetype is in the type_list) or (this_extension is in the extension_list) or ¬
                                                  (this_typeID is in typeIDs_list)) then
  process_item(this_item)
                              end if
                    end if
          end repeat
end open
-- this sub-routine processes folders
on process_folder(this_folder)
          set these_items to list folder this_folder without invisibles
          repeat with i from 1 to the count of these_items
                    set this_item to alias ((this_folder as Unicode text) & (item i of these_items))
                    set the item_info to info for this_item
                    if folder of the item_info is true then
  process_folder(this_item)
                    else
                              try
                                        set this_extension to the name extension of item_info
                              on error
                                        set this_extension to ""
                              end try
                              try
                                        set this_filetype to the file type of item_info
                              on error
                                        set this_filetype to ""
                              end try
                              try
                                        set this_typeID to the type identifier of item_info
                              on error
                                        set this_typeID to ""
                              end try
                              if (alias of the item_info is false) and ((this_filetype is in the type_list) or ¬
                                        (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
  process_item(this_item)
                              end if
                    end if
          end repeat
end process_folder
-- this sub-routine processes files
on process_item(this_item)
  -- NOTE that the variable this_item is a file reference in alias format
  -- FILE PROCESSING STATEMENTS GOES HERE
          tell application "QuickTime Player 7"
  activate
  open this_item
                    tell document 1
                              flip vertical (the first track whose kind is "video")
  save self contained this_item
  close this_item
                    end tell
          end tell
end process_item
--can't make alias into type document, error.
The script shown above is generating an error..... can't make alias into type document.  Can you help me fix this?  You will have to paste the code above into your AS editor and then make an app out of it then drag a QT movie (.mov or .mp4) over that app and see how it goes.
Thanks.
Robert

Answer 1

Okay, I will look into that....  for the moment, I wanted to report that I have something working....
on open theItems
          repeat with anItem in theItems
                    set sourceMovie to anItem as string
                    set {oldTID, my text item delimiters} to {my text item delimiters, "."}
                    set destinationMovie to (text item 1 of sourceMovie & "_flipped") & "." & text item 2 of sourceMovie
                    set my text item delimiters to oldTID
                    tell application "QuickTime Player 7"
  open anItem
                              tell document 1
                                        flip horizontal (the first track whose kind is "video")
                                        flip vertical (the first track whose kind is "video")
  save self contained in destinationMovie
  close
                              end tell
                    end tell
          end repeat
end open
Thanks!!!!!!!!!!!!!