FM JOB_CLOSE doesn't wait for pred job even when pred_jobname/jobcount set

Question

Dear experts,
I need to call in sequential order two batch jobs when there is a special condition. It's not always the case, which means when there is no successor task, then the job should be executed immediately. But when there is another waiting in the queue, then
I set the parameters pred_jobcount/pred_jobname so that the next job is executed when the previous is finished.
I tried with the combination of several parameters, read lots of help and checked example programs, but the problem I've got: either both jobs are launched at the same time (so it does';t really wait for the predecessor to be completed sucessfully even if predjob_checkstat is set to X), or the second job is never launched at all! Here is the call of JOB_CLOSE:
AS_PRED contains the correct information of the predecessor job (I verified against SM37 and no problem there). For the first job to be launched, I have no issue at all. However the successor is not launched at all!
(Just to play around and to test some other parameter combination, I called the FM with strtimmed always set to X but then both jobs are launched at the same time, which is not convenient for me!).
IF as_pred IS INITIAL.
    lv_strt_immed = 'X'.
  ELSE.
    lv_strt_immed = space..
    lv_checkstat = 'X'.
  ENDIF.
* Plan job with direct start after predecessor job (if available)
  CALL FUNCTION 'JOB_CLOSE'
    EXPORTING
      jobcount             = me->job_count
      jobname              = me->job_name
      pred_jobcount        = as_pred-predjobcnt
      pred_jobname         = as_pred-predjob
      predjob_checkstat    = lv_checkstat
      strtimmed            = lv_strt_immed
    IMPORTING
      job_was_released     = lp_job_released
    EXCEPTIONS
      cant_start_immediate = 1
      invalid_startdate    = 2
      jobname_missing      = 3
      job_close_failed     = 4
      job_nosteps          = 5
      job_notex            = 6
      lock_failed          = 7
      invalid_target       = 8
      OTHERS               = 9.
Do you have any hint what might be wrong with the function call above?
Many thanks for you help, best regards
Ebru

Answer 1

BP_JOB_CREATE can be used to create dependent jobs. The below sample program creates a chain of jobs. Prerequisite: the report program YTEST should exist.
++++++++++++++++++++++
REPORT  yjob_chain.
DATA cntr(3) TYPE n.
PARAMETERS:
  job_str(10) TYPE c DEFAULT 'ABC', "default jobname template
  p_njobs TYPE i. "number of nodes in chain
DATA jobname LIKE tbtcjob-jobname.
DATA jobcount LIKE tbtcjob-jobcount.
DATA pred_jobname LIKE tbtcjob-jobname.
DATA pred_jobcount LIKE tbtcjob-jobcount.
DATA flg_1stjob TYPE c.
START-OF-SELECTION.
  CLEAR flg_1stjob.
  DO p_njobs TIMES.
    PERFORM create_job.
  ENDDO.
*&      Form  create_job
*       text
FORM create_job.
  DATA global_job01 TYPE tbtcjob.
  DATA global_job02 TYPE tbtcjob.
  DATA steplist TYPE STANDARD TABLE OF tbtcstep.
  DATA stepline TYPE tbtcstep.
  stepline-program = 'YTEST'.
  stepline-typ = 'A'.
  stepline-authcknam = sy-uname.
  APPEND stepline TO steplist.
  cntr = cntr + 1.
  CONCATENATE job_str '-' cntr INTO jobname.
  global_job01-jobname = jobname.
  global_job01-jobclass = 'C'.
  IF flg_1stjob IS NOT INITIAL.
    global_job01-eventid = 'SAP_END_OF_JOB'.
    global_job01-eventparm = pred_jobname.
    global_job01-eventcount = pred_jobcount.
  ELSE.
    global_job01-reldate = sy-datum.
    global_job01-reltime = sy-timlo.
    global_job01-strtdate = sy-datum + 1.
    global_job01-strttime = '010000'.
  ENDIF.
  CALL FUNCTION 'BP_JOB_CREATE'
    EXPORTING
      job_cr_dialog       = 'N'
      job_cr_head_inp     = global_job01
    IMPORTING
      job_cr_head_out     = global_job02
    TABLES
      job_cr_steplist     = steplist
    EXCEPTIONS
      cant_create_job     = 1
      invalid_dialog_type = 2
      invalid_job_data    = 3
      job_create_canceled = 4
      OTHERS              = 5.
  IF sy-subrc = 0.
    pred_jobname = jobname.
    pred_jobcount = global_job02-jobcount.
    flg_1stjob = 'X'.
    WRITE:/ 'Created Job- ', 'Name: ', global_job02-jobname, 'Number: ', global_job02-jobcount.
  ELSE.
    WRITE:/ 'Error creating job'.
  ENDIF.
ENDFORM.                    "create_job