Edit Illustrator symbol with AppleScript

Question

Hello,
Does anyone know if it is possible to edit an existing symbol in an Illustrator CS3 document with AppleScript? Specifically, what I'm trying to do is this: I'd like to manually create an Illustrator document that uses the "3D Extrude and Bevel" effect to map symbols to the surfaces of the 3D object. Then, I'd like to programatically open that Illustrator document, edit the existing symbols (so the surfaces of the 3D object are updated), and finally export an image.
From what I've found in the AppleScript documentation PDF, I'm thinking this is not possible since it lists all the properties of a symbol object as read-only. But perhaps I'm overlooking something?
If it is not possible, is there another way of doing what I'm trying to achieve?
Thanks!
Ben

Answer 1

Ben, could you not have just swapped your symbols? like:
set symbol of every symbol item to symbol "Foo"
Justin, if it is essential that you need to crack open a symbol item then it may be possible using system events to expand the item may even be possible with a action for this part?
This works for me. It is set to work with what items i know are available to my test doc.
{1 symbol of >2 path items, 2 gradients swatches}
tell application "Adobe Illustrator"
activate
set Doc_Ref to the current document
tell Doc_Ref
set x to width / 2
set y to height / 2
set ruler origin to {x, y}
-- Make new layer to trash later
make new layer at beginning with properties ¬
{name:"Opened Symbol", visible:true}
-- Place the symbol item you want to open
make new symbol item at beginning of layer "Opened Symbol" with properties ¬
{symbol:symbol 1, position:{0, 0}}
-- Select the item
set selection to symbol item 1
-- Use system events to drive the GUI
tell application "System Events"
tell process "Adobe Illustrator"
tell menu bar 1
click menu item "Expand..." of menu "Object"
delay 0.1
keystroke return
delay 0.1
click menu item "Ungroup" of menu "Object"
end tell
end tell
end tell
-- List your items to edit
set Symbol_Items to every page item of layer "Opened Symbol"
-- Edit what ever you have here
set fill color of path item 1 of layer "Opened Symbol" to {gradient:gradient 1}
set fill color of path item 2 of layer "Opened Symbol" to {gradient:gradient 2}
-- New group
set New_Group to make new group item at beginning of layer "Opened Symbol"
-- Move edited items into new group
repeat with i from (count of Symbol_Items) to 1 by -1
move (item i of Symbol_Items) to beginning of New_Group
end repeat
-- New symbol from group
make new symbol at end with properties ¬
{name:"My New Symbol", source art:New_Group}
-- Replace instances
set symbol of every symbol item to symbol "My New Symbol"
-- Clean up
delete every page item of layer "Opened Symbol"
delete layer named "Opened Symbol"
delete symbol 1
end tell
end tell