GZip Compression (Yes this old chestnut Again)

Question

I have a client who requires this to work in .NET 4 Client Profile so no 4.5 compression improvements for me. All I need is 2 functions one to compress and one to decompress
both of which take in and return unicode strings. I have spent weeks nay months searching tweaking writing etc. to no avail, I have looked at all the existing snippets I could find but they
all either take in or return a Byte() or Stream or something else and when I tweak them to take/return a string they don't work. What I have so far (a snippet found online tweaked) is:
Public Shared Function Decompress(bytesToDecompress As String) As String
Using stream = New IO.Compression.GZipStream(New IO.MemoryStream(System.Text.Encoding.Unicode.GetBytes(bytesToDecompress)), IO.Compression.CompressionMode.Decompress)
Const size As Integer = 4096
Dim buffer = New Byte(size - 1) {}
Using memoryStream = New IO.MemoryStream()
Dim count As Integer
Do
count = stream.Read(buffer, 0, size)
If count > 0 Then
memoryStream.Write(buffer, 0, count)
End If
Loop While count > 0
Return System.Text.Encoding.Unicode.GetString(memoryStream.ToArray())
End Using
End Using
End Function
Public Shared Function Compress(Input As String) As String
Dim bytes() As Byte = System.Text.Encoding.Unicode.GetBytes(Input)
Using stream = New IO.MemoryStream()
Using zipStream = New IO.Compression.GZipStream(stream, IO.Compression.CompressionMode.Compress)
zipStream.Write(bytes, 0, bytes.Length)
Return System.Text.Encoding.Unicode.GetString(stream.ToArray())
End Using
End Using
End Function
However the problem is if you run the following you get nothing out.
Decompress(Compress("Test String"))
Please help me; I know this has been covered to death elsewhere but I am missing something when tweaking I am sure it's something very simple but it is causing me great stress! Many Many Thanks Indeed!

Answer 1

I have now found a workaround which may be useful to others so I am posting it here, it doesn't do exactly what was described above which would be ideal but here is the code:
Private Sub WriteCompressed(ByVal Path As String, Data As String)
Using WriteFileStream As IO.FileStream = IO.File.Create(Path)
Using DataStream As New IO.MemoryStream(System.Text.Encoding.Unicode.GetBytes(Data))
Using Compressor As IO.Compression.DeflateStream = New IO.Compression.DeflateStream(WriteFileStream, IO.Compression.CompressionMode.Compress)
DataStream.CopyTo(Compressor)
End Using
End Using
End Using
End Sub
Private Function ReadCompressed(ByVal Path As String) As String
Using ReadFileStream As IO.FileStream = System.IO.File.OpenRead(Path)
Using DataStream As New IO.MemoryStream
Using Decompressor As IO.Compression.DeflateStream = New IO.Compression.DeflateStream(ReadFileStream, IO.Compression.CompressionMode.Decompress)
Decompressor.CopyTo(DataStream)
Return System.Text.Encoding.Unicode.GetString(DataStream.ToArray)
End Using
End Using
End Using
End Function
Many thanks indeed to everyone who helped and any more input is still welcome. Thanks again!
That's great. You should propose your post as the answer to end the thread.
I just finished with a different method. However I will guess the real issue is that strings can not contain various binary values such as Nulls, Delete, Bell, Backspace, etc (as you can see zeros in RTB2 in the image below which are null
values).
I forgot to add that during testing I was receiving errors because compressed data written to a string then read from a string into bytes and decompressed would return errors during the decompressing that the data did not contain a valid GZip header. Therefore
when GZip compresses it uses some format for the compressed data that is known to Gzip. Otherwise it would not have a header in the compressed data.
You can see what binary values (Decimal) would be in a string at this link
Ascii Table.
Therefore I used the code below to get a string from a RichTextBox1 to a byte array. That is compressed and output to a byte array.
The information in the "compressed" byte array is then converted byte by byte to the bytes value in RichTextBox2 with each value separated by a comma.
To decompress the string in RichTextBox2 that text is split into a string array on a comma. Then each item is converted to a byte into a List(Of Byte). The List(Of Byte).ToArray is then decompressed back into a byte array and that byte array is converted
to a string in RichTextBox3.
I suspect the actual compressed byte array could be written to a binary file using the
BinaryWriter Class if the original strings were supposed to be compressed and attached as files for transfer somewhere.
Option Strict On
Imports System.IO
Imports System.IO.Compression
Imports System.Text
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Me.Location = New Point(CInt((Screen.PrimaryScreen.WorkingArea.Width / 2) - (Me.Width / 2)), CInt((Screen.PrimaryScreen.WorkingArea.Height / 2) - (Me.Height / 2)))
RichTextBox1.Text = My.Computer.FileSystem.ReadAllText("C:\Users\John\Desktop\Northwind Database.Txt")
Label1.Text = "Waiting"
Label2.Text = "Waiting"
Label3.Text = "Waiting"
Label4.Text = "Waiting"
Button2.Enabled = False
End Sub
Dim BytesCompressed() As Byte
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
RichTextBox2.Clear()
RichTextBox3.Clear()
Label1.Text = "Waiting"
Label2.Text = "Waiting"
Label3.Text = "Waiting"
Label4.Text = "Waiting"
If RichTextBox1.Text <> "" Then
Dim uniEncoding As New UnicodeEncoding()
BytesCompressed = Compress(uniEncoding.GetBytes(RichTextBox1.Text))
Label1.Text = RichTextBox1.Text.Count.ToString
Label2.Text = BytesCompressed.Count.ToString
For Each Item In BytesCompressed
RichTextBox2.AppendText(CStr(CInt(Item)) & ",")
Next
RichTextBox2.Text = RichTextBox2.Text.Remove(RichTextBox2.Text.Count - 1, 1)
End If
Button2.Enabled = True
End Sub
Private Shared Function Compress(data As Byte()) As Byte()
Using compressedStream = New MemoryStream()
Using zipStream = New GZipStream(compressedStream, CompressionMode.Compress)
zipStream.Write(data, 0, data.Length)
zipStream.Close()
Return compressedStream.ToArray()
End Using
End Using
End Function
Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
Button2.Enabled = False
Dim RTB2Split() As String = RichTextBox2.Text.Split(","c)
Dim BytesToUse As New List(Of Byte)
For Each Item In RTB2Split
BytesToUse.Add(CByte(Item))
Next
Label3.Text = BytesToUse.Count.ToString
Dim uniEncoding As New UnicodeEncoding()
RichTextBox3.Text = uniEncoding.GetString(Decompress(BytesToUse.ToArray))
Label4.Text = RichTextBox3.Text.Count.ToString
End Sub
Private Shared Function Decompress(data As Byte()) As Byte()
Using compressedStream = New MemoryStream(data)
Using zipStream = New GZipStream(compressedStream, CompressionMode.Decompress)
Using resultStream = New MemoryStream()
zipStream.CopyTo(resultStream)
Return resultStream.ToArray()
End Using
End Using
End Using
End Function
End Class
La vida loca