Employee photo is not Displaying on the PDF form

Question

Hello Experts,
  We have a static form and passing the form data and photo repository URL (Used FM to get the URL of the photo 'HRMSS_RFC_EP_READ_PHOTO_URI' ) to the form.  And all these sent to ADS for made complete form.
But we  are facing the probelm that Photo is not diplaying on the form. We have found that Photo URL is not worked priviously
now made the changes in OAC0 and working fine. But the photo is still not showing  on the form.
Can anybody help us
      Logic to call the PDF Form
  CALL FUNCTION 'FP_FUNCTION_MODULE_NAME'
    EXPORTING
      i_name     = lc_formname
    IMPORTING
      e_funcname = ld_fm_name.
*Function to open form processing
Set output parameters and open spool job.
  ls_fp_outputparams-nodialog   = lc_x.
  ls_fp_outputparams-getpdf     = lc_getpdf.      "'M'
  ls_fp_outputparams-connection = lc_connection.  "'ADS'
  ls_fp_outputparams-bumode     = lc_bumode.      "'M'.
  ls_fp_outputparams-assemble   = lc_x.
***Function module to open the Spool Job
  CALL FUNCTION 'FP_JOB_OPEN'
    CHANGING
      ie_outputparams = ls_fp_outputparams
    EXCEPTIONS
      cancel          = 1
      usage_error     = 2
      system_error    = 3
      internal_error  = 4
      OTHERS          = 5.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
Regards,
Raj

Answer 1

Image of Employee
      CALL FUNCTION 'HR_IMAGE_EXISTS'
        EXPORTING
          p_pernr               = wa_itab-pernr
        IMPORTING
          p_connect_info        = p_connect_info
        EXCEPTIONS
          error_connectiontable = 1
          OTHERS                = 2.
      IF sy-subrc = 0.
        CALL FUNCTION 'SCMS_DOC_READ'
          EXPORTING
            stor_cat              = space
            crep_id               = p_connect_info-archiv_id
            doc_id                = p_connect_info-arc_doc_id
          TABLES
            access_info           = lt_infos
            content_bin           = lt_image_bin
          EXCEPTIONS
            bad_storage_type      = 1
            bad_request           = 2
            unauthorized          = 3
            comp_not_found        = 4
            not_found             = 5
            forbidden             = 6
            conflict              = 7
            internal_server_error = 8
            error_http            = 9
            error_signature       = 10
            error_config          = 11
            error_format          = 12
            error_parameter       = 13
            error                 = 14
            OTHERS                = 15.
        IF sy-subrc = 0.
          READ TABLE lt_infos INDEX 1 ASSIGNING <fs_info>.
          IF sy-subrc = 0.
            CALL FUNCTION 'SCMS_BINARY_TO_XSTRING'
              EXPORTING
                input_length = <fs_info>-comp_size
                first_line   = <fs_info>-first_line
                last_line    = <fs_info>-last_line
              IMPORTING
                buffer       = l_employee_photo_content
              TABLES
                binary_tab   = lt_image_bin
              EXCEPTIONS
                failed       = 1
                OTHERS       = 2.
            IF sy-subrc = 0.
              wa_itab-pic = l_employee_photo_content.
            ENDIF.
          ENDIF.
        ENDIF.
      ENDIF.
      MODIFY itab FROM wa_itab.