Function/Procedure help - just want to build simple query and show results

Question

I'd like a simple "histogram" function - perhaps there is one built-in I'm not aware of. I just want to count discrete values of a column. So I'm constantly writing queries of the form:
select column_name, count(*)
from table_name
group by column_name
order by column_name;
and I'm trying to write a function that will allow me to just type:
execute whatever(column_name, table_name)
or select whatever(column_name, table_name) from ?
and get the equivalent results from the query above.
How do you, or can you, write a procedure to take column/table names as inputs, substitue them into a query, execute the query and just display the results of that query? As I'm trying to figure out how to do this via google search, I keep going down rabbit holes of creating temporary tables/data types/records/refcursors etc. and I can't get any of it to compile. I'm not a DBA or SQL expert, so I'm hoping there's a simple way to accomplish this (without having to store and then process the "results" one row at a time)

Answer 1

If I understand the requirement correctly, a simple pipelined function will do it:
Dynamic
GROUP_VALUE                    NUM_RECS
10                                    1
20                                    2
30                                    6
40                                    1
50                                   45
60                                    5
70                                    1
80                                   34
90                                    3
100                                   6
110                                   2
                                      1
12 rows selected.
  1  SELECT *
  2* FROM TABLE (Gen_Counts.Group_Count ('EMPLOYEES', 'DEPARTMENT_ID'))
Static
DEPARTMENT_ID   COUNT(*)
           10          1
           20          2
           30          6
           40          1
           50         45
           60          5
           70          1
           80         34
           90          3
          100          6
          110          2
                       1
12 rows selected.
  1  SELECT department_id, Count(*)
  2    FROM employees
  3   GROUP BY department_id
  4*  ORDER BY 1The types and package code is:
CREATE OR REPLACE TYPE group_count_type IS OBJECT
    (group_value VARCHAR2(4000), num_recs NUMBER);
CREATE OR REPLACE TYPE group_count_list_type IS TABLE OF group_count_type;
CREATE OR REPLACE PACKAGE Gen_Counts IS
FUNCTION Group_Count (p_tab_name VARCHAR2, p_col_name VARCHAR2) RETURN group_count_list_type PIPELINED;
END Gen_Counts;
CREATE OR REPLACE PACKAGE BODY Gen_Counts IS
FUNCTION Group_Count (p_tab_name VARCHAR2, p_col_name VARCHAR2) RETURN group_count_list_type PIPELINED IS
  l_cur             SYS_REFCURSOR;
  l_rec_list    group_count_list_type;
  l_cur_str     VARCHAR2(1000) := 'SELECT group_count_type (' || p_col_name || ', Count(*)) FROM ' || p_tab_name ||
    ' GROUP BY ' || p_col_name || ' ORDER BY ' || p_col_name;
BEGIN
  OPEN l_cur FOR l_cur_str;
  DBMS_Output.Put_Line (l_cur_str);
  LOOP
    FETCH l_cur BULK COLLECT
     INTO l_rec_list LIMIT 1000;
    EXIT WHEN l_rec_list.COUNT = 0;
    FOR i IN 1..l_rec_list.COUNT LOOP
      PIPE ROW (group_count_type (l_rec_list(i).group_value, l_rec_list(i).num_recs));
    END LOOP;
  END LOOP;
END Group_Count;
END Gen_Counts;
/Edited by: BrendanP on 06-Sep-2012 07:18
Just to be clear - I'm not saying it's a great idea to do that, just that's a way of doing it technically. I'd just use the static way myself.