Error Message in Bulk Exception.

Question

Hi
When i use a normal Exception, the SQLERRM gives me the complete error along with the column name.
Ex :
ORA-01400: cannot insert NULL into ("BENCHMARK"."T6"."X")
But
When i Use Bulk_Exception, SQLERRM does not give me the complete error along with column name.
Ex:
ORA-01400: cannot insert NULL into ()
Is it that Bulk_exception error messages are less informative. These error messages, does not help me in finding out which column is violation the NOT NULL constraint and hence they actually make no sense.
Is there any way, through which i can get the complete error message as i get in the normal exception.
I am using 9i version.
Regards
Nikhil

Answer 1

I couldn't find exact solution to your problem, but one idea that came to mind, is resubmit statement with problematic rows (without using bulk processing) and save error messages.
SQL> declare
  2    bulk_errors exception;
  3    pragma exception_init ( bulk_errors, -24381 );
  4   
  5    j number;   
  6   
  7    type numbers is table of number;
  8    ids numbers;
  9  begin
10    select case when mod(abs(dbms_random.random),3)=0 then null else 1 end id bulk collect into ids
11      from dual
12    connect by level < 10;
13   
14    forall i in ids.first .. ids.last save exceptions
15      insert into test01 values ( ids(i) );
16    exception when bulk_errors then
17       for i in 1..sql%bulk_exceptions.count loop
18         j := sql%bulk_exceptions(i).error_index;
19         begin
20            insert into test01 values ( ids(j) );
21         exception when others then
22            dbms_output.put_line( 'Row #'||j||'. '||substr(sqlerrm,1,instr(sqlerrm,chr(10))-1) );
-- substr to get only the first line
23         end;
24       end loop;
25  end;
26  /
Row #1. ORA-01400: cannot insert NULL into ("SCOTT"."TEST01"."ID")
Row #3. ORA-01400: cannot insert NULL into ("SCOTT"."TEST01"."ID")
Row #6. ORA-01400: cannot insert NULL into ("SCOTT"."TEST01"."ID")
Row #7. ORA-01400: cannot insert NULL into ("SCOTT"."TEST01"."ID")
Row #8. ORA-01400: cannot insert NULL into ("SCOTT"."TEST01"."ID")
Row #9. ORA-01400: cannot insert NULL into ("SCOTT"."TEST01"."ID")