Fill Blank Cells in Column

Question

I have a spreadsheet given to me that is a list. Column A is a nominal or catergorical variable (imagine something like "Nationality") and column B is a ratio variable (imagine something like "height").
Unfortunately not all of the rows have data filled out column A. The issue is identical to the one presented here in MS Excel: http://www.contextures.com/xlDataEntry02.html
I would like to calculate averages for the subgroups in column A. I could do this manually be selecting each range of data in column B, but with thousands of cells and many subcategories, it would take a long time. From what I can see Numbers "categories" function won't work as I would like if there are blank cells, so it seems I would need to fill in the blank data, to make a proper nominalised database list. Rather than do this manually with manual fills, is there a way to do it programatically? I can't manage the trick for MS Excel in the aforementioned website, as Numbers only allows filtering for blank cells, rather than selecting blank cells.
I hope someone can help.

Answer 1

And now, the script :
--[SCRIPT fillblankcells]
Enregistrer le script en tant que Script : fillblankcells.scpt
déplacer le fichier ainsi créé dans le dossier
<VolumeDeDémarrage>:Users:<votreCompte>:Library:Scripts:Applications:Numbers:
Il vous faudra peut-être créer le dossier Numbers et peut-être même le dossier Applications.
Sélectionner une cellule dans la colonne à compléter.
menu Scripts > Numbers > fillblankcells
Si une cellule de la colonne est vide, le script l'alimente avec le contenu de la dernière cellule remplie qui la précéde.
--=====
L'aide du Finder explique:
L'Utilitaire AppleScript permet d'activer le Menu des scripts :
Ouvrez l'Utilitaire AppleScript situé dans le dossier Applications/AppleScript.
Cochez la case "Afficher le menu des scripts dans la barre de menus".
--=====
Save the script as a Script: fillblankcells.scpt
Move the newly created file into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:Numbers:
Maybe you would have to create the folder Numbers and even the folder Applications by yourself.
Select a cell in the column to fill.
menu Scripts > Numbers > fillblankcells
The script will fill every blank cell of this column with the contents of the preceeding filled cell.
--=====
The Finder's Help explains:
To make the Script menu appear:
Open the AppleScript utility located in Applications/AppleScript.
Select the "Show Script Menu in menu bar" checkbox.
--=====
Yvan KOENIG (VALLAURIS, France)
2010/04/05
--=====
on run
set {dName, sName, tName, rname, rowNum1, colNum1, rowNum2, colNum2} to my getSelParams()
tell application "Numbers" to tell document dName to tell sheet sName to tell table tName to tell column colNum1
set maybe to ""
repeat with r from 2 to count of row
if not (value of cell r) = 0 then
set maybe to value of cell r
else
set value of cell r to maybe
end if
end repeat
end tell
end run
--=====
on getSelParams()
local r_Name, t_Name, s_Name, d_Name, col_Num1, row_Num1, col_Num2, row_Num2
set {d_Name, s_Name, t_Name, r_Name} to my getSelection()
if r_Name is missing value then
if my parleAnglais() then
error "No selected cells"
else
error "Il n'y a pas de cellule sélectionnée !"
end if
end if
set two_Names to my decoupe(r_Name, ":")
set {row_Num1, col_Num1} to my decipher(item 1 of two_Names, d_Name, s_Name, t_Name)
if item 2 of two_Names = item 1 of two_Names then
set {row_Num2, col_Num2} to {row_Num1, col_Num1}
else
set {row_Num2, col_Num2} to my decipher(item 2 of two_Names, d_Name, s_Name, t_Name)
end if
return {d_Name, s_Name, t_Name, r_Name, row_Num1, col_Num1, row_Num2, col_Num2}
end getSelParams
--=====
set {rowNumber, columnNumber} to my decipher(cellRef,docName,sheetName,tableName)
apply to named row or named column !
on decipher(n, d, s, t)
tell application "Numbers" to tell document d to tell sheet s to tell table t to return {address of row of cell n, address of column of cell n}
end decipher
--=====
set { d_Name, s_Name, t_Name, r_Name} to my getSelection()
on getSelection()
local _, theRange, theTable, theSheet, theDoc, errmsg, errNum
tell application "Numbers" to tell document 1
repeat with i from 1 to the count of sheets
tell sheet i
set x to the count of tables
if x > 0 then
repeat with y from 1 to x
try
(selection range of table y) as text
on error errmsg number errNum
set {_, theRange, _, theTable, _, theSheet, _, theDoc} to my decoupe(errmsg, quote)
return {theDoc, theSheet, theTable, theRange}
end try
end repeat -- y
end if -- x>0
end tell -- sheet
end repeat -- i
end tell -- document
return {missing value, missing value, missing value, missing value}
end getSelection
--=====
on decoupe(t, d)
local l
set AppleScript's text item delimiters to d
set l to text items of t
set AppleScript's text item delimiters to ""
return l
end decoupe
--=====
on parleAnglais()
local z
try
tell application "Numbers" to set z to localized string "Cancel"
on error
set z to "Cancel"
end try
return (z is not "Annuler")
end parleAnglais
--=====
--[/SCRIPT]
Yvan KOENIG (VALLAURIS, France) lundi 5 avril 2010 14:37:02