Error in procedure ( Anonymous block )

Question

Hello Friends,
This question seems to be simple but ..
I am having a pl/sql block as follows ..
==========================
DECLARE
CURSOR C_CUR IS SELECT X_PRCS_STYP_NM, X_CNTL_PARM1_TX,TO_DATE(X_CNTL_PARM_TM) X_AS_OF_DATE , X_CNTL_INDICR1_FL FROM KAW_OWNER.X_PRCS_CNTL;
v_sql_stmt VARCHAR2(32000);
v_cnt NUMBER := 0;
v_max_count NUMBER := 1000000;
v_err_code NUMBER;
v_err_msg VARCHAR2(200);
BEGIN
FOR rec IN C_CUR LOOP
IF (( rec.X_CNTL_INDICR1_FL='Y' OR rec.X_CNTL_INDICR1_FL='y' ) AND ( rec.X_PRCS_STYP_NM = 'INSERT' OR rec.X_PRCS_STYP_NM = 'insert' )) THEN
v_sql_stmt := 'INSERT INTO '|| 'KAW_OWNER.'|| 'T_'||rec.X_CNTL_PARM1_TX||' '|| ' SELECT * '|| ' FROM '||' KAW_OWNER.'|| rec.X_CNTL_PARM1_TX ||
' WHERE X_AS_OF_DATE = ' ||rec.X_AS_OF_DATE ;
dbms_output.put_line ( v_sql_stmt ) ;
END IF;
END LOOP;
END;
=====================
output
INSERT INTO KAW_OWNER.T_FINANCIAL_ADVISOR_X_ACCOUNT SELECT * FROM KAW_OWNER.FINANCIAL_ADVISOR_X_ACCOUNT WHERE X_AS_OF_DATE = 01-JAN-11
=======================================================
when i take the query ..and run
SELECT * FROM KAW_OWNER.FINANCIAL_ADVISOR_X_ACCOUNT WHERE X_AS_OF_DATE = 01-JAN-11
I got the error as 'ORA-00904 "JAN" :invalid identifier
but when i run the query as
SELECT * FROM KAW_OWNER.FINANCIAL_ADVISOR_X_ACCOUNT WHERE X_AS_OF_DATE = '01-JAN-11'
am getting records .
my question is : How to have '01-JAN-11' as an output of the pl/sql block..
thanks / kumar

Answer 1

Hi,
I am not sure about your requirements.
try this,
DECLARE
   CURSOR C_CUR
   IS
      SELECT X_PRCS_STYP_NM
            ,X_CNTL_PARM1_TX
            ,TO_CHAR (X_CNTL_PARM_TM, 'DD-MON-YYYY') X_AS_OF_DATE
            ,X_CNTL_INDICR1_FL
        FROM KAW_OWNER.X_PRCS_CNTL;
   v_sql_stmt     VARCHAR2 (32000);
   v_cnt          NUMBER := 0;
   v_max_count    NUMBER := 1000000;
   v_err_code     NUMBER;
   v_err_msg      VARCHAR2 (200);
BEGIN
   FOR rec IN C_CUR
   LOOP
      IF ( (rec.X_CNTL_INDICR1_FL = 'Y'
            OR rec.X_CNTL_INDICR1_FL = 'y')
          AND (rec.X_PRCS_STYP_NM = 'INSERT'
               OR rec.X_PRCS_STYP_NM = 'insert'))
      THEN
         v_sql_stmt  :=
               'INSERT INTO '
            || 'KAW_OWNER.'
            || 'T_'
            || rec.X_CNTL_PARM1_TX
            || ' '
            || ' SELECT * '
            || ' FROM '
            || ' KAW_OWNER.'
            || rec.X_CNTL_PARM1_TX
            || ' WHERE X_AS_OF_DATE = TO_DATE('''
            || rec.X_AS_OF_DATE
            || ''',''DD-MON-YYYY'')';
      DBMS_OUTPUT.put_line (v_sql_stmt);
      END IF;
   END LOOP;
END;This is just to make sure that the query printed out will work manually. I would advice you to use bind variables when using execute immediate. Like this
DECLARE
   CURSOR C_CUR
   IS
      SELECT X_PRCS_STYP_NM
            ,X_CNTL_PARM1_TX
            ,X_CNTL_PARM_TM X_AS_OF_DATE
            ,X_CNTL_INDICR1_FL
        FROM KAW_OWNER.X_PRCS_CNTL;
   v_sql_stmt     VARCHAR2 (32000);
   v_cnt          NUMBER := 0;
   v_max_count    NUMBER := 1000000;
   v_err_code     NUMBER;
   v_err_msg      VARCHAR2 (200);
BEGIN
   FOR rec IN C_CUR
   LOOP
      IF ( (rec.X_CNTL_INDICR1_FL = 'Y'
            OR rec.X_CNTL_INDICR1_FL = 'y')
          AND (rec.X_PRCS_STYP_NM = 'INSERT'
               OR rec.X_PRCS_STYP_NM = 'insert'))
      THEN
         v_sql_stmt  :=
               'INSERT INTO '
            || 'KAW_OWNER.'
            || 'T_'
            || rec.X_CNTL_PARM1_TX
            || ' '
            || ' SELECT * '
            || ' FROM '
            || ' KAW_OWNER.'
            || rec.X_CNTL_PARM1_TX
            || ' WHERE X_AS_OF_DATE = :v_as_of_date';
         EXECUTE IMMEDIATE v_sql_stmt USING rec.X_AS_OF_DATE;
      END IF;
   END LOOP;
END;G.