From Adressbook to Excel file

Question

For my work I need to deliver all Adresses (groupwise) in an Excell file.
Furthermore I need to put the Billing number (I strategically placed in the "note" section) to be visible
Yes, I am a Apple apprentice and would like some help
iBook G4   Mac OS X (10.3.9)  

Answer 1

Try this - open it with script editor and run it. The resulting file on the desktop can be dropped into excel.
AK
click here to open this script in your editor<pre style="font-family: 'Monaco', 'Courier New', Courier, monospace; overflow:auto; color: #222; background: #DDD; padding: 0.2em; font-size: 10px; width:400px">(* Make Address Book contacts into a CSV file for import to Excel*)
(* AK May 2006 *)
set CName to ((path to desktop) as string) & "ABContacts.cvs" --change this for different file name
set CVSFile to open for access CName with write permission
set CVSLine to "Group" & tab & "First Name" & tab & "Last Name" & tab & "Email" & tab & "Billing Number" & return --header line
write CVSLine to CVSFile
set ContactDetails to ""
tell application "Address Book"
repeat with ThisGroup in groups
set GroupName to name of ThisGroup
repeat with ThisContact in people of ThisGroup
set Details to GroupName
set Details to Details & tab & first name of ThisContact
set Details to Details & tab & last name of ThisContact
--if other data needed, use this pattern
--see AB's dictionary for applescript names of contact properties
try
set Details to Details & tab & value of email 1 of ThisContact --this only gets 1st email
on error
set Details to Details & tab
end try
set Details to Details & tab & note of ThisContact
set ContactDetails to ContactDetails & Details & return
end repeat
end repeat
end tell
write ContactDetails to CVSFile
close access CVSFile</pre>