Fetch cursor with a variable column number

Question

Hello guys,
this is the first time I write to this forum, as far as I remember. hence, if this is not the right place to ask this question, please point me to the right resource.
I have the following Procedure (the function split splits a string into an array):
BEGIN
/* SPLIT IN GROUPS AND BUILD THE PARAMETER STRINGS */
tokens_in := string_fnc.split(in_groups, '.');
for i in 1..tokens_in.count loop
IDX_REM := i;
sql_par1 := sql_par1 || ', GRP' || i || '.NAME "GROUP_' || i || '"';
sql_par2 := sql_par2 || ', DEV_XCSA.WFA_GROUP GRP' || i;
IF i = 1 THEN
sql_par3 := sql_par3 || ' AND S.ID = GRP1.FK_PARENT_SEC_ID ';
ELSE
sql_par3 := sql_par3 || ' AND GRP' || i || '.FK_PARENT_GROUP_ID ( + ) = GRP' || (i-1) || '.ID';
END IF;
end loop;
sql_par3 := sql_par3 || ' AND SGQ.FK_GROUP_ID ( + ) = GRP' || IDX_REM || '.ID';
/* BUILD THE QUERY STRING */
sql_stmt := 'SELECT A.NAME "APPRAISAL" , AQ.NAME "PROJECT" , S.NAME "SECTION"';
sql_stmt := sql_stmt || sql_par1;
sql_stmt := sql_stmt || ', SGQ.NAME "QUESTION" , SGQ.VALUE "ANSWER"     FROM DEV_XCSA.WFA_APPRAISAL A, DEV_XCSA.WFA_QUESTIONNAIRE AQ, DEV_XCSA.WFA_SECTION S';
sql_stmt := sql_stmt || sql_par2;                                             
sql_stmt := sql_stmt || ', DEV_XCSA.WFA_QUESTION SGQ WHERE A.CPHID = ''' ||USER_NAME || ''' AND A.ID = AQ.FK_APPRAISAL_ID     AND AQ.ID = S.FK_QUESTIONNAIRE_ID';
sql_stmt := sql_stmt || sql_par3;                                             
/* RUN THE QUERY */
OPEN QUEST_CUR FOR sql_stmt;
You can see that now the select statement has a variable number of return columns.
I would like to fetch the result of the query in a loop assigning the records to variables or to a record variable.
But after reading the documentation it looks that I can only declare record variables before the query string is built and there is not an easy way to fetch a cursor into a variable number of variables.
Is it possible to do what I am trying to do? Can you suggest a better approach?
Please help me,
TN

Answer 1

Tremal Naik wrote:
Ok, thanks to you both.
Please, bear in mind that I am really a PL/SQL novice and I may have misunderstood BluShadow's hints.
I will have a closer look at it and let you know my thoughts.Here's a cleaner commented example that should help you to understand what it's doing...
SQL> CREATE OR REPLACE PROCEDURE run_query(p_sql IN VARCHAR2) IS
  2    v_v_val     VARCHAR2(4000);
  3    v_n_val     NUMBER;
  4    v_d_val     DATE;
  5    v_ret       NUMBER;
  6    c           NUMBER;
  7    d           NUMBER;
  8    col_cnt     INTEGER;
  9    f           BOOLEAN;
10    rec_tab     DBMS_SQL.DESC_TAB;
11    col_num     NUMBER;
12    v_rowcount  NUMBER := 0;
13  BEGIN
14    -- create a cursor
15    c := DBMS_SQL.OPEN_CURSOR;
16    -- parse the SQL statement into the cursor
17    DBMS_SQL.PARSE(c, p_sql, DBMS_SQL.NATIVE);
18    -- execute the cursor
19    d := DBMS_SQL.EXECUTE(c);
20    --
21    -- Describe the columns returned by the SQL statement
22    DBMS_SQL.DESCRIBE_COLUMNS(c, col_cnt, rec_tab);
23    --
24    -- Bind local return variables to the various columns based on their types
25    FOR j in 1..col_cnt
26    LOOP
27      CASE rec_tab(j).col_type
28        WHEN 1 THEN DBMS_SQL.DEFINE_COLUMN(c,j,v_v_val,2000); -- Varchar2
29        WHEN 2 THEN DBMS_SQL.DEFINE_COLUMN(c,j,v_n_val);      -- Number
30        WHEN 12 THEN DBMS_SQL.DEFINE_COLUMN(c,j,v_d_val);     -- Date
31      ELSE
32        DBMS_SQL.DEFINE_COLUMN(c,j,v_v_val,2000);  -- Any other type return as varchar2
33      END CASE;
34    END LOOP;
35    --
36    -- Display what columns are being returned...
37    FOR j in 1..col_cnt
38    LOOP
39      DBMS_OUTPUT.PUT_LINE(rec_tab(j).col_name||' - '||case rec_tab(j).col_type when 1 then 'VARCHAR2'
40                                                                                when 2 then 'NUMBER'
41                                                                                when 12 then 'DATE'
42                                                       else 'Other' end);
43    END LOOP;
44    --
45    -- This part outputs the DATA
46    LOOP
47      -- Fetch a row of data through the cursor
48      v_ret := DBMS_SQL.FETCH_ROWS(c);
49      -- Exit when no more rows
50      EXIT WHEN v_ret = 0;
51      v_rowcount := v_rowcount + 1;
52      DBMS_OUTPUT.PUT_LINE('Row: '||v_rowcount);
53      DBMS_OUTPUT.PUT_LINE('--------------');
54      -- Fetch the value of each column from the row
55      FOR j in 1..col_cnt
56      LOOP
57        -- Fetch each column into the correct data type based on the description of the column
58        CASE rec_tab(j).col_type
59          WHEN 1  THEN DBMS_SQL.COLUMN_VALUE(c,j,v_v_val);
60                       DBMS_OUTPUT.PUT_LINE(rec_tab(j).col_name||' : '||v_v_val);
61          WHEN 2  THEN DBMS_SQL.COLUMN_VALUE(c,j,v_n_val);
62                       DBMS_OUTPUT.PUT_LINE(rec_tab(j).col_name||' : '||v_n_val);
63          WHEN 12 THEN DBMS_SQL.COLUMN_VALUE(c,j,v_d_val);
64                       DBMS_OUTPUT.PUT_LINE(rec_tab(j).col_name||' : '||to_char(v_d_val,'DD/MM/YYYY HH24:MI:SS'));
65        ELSE
66          DBMS_SQL.COLUMN_VALUE(c,j,v_v_val);
67          DBMS_OUTPUT.PUT_LINE(rec_tab(j).col_name||' : '||v_v_val);
68        END CASE;
69      END LOOP;
70      DBMS_OUTPUT.PUT_LINE('--------------');
71    END LOOP;
72    --
73    -- Close the cursor now we have finished with it
74    DBMS_SQL.CLOSE_CURSOR(c);
75  END;
76  /
Procedure created.
SQL> exec run_query('select empno, ename, deptno from emp where deptno = 10');
EMPNO - NUMBER
ENAME - VARCHAR2
DEPTNO - NUMBER
Row: 1
EMPNO : 7782
ENAME : CLARK
DEPTNO : 10
Row: 2
EMPNO : 7839
ENAME : KING
DEPTNO : 10
Row: 3
EMPNO : 7934
ENAME : MILLER
DEPTNO : 10
PL/SQL procedure successfully completed.
SQL> exec run_query('select * from emp where deptno = 10');
EMPNO - NUMBER
ENAME - VARCHAR2
JOB - VARCHAR2
MGR - NUMBER
HIREDATE - DATE
SAL - NUMBER
COMM - NUMBER
DEPTNO - NUMBER
Row: 1
EMPNO : 7782
ENAME : CLARK
JOB : MANAGER
MGR : 7839
HIREDATE : 09/06/1981 00:00:00
SAL : 2450
COMM :
DEPTNO : 10
Row: 2
EMPNO : 7839
ENAME : KING
JOB : PRESIDENT
MGR :
HIREDATE : 17/11/1981 00:00:00
SAL : 5000
COMM :
DEPTNO : 10
Row: 3
EMPNO : 7934
ENAME : MILLER
JOB : CLERK
MGR : 7782
HIREDATE : 23/01/1982 00:00:00
SAL : 1300
COMM :
DEPTNO : 10
PL/SQL procedure successfully completed.
SQL> exec run_query('select * from dept where deptno = 10');
DEPTNO - NUMBER
DNAME - VARCHAR2
LOC - VARCHAR2
Row: 1
DEPTNO : 10
DNAME : ACCOUNTING
LOC : NEW YORK
PL/SQL procedure successfully completed.
SQL>As you can see, you can use DBMS_SQL to query any SQL string you like, regardless of the number of returned columns and their datatypes and the DBMS_SQL package can tell your code all the information it needs to know so that it can read the names, datatypes and data from that query.