Error when defining a program executable

Question

Could anybody explain the following error, which appears when I attempt to define an executable, GLCRVL against a program (GLCRVL2). Appears when closing the "Concurrent Program Executable" form:
*"APP-FND-00508: Please enter a unique execution file name that is not already in use for your application"*
The executable in question is
/opt/oracle/DOLNSGC3/apps_11i/appl/gl/11.5.0/bin/GLCRVL
I made a copy of the GLCRVL spawned program, which now exists in FND_CONCURRENT_PROGRAMS AS
SQL> select application_id AS APP_ID
2 ,concurrent_program_id AS CP_ID
3 ,concurrent_program_name AS CP_NAME
4 ,executable_application_id AS EXA_ID
5 ,executable_id AS EX_ID
6 ,execution_method_code AS EXM_CODE
7 ,argument_method_code AS AM_CODE
8 ,enabled_flag
9 from FND_CONCURRENT_PROGRAMS
10 where CONCURRENT_PROGRAM_NAME in ('GLCRVL', 'GLCRVL2')
11 /
APP_ID CP_ID CP_NAME XA_ID EX_ID E A E
101 20397 GLCRVL 101 149 A D Y
101 45769 GLCRVL2 101 149 A D Y
Running 11.5.0 on Sun Solaris with 64-bit 10.2.0.4.0 Oracle DB Server

Answer 1

Hi all,
not sure if any of you are still watching this one, but I thought I'd update you on some good progress! I managed to get a spawned process working by registering it using the PL/SQL API, as follows:
set serveroutput on
declare
  b_Continue boolean := true;
  v_Prg_Name        varchar2(20) := 'GL_REVAL';
  v_Exec_Name       varchar2(20) := 'GL_REVAL';
begin
  begin
    begin
      fnd_program.delete_executable(v_Exec_name, 'SQLGL');
      commit;
      dbms_output.put_line('executable ' || v_Exec_Name || ' removed from SQLGL');
      exception -- catch
        when others then
          null;
    end;
    fnd_program.executable(v_Exec_Name -- executable
                          , 'SQLGL' -- application
                          , v_Exec_Name -- short_name
                          , 'Backend program - Reval Balances' -- description
                          , 'Spawned' -- execution_method
                          , 'GLCRVL' -- execution_file_name
                          , null -- subroutine_name
                          , null -- Execution File Path
                          , 'US' -- language_code
                          , null);
    commit;
    b_Continue := true;
    dbms_output.put_line('Registration of executable ' || v_Exec_Name || ' sucessful');
    exception
      when others then
        rollback;
        dbms_output.put_line('Registration error for executable ' || v_Exec_Name || ', ' || sqlerrm);
  end;
  if (b_Continue) then
    begin
      begin
        fnd_program.delete_program(v_Prg_Name, 'SQLGL');
        commit;
        dbms_output.put_line('program ' || v_Prg_Name || ' in SQLGL removed');
        exception -- catch
          when others then
            null;
      end;
      fnd_program.register ( program                        => 'Program - Revalue Balances (Backend)'
                            ,application                    => 'SQLGL'
                            ,enabled                        => 'Y'
                            ,short_name                     => v_Prg_Name
                            ,description                    => 'Revalue Balances'
                            ,executable_short_name          => v_Exec_Name
                            ,executable_application         => 'SQLGL'
                            ,execution_options              => null
                            ,priority                       => null
                            ,save_output                    => 'Y'
                            ,print                          => 'Y'
                            ,cols                           => null
                            ,rows                           => null
                            ,style                          => null
                            ,style_required                 => 'N'
                            ,printer                        => null
                            ,request_type                   => null
                            ,request_type_application       => null
                            ,use_in_srs                     => 'Y'
                            ,allow_disabled_values          => 'N'
                            ,run_alone                      => 'N'
                            ,output_type                    => 'TEXT'
                            ,enable_trace                   => 'N'
                            ,restart                        => 'N'
                            ,nls_compliant                  => 'Y'
                            ,icon_name                      => null
                            ,language_code                  => 'US'
                            ,mls_function_short_name        => null
                            ,mls_function_application       => null
                            ,incrementor                    => null);
      commit;
      dbms_output.put_line('Registration of program ' || v_Prg_Name || ' sucessful');
      exception
        when others then
          b_Continue := false;
          rollback;
          dbms_output.put_line('Registration error for program GL_REVAL ' || sqlerrm);
    end;
  end if;
  if (b_Continue) then
    begin
      fnd_program.remove_from_group(v_Prg_Name, 'SQLGL', 'GL Concurrent Program Group', 'SQLGL');
      dbms_output.put_line('program ' || v_Prg_Name || ' removed from group "GL Concurrent_Group" in SQLGL');
      commit;
      exception
        when others then
          rollback;
          null;
    end;
    begin
      fnd_program.add_to_group(v_Prg_Name -- program_short_name
                             , 'SQLGL' -- application
                             , 'GL Concurrent Program Group' -- Request Group Name
                             , 'SQLGL'); -- Report Group Application
      commit;
      b_Continue := true;
      dbms_output.put_line('program, ' || v_Prg_Name || ', sucessfully added to group "GL Concurrent Program Group"');
      exception
        when others then
          b_Continue := false;
          rollback;
          dbms_output.put_line('Registration error for program ' || v_Prg_Name || ' in group' || sqlerrm);
    end;
  end if;
  begin
    if (b_Continue) then
      if (fnd_program.parameter_exists (v_Prg_Name, 'SQLGL', 'Set of Books ID') ) then
        fnd_program.delete_parameter(v_Prg_Name, 'SQLGL', 'Set of Books ID');
        commit;
        dbms_output.put_line('Parameter "Set of Books ID" removed');
      end if;
      if (fnd_program.parameter_exists (v_Prg_Name, 'SQLGL', 'Revaluation ID') ) then
        fnd_program.delete_parameter(v_Prg_Name, 'SQLGL', 'Revaluation ID');
        commit;
        dbms_output.put_line('Parameter "Revaluation ID" removed');
      end if;
      if (fnd_program.parameter_exists (v_Prg_Name, 'SQLGL', 'PERIOD') ) then
        fnd_program.delete_parameter(v_Prg_Name, 'SQLGL', 'PERIOD');
        commit;
        dbms_output.put_line('Parameter "PERIOD" removed');
      end if;
      if (fnd_program.parameter_exists (v_Prg_Name, 'SQLGL', 'EFFECTIVE_DATE') ) then
        fnd_program.delete_parameter(v_Prg_Name, 'SQLGL', 'EFFECTIVE_DATE');
        commit;
        dbms_output.put_line('Parameter "EFFECTIVE_DATE" removed');
      end if;
      if (fnd_program.parameter_exists (v_Prg_Name, 'SQLGL', 'RATE_DATE') ) then
        fnd_program.delete_parameter(v_Prg_Name, 'SQLGL', 'RATE_DATE');
        commit;
        dbms_output.put_line('Parameter "RATE_DATE" removed');
      end if;
      fnd_program.parameter (program_short_name            => v_Prg_Name
                            ,application                   =>  'SQLGL'
                            ,sequence                      => 10
                            ,parameter                     => 'Set Of Books ID'
                            ,description                   => null
                            ,enabled                       => 'Y'
                            ,value_set                     => 'GL_SRS_SET_OF_BOOKS'
                            ,default_type                  => 'S'
                            ,default_value                 => null
                            ,required                      => 'Y'
                            ,enable_security               => 'N'
                            ,range                         => null
                            ,display                       => 'N'
                            ,display_size                  => 30
                            ,description_size              => 50
                            ,concatenated_description_size => 25
                            ,prompt                        => 'Set Of Books'
                            ,token                         => '');
      dbms_output.put_line('Parameter "Set of Books ID" added');
      fnd_program.parameter (program_short_name            => v_Prg_Name
                            ,application                   =>  'SQLGL'
                            ,sequence                      => 20
                            ,parameter                     => 'Revaluation ID'
                            ,description                   => null
                            ,enabled                       => 'Y'
                            ,value_set                     => 'GL_SRS_REVAL_NAME'
                            ,default_type                  => 'S'
                            ,default_value                 => null
                            ,required                      => 'Y'
                            ,enable_security               => 'N'
                            ,range                         => null
                            ,display                       => 'Y'
                            ,display_size                  => 35
                            ,description_size              => 50
                            ,concatenated_description_size => 25
                            ,prompt                        => 'Revaluation'
                            ,token                         => '');
      dbms_output.put_line('Parameter "Revaluation ID" added');
      fnd_program.parameter (program_short_name            => v_Prg_Name
                            ,application                   =>  'SQLGL'
                            ,sequence                      => 30
                            ,parameter                     => 'PERIOD'
                            ,description                   => null
                            ,enabled                       => 'Y'
                            ,value_set                     => 'GL_SRS_REVAL_PERIOD'
                            ,default_type                  => null
                            ,default_value                 => null
                            ,required                      => 'Y'
                            ,enable_security               => 'N'
                            ,range                         => null
                            ,display                       => 'Y'
                            ,display_size                  => 15
                            ,description_size              => 50
                            ,concatenated_description_size => 25
                            ,prompt                        => 'Period'
                            ,token                         => '');
      dbms_output.put_line('Parameter "PERIOD" added');
      fnd_program.parameter (program_short_name            => v_Prg_Name
                            ,application                   =>  'SQLGL'
                            ,sequence                      => 40
                            ,parameter                     => 'EFFECTIVE_DATE'
                            ,description                   => null
                            ,enabled                       => 'Y'
                            ,value_set                     => 'GL_SRS_STANDARD_DATE'
                            ,default_type                  => 'S'
                            ,default_value                 => null
                            ,required                      => 'Y'
                            ,enable_security               => 'N'
                            ,range                         => null
                            ,display                       => 'Y'
                            ,display_size                  => 11
                            ,description_size              => 50
                            ,concatenated_description_size => 25
                            ,prompt                        => 'Effective Date'
                            ,token                         => '');
      dbms_output.put_line('Parameter "EFFECTIVE_DATE" added');
      fnd_program.parameter (program_short_name            => v_Prg_Name
                            ,application                   =>  'SQLGL'
                            ,sequence                      => 50
                            ,parameter                     => 'RATE_DATE'
                            ,description                   => null
                            ,enabled                       => 'Y'
                            ,value_set                     => 'GL_SRS_STANDARD_DATE'
                            ,default_type                  => 'A'
                            ,default_value                 => 'EFFECTIVE_DATE.VALUE'
                            ,required                      => 'N'
                            ,enable_security               => 'N'
                            ,range                         => null
                            ,display                       => 'Y'
                            ,display_size                  => 11
                            ,description_size              => 50
                            ,concatenated_description_size => 25
                            ,prompt                        => 'Rate Date'
                            ,token                         => '');
      dbms_output.put_line('Parameter "RATE_DATE" added');
      commit;
      dbms_output.put_line(' ');
      dbms_output.put_line('All parameters added sucessfully ');
      b_Continue := true;
    end if; -- if (b_Continue) then
    exception
      when others then
        rollback;
        b_Continue := false;
        dbms_output.put_line('Error adding parameters ');
  end;
  if (b_Continue) then
    dbms_output.put_line('All registration was sucessful');
  else
    dbms_output.put_line('Registration unsucessful');
  end if;
  exception
    when others then
      rollback;
      dbms_output.put_line('Registration Error ' || sqlerrm);
end;
show errI then ran a test using the following script, and it seems to work!!!
set serveroutput on
declare
  b_Set_NLS         boolean;
  b_Wait            boolean;
  n_Request_ID      number;
  p_Language        varchar2(20) := 'AMERICAN';
  v_Phase           varchar2(100);
  v_Status          varchar2(100);
  v_Dev_Phase       varchar2(100);
  v_Dev_Status      varchar2(100);
  v_Message         varchar2(100);
  FND_EXCEPTION     exception;
  v_FND_EXC         varchar2(50);
  v_Prg_Name        varchar2(20) := 'GL_REVAL';
begin
  fnd_global.apps_initialize(1208, 50211, 101);
  fnd_program.enable_program(v_Prg_Name, 'SQLGL', 'Y');
  if not (fnd_program.executable_exists(v_Prg_Name, 'SQLGL') ) then
    v_FND_EXC := 'App ' || v_Prg_Name || ' does not exist';
    raise FND_EXCEPTION;
  end if;
  dbms_session.set_nls(param => 'nls_language'
                      ,value => p_Language);
  b_Set_NLS := fnd_submit.set_nls_options(p_Language);
  -- Test parameters
  n_Request_ID := fnd_request.submit_request( application => 'SQLGL'
                                             ,program     => v_Prg_Name
                                             ,description => 'Program - Revalue Balances (Backend)'
                                             ,start_time  => ''
                                             ,sub_request => false
                                             ,argument1   => '2'
                                             ,argument2   => '10060' --p_Revaluation_ID
                                             ,argument3   => 'Oct-09' --p_Period
                                             ,argument4   => '2009/10/31 00:00:00'
                                             --,argument5   => p_Rate_Date
  if (n_Request_ID > 0) then
    commit;
    b_Wait := fnd_concurrent.wait_for_request(request_id => n_Request_ID
                                             ,interval   => 60
                                             ,max_wait   => 0
                                             ,phase      => v_Phase
                                             ,status     => v_Status
                                             ,dev_phase  => v_Dev_Phase
                                             ,dev_status => v_Dev_Status
                                             ,message    => v_Message);
    v_FND_EXC := v_Dev_Status;
    if (v_Dev_Phase = 'COMPLETE') then
      case v_Dev_Status
        when 'WARNING' then
          raise FND_EXCEPTION;
        when 'ERROR' then
          raise FND_EXCEPTION;
        when 'NORMAL' then
          null;
        else
          v_FND_EXC := 'UNKNOWN';
          raise FND_EXCEPTION;
      end case;
    else
      v_FND_EXC := 'INCOMPLETE,' || v_Dev_Phase;
      raise FND_EXCEPTION;
    end if;
  end if;
  -- No Request ID has been returned by FND_REQUEST.SUBMIT_REQUEST or FND_SUBMIT.SUBMIT_SET
  if (n_Request_ID = 0) then
    v_FND_EXC := 'SUBMISSION FAILURE';
    raise FND_EXCEPTION;
  end if;
  dbms_output.put_line(v_Prg_Name || ' ran fine ');
exception
  when FND_EXCEPTION then
    dbms_output.put_line('Request Exception, ' || v_FND_EXC);
  when others then
    v_FND_EXC := 'UNKNOWN';
    dbms_output.put_line(v_FND_EXC || ' ' || sqlerrm);
end;
/Cheers!
P;