Error calling methods CL_GUI_FRONTEND_SERVICES

Question

Hi all,
I have a requirement in BAPI (integrating solman to portal) to download file from app. server to local directory. I used the below FM to get temp directory of presntation server.
CALL METHOD CL_GUI_FRONTEND_SERVICES=>GET_TEMP_DIRECTORY
   CHANGING
     TEMP_DIR             =  LV_TEMP_DIR
   EXCEPTIONS
     CNTL_ERROR           = 1
     ERROR_NO_GUI         = 2
     NOT_SUPPORTED_BY_GUI = 3
     others               = 4.
   CALL METHOD cl_gui_cfw=>flush.
It works fine in R3, but when i called it from portal it shows Access not possible using 'NULL' object reference with a short dump .
st22 shows
Error in ABAP application program.
The current ABAP program "CL_GUI_FRONTEND_SERVICES======CP" had to be
terminated because one of the
statements could not be executed.
This is probably due to an error in the ABAP program.
An exception occurred. This exception is dealt with in more detail belo
. The exception, which is assigned to the class 'CX_SY_REF_IS_INITIAL',
neither
caught nor passed along using a RAISING clause, in the procedure
"GET_TEMP_DIRECTORY" "(METHOD)"
Since the caller of the procedure could not have expected this exceptio
to occur, the running program was terminated.
The reason for the exception is:
Attempt to access a component using 'NULL' object reference (points
to nothing).
An object reference must point to an object (an instance of a class)
before you can use it to access components (variable:
"CL_GUI_FRONTEND_SERVICES=>HANDLE").
Either the reference has not yet been set, or it has been reset to
'NULL' by a CLEAR statement.
When i put external break point and the dump comes during execution of CALL METHOD cl_gui_cfw=>flush.
Is it not possible to use CL_GUI_FRONTEND_SERVICES in RFC ??.
thanks and regards
Jijo

Answer 1

Hi,
the dump is because you cannot use that function from a BSP application, which runs in internet or intranet. The procedure in this case is different:
DATA: flights  TYPE flighttab,
        flight   LIKE LINE OF flights,
        appl     TYPE string,
        filetype TYPE string,
        output   TYPE string,
        output2  TYPE xstring,
        response     TYPE REF TO if_http_response,
        l_len        TYPE i,
        seatsmax     TYPE string,
        seatsocc     TYPE string.
  appl = 'application/msexcel'.
  filetype = 'attachment;filename=mi archivo.xls'.
  SELECT * FROM sflight
     INTO TABLE flights
     UP TO 20 ROWS.
  LOOP AT flights INTO flight.
    seatsmax = flight-seatsmax. CONDENSE seatsmax.
    seatsocc = flight-seatsocc. CONDENSE seatsocc.
    CONCATENATE output
    flight-carrid cl_abap_char_utilities=>horizontal_tab
    flight-connid cl_abap_char_utilities=>horizontal_tab
    flight-fldate cl_abap_char_utilities=>horizontal_tab
    flight-planetype cl_abap_char_utilities=>horizontal_tab
    seatsmax cl_abap_char_utilities=>horizontal_tab
    seatsocc cl_abap_char_utilities=>horizontal_tab
    cl_abap_char_utilities=>cr_lf
    INTO output.
  ENDLOOP.
  response = runtime->server->response.
  response->delete_header_field( name = if_http_header_fields=>cache_control ).
  response->delete_header_field( name = if_http_header_fields=>expires ).
  response->delete_header_field( name = if_http_header_fields=>pragma ).
  response->set_header_field( name = if_http_header_fields=>content_type
                              value = appl ).
  response->set_header_field( name = 'content-disposition'
                              value = filetype ).
  CALL FUNCTION 'SCMS_STRING_TO_XSTRING'
    EXPORTING
      text     = output
      mimetype = 'text/unicode; charset=utf-16le'
    IMPORTING
      buffer   = output2.
  CONCATENATE cl_abap_char_utilities=>byte_order_mark_little
              output2 INTO output2 IN BYTE MODE.
  l_len = XSTRLEN( output2 ).
  response->set_data( data = output2
                      length = l_len ).
  navigation->response_complete( ).
This is the code for downloading an Excel file.