Execute an ABAP ".txt" file with a call function

Question

Hello,
I'd like to know if it exist a "call function" or another way to execute an Abap program which is written within a ".txt" file.
1. I'd like to write an Abap program into a ".txt" file
2. Create an Abap program which will read the ".txt" file (& upload it into an internal table for example) & execute this Abap code.
Is it possible?
Thanks in advance for your answer.
Samuel

Answer 1

Something like this -:)
REPORT z_test_query.
* TYPES                                                           *
TYPES: BEGIN OF ty_lines,
       line TYPE string,
       END OF ty_lines.
* TABLAS INTERNAS                                                 *
DATA: t_lines TYPE STANDARD TABLE OF ty_lines,
      t_program TYPE STANDARD TABLE OF progtab WITH HEADER LINE,
      t_writes TYPE STANDARD TABLE OF listzeile.
* VARIABLES                                                       *
DATA: w_file_name TYPE string.
* FIELD-SYMBOLS                                                   *
FIELD-SYMBOLS: <fs_lines> LIKE LINE OF t_lines,
               <fs_write> LIKE LINE OF t_writes.
* SELECTION-SCREEN                                                *
SELECTION-SCREEN BEGIN OF BLOCK file WITH FRAME.
PARAMETERS:
            p_file TYPE rlgrap-filename.
SELECTION-SCREEN END OF BLOCK file.
* AT SELECTION-SCREEN ON VALUE-REQUEST                            *
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
  PERFORM get_filename CHANGING p_file.
*&      Form  GET_FILENAME                                        *
FORM get_filename CHANGING po_p_file.
  DATA: ls_field_name TYPE dynpread-fieldname.
  ls_field_name = 'P_FILE'.
  CALL FUNCTION 'F4_FILENAME'
       EXPORTING
            program_name  = syst-cprog
            dynpro_number = syst-dynnr
            field_name    = ls_field_name
       IMPORTING
            file_name     = po_p_file.
  w_file_name = po_p_file.
ENDFORM.                    " GET_FILENAME
*   START-OF-SELECTION                                            *
START-OF-SELECTION.
  CALL FUNCTION 'GUI_UPLOAD'
       EXPORTING
            filename = w_file_name
       TABLES
            data_tab = t_lines.
  IF sy-subrc EQ 0.
    LOOP AT t_lines ASSIGNING <fs_lines>.
      MOVE <fs_lines>-line TO t_program-line.
      APPEND t_program.
    ENDLOOP.
  ENDIF.
  CALL FUNCTION 'RFC_ABAP_INSTALL_AND_RUN'
       EXPORTING
            mode        = 'F'
            programname = 'ZDUMMY_TEST'
       TABLES
            program     = t_program
            writes      = t_writes.
  IF sy-subrc EQ 0.
    LOOP AT t_writes ASSIGNING <fs_write>.
      WRITE:/ <fs_write>-zeile.
    ENDLOOP.
  ENDIF.
Greetings,
Blag.