Find text in webpage and email notification applescript/automator

Question

Hey guys, I'm trying to make (what I think is) a fairly complicated automator/applescript action.  Basically, I'm trying to buy a certain product and it is only available on the webpage at certain times. So I want to create a function that will constantly run in the background on my computer. I want this function to reload a safari page every 10-15 minutes (the one with the store's product page), search for text (the name of the product) and either stop there if the text isn't found or if the text is found, open mail and send myself an email notification so that I'll get it on my phone if the product becomes available. Is this possible at all?

Answer 1

this might do what you're looking for:
on idle
          set pagURL to "http://page.url.com?whatever"
          if application "Safari" is not running then
                    quit
                    return
          end if
          tell application "Safari"
                    set URL of document 1 of window 1 to "http://your.web.address/"
                    delay 5
  -- delay to let page load. 
  -- there are more elegant ways of doing this using do javascript, but this will suffice.
                    if source of document 1 of window 1 contains "search text" then
                              my sendAMail()
                    end if
                    return 900 --fifteen minutes
          end tell
end idle
on sendAMail()
          tell application "Mail"
                    set theMess to make new outgoing message at end with properties {sender:"your name", subject:"some subject line", content:"The message you want to send to yourself", visible:true}
                    tell theMess
                               make new to recipient at end of to recipients with properties {address:"[email protected]"}
                    end tell
  -- send theMess
          end tell
end sendAMail
copy it into the applescript editor, edit in all the correct information about the web page, your email address, etc., then save it as a stay open application.  when run, it will periodically reload and check the page - adjust the number after the return statement to set it to different time periods.
test it first, then when you're ready to use it set visible:false in the line where you make the message, and uncomment the send theMess line.  this will get mail to make and send the message invisibly.