EREC: Stars disappear when assigment page is refreshed.

Question

Hi Experts,
I am really stuck on this and hope someone guides me.
I am facing problem in Assignment page for the requisition. Where ranking details are displayed and stars are visible for the listed candidates. When assignment page is refreshed, stars which were visible earlier will disappear.
Why refreshing making the ranking stars to disappear? Is there any note to address this issue? Please help out.
Regards
Savitha
Edited by: SAPHCMRR on Aug 4, 2011 12:46 PM
Edited by: SAPHCMRR on Aug 5, 2011 9:18 AM

Answer 1

Hello Savitha,
Note 1124565 originally had a correction instruction for EHP4 although this was not necessary (because the changes have been implemented before EHP4 was shipped). One of my colleagues came across this fact and we deleted the correction instruction for EHP4.
It seems like someone tried to reapply the note in your system after it has been changed and that during this the LOOP-statement got lost. I had a look at the version history of GET_AUTO_SRCH_LST_BY_CDCY_LST and to me it seems like the coding had been there correctly (in the initial version 1), most probably because it was part of the initial shipment of EHP4.
the code should be like this :
method get_auto_srch_lst_by_cdcy_lst.
  data: lt_hit_list             type rcf_t_hitlist_with_rankv,
        ls_srch_mtch            type rcf_s_hitlist_with_rankv,
        lt_cdcy_list            type rcf_t_assignments,
        ls_cdcy_list            type rcf_s_assignments,
        ls_hidden_info          type rcf_s_name_value,
        lt_hidden_info          type rcf_t_name_value,
        lo_ex                   type ref to cx_hrrcf,
        lv_is_ranking_supported type boole_d.
  field-symbols: <ls_cdcy_slct> type rcf_s_mass_proc_activities,
                 <ls_hit_list>  type rcf_s_hitlist_with_rankv.
  clear pt_srch_mtch_list_slct.
check if attribute ranking is supported
  if cl_hrrcf_switch_check=>hrerc_sfws_ui_enh_03( ) eq true.
    call function 'HR_RCF_CHECK_TREX_VERSION'
      importing
        ev_ranking_supported = lv_is_ranking_supported.
  endif.
  ls_hidden_info-fieldname  = 'REQUISITION'.
  ls_hidden_info-fieldvalue = ps_req_hrobject.
  append ls_hidden_info to lt_hidden_info.
  loop at pt_cdcy_list_slct assigning <ls_cdcy_slct>.
    ls_cdcy_list-cdcy_object = <ls_cdcy_slct>-hrobject.
    append ls_cdcy_list to lt_cdcy_list.
  endloop.
  unassign <ls_cdcy_slct>.
  try.
      call method cl_hrrcf_search_match_bl=>get_auto_srch_lst
        exporting
          p_search_compid    = p_search_compid
          ps_hrobject        = ps_req_hrobject
          pt_hidden_info_tab = lt_hidden_info
        importing
          pt_hit_list        = lt_hit_list
        changing
          pt_cdcy_list       = lt_cdcy_list.
      if lv_is_ranking_supported eq false.
        sort lt_hit_list by hrobject.
        loop at pt_cdcy_list_slct assigning <ls_cdcy_slct>.
          ls_srch_mtch-hrobject = <ls_cdcy_slct>-hrobject.
          read table lt_hit_list assigning <ls_hit_list>
            with key hrobject = <ls_cdcy_slct>-hrobject
            binary search.
          if sy-subrc eq 0.
            ls_srch_mtch-rankv = <ls_hit_list>-rankv.
          endif.
          append ls_srch_mtch to pt_srch_mtch_list_slct.
          clear: ls_srch_mtch.
        endloop.
      else.
        pt_srch_mtch_list_slct = lt_hit_list.
      endif.
    catch cx_hrrcf into lo_ex.
      raise exception type cx_hrrcf
        exporting
          previous = lo_ex.
  endtry.
endmethod.