Duplicates in Collections

Question

Hello All,
Good morning to all OTN users.
I have below requirement to identify the duplicates in the Collection and I am not sure how to implement in easy way. Requesting all your help in doing the same.
Requirement:
I have a collection based on the record like below,
TYPE tt_type IS RECORD(
a VARCHAR2(1),
b VARCHAR2(25),
c VARCHAR2(25),
d VARCHAR2(20),
e VARCHAR2(1),
f VARCHAR2(20),
g VARCHAR2(1),
h VARCHAR2(20),
i VARCHAR2(1),
j VARCHAR2(20),
k VARCHAR2(3),
l VARCHAR2(8),
m VARCHAR2(8),
n VARCHAR2(25),
o VARCHAR2(25),
p VARCHAR2(2),
q VARCHAR2(25));
TYPE tty IS TABLE OF tt_type INDEX BY BINARY_INTEGER;
l_rec tty;
I am loading the l_rec based on some buisiness requirement. After loading the data, I have to identify the duplicates based on the two columns (This
is not possible in the SQL query due to the dependency on other queries).Basically I have to identify the duplicates based on column's "a" and "b".
Values will be like this:
a b
1) 123 098
2) 123 100
3) 345 154
4) 789 189
Here 1st and 2 nd records are duplicates (as per our functionality) and I have to remove the first record as second record has larger value for column "b" compared to 1st record.
Please help in implementing this.
Thanks a lot in advance.
Best regards,
Pavan

Answer 1

862637 wrote:
I cannot do it in the SQL, due to multiple dependencies.Assuming that statement is valid and pure array processing in PL/SQL is the solution, then removing duplicates can be done as follows:
1) quick sort the array
2) copy the array and in copying skip duplicates
The following code demonstrates this approach.
SQL> create or replace type TStrings is table of varchar2(4000);
  2  /
Type created.
SQL>
SQL> create or replace package ArrayLib is
  2          procedure QuickSort( array in out nocopy TStrings );
  3          procedure RemoveDuplicates(  array in out nocopy TStrings, sorted boolean default false );
  4  end;
  5  /
Package created.
SQL>
SQL> create or replace package body ArrayLib is
  2          procedure SwapPivots( array in out nocopy TStrings, pivot1 number, pivot2 number ) is
  3                  pivotValue      varchar2(32767);
  4          begin
  5                  pivotValue := array(pivot1);
  6                  array(pivot1) := array(pivot2);
  7                  array(pivot2) := pivotValue;
  8          end;
  9 
10          procedure  Partition( array in out nocopy TStrings, left number, right number, pivotIndex number, storeIndex out number ) is
11                  pivotValue      varchar2(32767);
12          begin
13                  pivotValue := array(pivotIndex);
14                  SwapPivots( array, pivotIndex, right );
15                  storeIndex := left;
16                  for i in left..right - 1 loop
17                          if array(i) < pivotValue then
18                                  SwapPivots( array, i, storeIndex );
19                                  storeIndex := storeIndex + 1;
20                          end if;
21                  end loop;
22                  SwapPivots( array, storeIndex, right );
23          end;
24 
25          procedure QuickSort( array in out nocopy TStrings, left number, right number ) is
26                  pivotIndex      number;
27                  pivotNewIndex   number;
28 
29          begin
30                  if left < right then
31                          pivotIndex := trunc( DBMS_RANDOM.value( left, right ) );
32 
33                          Partition( array, left, right, pivotIndex, pivotNewIndex );
34                          QuickSort( array, left, pivotNewIndex-1 );
35                          QuickSort( array, pivotNewIndex+1, right );
36                  end if;
37          end;
38 
39          procedure QuickSort( array in out nocopy TStrings ) is
40          begin
41                   QuickSort( array, 1, array.Count );
42          end;
43 
44          procedure RemoveDuplicates(  array in out nocopy TStrings, sorted boolean default false ) is
45                  unqArray        TStrings;
46          begin
47                  if not sorted then
48                          QuickSort( array );
49                  end if;
50 
51                  for i in 1..array.Count loop
52                          case
53                                  when unqArray is null then
54                                          unqArray := new TStrings( array(i) );
55                                  when unqArray(unqArray.Count) = array(i) then
56                                          --// skip duplicate
57                                          null;
58                          else
59                                  unqArray.Extend(1);
60                                  unqArray(unqArray.Count) := array(i);
61                          end case;
62                  end loop;
63 
64                  array := unqArray;
65          end;
66 
67  end;
68  /
Package body created.
SQL>
SQL> --// example
SQL> declare
  2          array   TStrings;
  3  begin
  4          select
  5                  ename bulk collect into array
  6          from    emp;
  7 
  8          --// add 3 duplicates
  9          array.Extend(3);
10          array( array.Count-2 ) := 'ADAMS';
11          array( array.Count-1 ) := 'BLAKE';
12          array( array.Count ) := 'WARD';
13 
14          --// remove duplicates
15          ArrayLib.RemoveDuplicates( array );
16 
17          for i in 1..array.Count loop
18                  W( i||' '||array(i) );
19          end loop;
20  end;
21  /
1 ADAMS
2 ALLEN
3 BLAKE
4 CLARK
5 FORD
6 JAMES
7 JONES
8 KING
9 MARTIN
10 MILLER
11 SCOTT
12 SMITH
13 TURNER
14 WARD
PL/SQL procedure successfully completed.
SQL>