Generating Insert Scripts for multiple tables

Question

Hi,
I have 6 tables TABLA,TABLB,TABLC,TABLED,TABLEE,TABLEF
I want to generate Insert Scripts for the above 6 tables.
Is there any mechanism to do so so that i can generate the .sql files for the above 6 tables to another schema?
Any help will be needful for me.

Answer 1

Hi,
May the below given function script help you...
CREATE OR REPLACE FUNCTION get_insert_script (v_table_name VARCHAR2)
   RETURN VARCHAR2
AS
   b_found   BOOLEAN         := FALSE;
   v_tempa   VARCHAR2 (8000);
   v_tempb   VARCHAR2 (8000);
   v_tempc   VARCHAR2 (255);
BEGIN
   FOR tab_rec IN (SELECT table_name
                     FROM all_tables
                    WHERE table_name = UPPER (v_table_name))
   LOOP
      b_found := TRUE;
      v_tempa := 'select ''insert into ' || tab_rec.table_name || ' (';
      FOR col_rec IN (SELECT   *
                          FROM cols
                         WHERE table_name = tab_rec.table_name
                      ORDER BY column_id)
      LOOP
         IF col_rec.column_id = 1
         THEN
            v_tempa := v_tempa || '''||chr(10)||''';
         ELSE
            v_tempa := v_tempa || ',''||chr(10)||''';
            v_tempb := v_tempb || ',''||chr(10)||''';
         END IF;
         v_tempa := v_tempa || col_rec.column_name;
         IF INSTR (col_rec.data_type, 'CHAR') > 0
         THEN
            v_tempc := '''''''''||' || col_rec.column_name || '||''''''''';
         ELSIF INSTR (col_rec.data_type, 'DATE') > 0
         THEN
            v_tempc :=
                  '''to_date(''''''||to_char('
               || col_rec.column_name
               || ',''mm/dd/yyyy hh24:mi'')||'''''',''''mm/dd/yyyy hh24:mi'''')''';
         ELSE
            v_tempc := col_rec.column_name;
         END IF;
         v_tempb :=
               v_tempb
            || '''||decode('
            || col_rec.column_name
            || ',Null,''Null'','
            || v_tempc
            || ')||''';
      END LOOP;
      v_tempa :=
            v_tempa
         || ') values ('
         || v_tempb
         || ');'' from '
         || tab_rec.table_name
         || ';';
   END LOOP;
   IF NOT b_found
   THEN
      v_tempa := '- Table ' || v_table_name || ' not found';
   ELSE
      v_tempa := v_tempa || CHR (10) || 'select ''- commit;'' from dual;';
   END IF;
   RETURN v_tempa;
END;(copied and pasted from a commercial site)
*009*
Edited by: 009 on Jan 14, 2010 10:43 PM
(Function after debug)