Getting a script to work in Mail rules

Question

I have a script that works fine in Script Editor or as a stand alone script. I would like to get it to work from within Mail rules but for some reason it doesn't want to. I have tried placing hte script within the brackets of
using terms from application "Mail"
on perform mail action with messages theMessages for rule theRule
and
end perform mail action with messages
end using terms from
which I was thought to believe enabled script to work with Mail rules. If aynone has any ideas how to resolve this I would love to hear from them.
My script is as follows.
tell application "Mail"
set the_message to item 1 of (get selection)
set theSubject to the subject of the_message
if theSubject is "Nouvelle Réservation" then
set the_message to item 1 of (get selection)
set message_text to content of the_message as string
set nom to paragraph 8 of message_text
set prenom_script to paragraph 9 of message_text
set spectacle_script to paragraph 2 of message_text
set date_script to paragraph 3 of message_text
set node_placesscript to paragraph 5 of message_text
end if
end tell
tell application "FileMaker Pro Advanced"
activate
open file "xxx:Users:yyy:Documents:zzz:fichiers fp7:Import reservations script.fp7"
try
delete every record
end try
set newRecord to create record -- store the result as 'newRecord'
tell newRecord -- now target that new record
set cell "nom_script" to nom
set cell "prenom_script" to prenom_script
set cell "spectacle_script" to spectacle_script
set cell "date_script" to date_script
set cell "node_placesscript" to node_placesscript
do script "whole import process into «•_reservations»"
end tell
end tell

Answer 1

Hello
You need to tell application "Mail" to do its tasks. Also your original if clause is closed too soon.
So a possible fix would be as follows :
--SCRIPT1
using terms from application "Mail"
on perform mail action with messages theMessages for rule theRule
my initFilemaker()
tell application "Mail" -- # required
repeat with oneMessage in theMessages
set theSubject to the subject of oneMessage
if theSubject is "Nouvelle Réservation" then -- # should enclose the rest of this iteration
set message_text to content of oneMessage
set nom to paragraph 8 of message_text
set prenom_script to paragraph 9 of message_text
set spectacle_script to paragraph 2 of message_text
set date_script to paragraph 3 of message_text
set node_placesscript to paragraph 5 of message_text
tell application "FileMaker Pro Advanced"
set newRecord to create record -- store the result as 'newRecord'
tell newRecord -- now target that new record
set cell "nom_script" to nom
set cell "prenom_script" to prenom_script
set cell "spectacle_script" to spectacle_script
set cell "date_script" to date_script
set cell "node_placesscript" to node_placesscript
do script "whole import process into «•_reservations»"
end tell
end tell
end if
end repeat
end tell
end perform mail action with messages
end using terms from
on initFilemaker()
tell application "FileMaker Pro Advanced"
open file "xxx:Users:yyy:Documents:zzz:fichiers fp7:Import reservations script.fp7"
try
delete every record
end try
end tell
end initFilemaker
--END OF SCRIPT1
Or, since I'm not comfortable with nested tell structure (tell FMP in tell Mail), I'd write something like this (with other minor changes to my preferences) :
--SCRIPT1a
using terms from application "Mail"
on perform mail action with messages theMessages for rule theRule
my fmpclearrecords()
tell application "Mail"
repeat with m in theMessages
set m to m's contents
if m's subject = "Nouvelle Réservation" then
my fmpnewrecord(m's content)
end if
end repeat
end tell
end perform mail action with messages
end using terms from
on fmpclearrecords()
set a to "xxx:Users:yyy:Documents:zzz:fichiers fp7:Import reservations script.fp7" as alias
tell application "FileMaker Pro Advanced"
open a
try
delete records
end try
end tell
end fmpclearrecords
on fmpnewrecord(t)
tell application "FileMaker Pro Advanced"
tell (create new record)
set cell "nom_script" to t's paragraph 8
set cell "prenom_script" to t's paragraph 9
set cell "spectacle_script" to t's paragraph 2
set cell "date_script" to t's paragraph 3
set cell "node_placesscript" to t's paragraph 5
end tell
do script "whole import process into «•_reservations»"
end tell
end fmpnewrecord
--END OF SCRIPT1a
Not tested, for I don't have FMP for OSX.
But I see no specific reason for the above to fail except for the case that certain threading issue of script run via Mail rule interferes.
*If it still fails, check console log for specific errors.
Good luck,
H
EDIT: The object referencing in FMP seems incomplete though it might work in current form.
It would be better to specifiy complete reference such as :
-- delete records
tell application "FMP"
tell document 1
tell database 1
tell current layout
delete records
end tell
end tell
end tell
end tell
-- create new record
tell application "FMP"
tell document 1
tell database 1
tell current layout
tell (create new record)
-- omitted
end tell
end tell
end tell
end tell
end tell
--etc
Message was edited by: Hiroto