Filter Ascending only on the active cell.

Question

Hello Guys,
I was working on a macro to 
Step:-
1) Unprotect Worksheet
2) Autofilter the range and then filter ascending on the active cell.
3) Protect the worksheet again
here is the code :-
Sub Filter_ActiveCell()
    Dim Acell As String
    Acell = ActiveCell
        ActiveSheet.Unprotect Password:="bismillah1111"
        Rows("3:3").Select
        Selection.AutoFilter
' Here is where the problem lies.                
    ActiveWorkbook.Worksheets("Summary Sheet ").AutoFilter.Sort.SortFields.Add Key _
        :=Range(Acell), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _
        xlSortNormal
    With ActiveWorkbook.Worksheets("Summary Sheet ").AutoFilter.Sort
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    Selection.AutoFilter
    ActiveSheet.Protect Password:="bismillah1111"
End Sub
I am trying hard to understand but the variable doesn't work. this took 2 hours of mine but all in vain.
Can someone please help me in this.
Thanks,
Wasimali Bori

Answer 1

The line
Acell = ActiveCell
will set the variable Acell to the value of the active cell. One way to do what you want would be to set Acell to the
address of the active cell:
Acell = ActiveCell.Address
Another way would be
Sub Filter_ActiveCell()
    Dim Acell As Range
    Set Acell = ActiveCell
    ActiveSheet.Unprotect Password:="bismillah1111"
    Rows("3:3").Select
    Selection.AutoFilter
    ' Here is where the problem lies.
    ActiveSheet.AutoFilter.Sort.SortFields.Add Key _
        :=Acell, SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _
        xlSortNormal
    With ActiveSheet.AutoFilter.Sort
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    Selection.AutoFilter
    ActiveSheet.Protect Password:="bismillah1111"
End Sub
Regards, Hans Vogelaar (http://www.eileenslounge.com)