Having problems printing pathlist in Leopard

Question

Hello all!
At my workplace we recently got a few new G5's running Leopard and are having some difficulties with some scripts. This script in particular should accept a file name or multiple file names and should output the pathlist of the files to textEditor and then open up the print dialog so all the user has to do is click print. However when it runs on Leopard, it opens text edit and give an error message. It reads "Can't get last paragraph of document 1 of application 'TextEdit'. Invalid index." The source code is listed below. Any help would be greatly appreciated!
Stephen
script newfile
property pathlist : ""
property filename : ""
end script
on open (files_passed)
(* make a list that has the correct number of newfiles in it*)
set myfiles to [] as list
repeat with counter from 1 to (count of files_passed)
set myfiles to myfiles & "" as list
end repeat
repeat with counter from 1 to count of myfiles
copy newfile to item counter of myfiles
end repeat
(* set up pathlists and filenames for each of the documents*)
set pointer to 1 (*this shows which of myfiles to change*)
repeat with current in files_passed
set pathlist to the POSIX path of current
separate_path(pathlist)
set newpathlist to the result (*a list of each folder and filename in the pathlist*)
makeprintablepathlist(newpathlist)
set finished_path to the result
(*set the properties of current myfile*)
set pathlist of item pointer of myfiles to item 1 of finished_path
set filename of item pointer of myfiles to item 2 of finished_path
set pointer to pointer + 1
end repeat
sort_files(myfiles)
set myfiles_sorted to the result
(*check if textedit is open*)
tell application "System Events"
if process "textedit" exists then
set should_close to false
else
set should_close to true
end if
end tell
tell application "TextEdit"
activate
make new document at the beginning
tell document 1
set last paragraph to " "
set size of last paragraph to 10
set font of last paragraph to "Helvetica"
repeat with current in myfiles_sorted
set last paragraph to pathlist of current & " "
set font of last paragraph to "Helvetica-Bold"
set last paragraph to filename of current & " "
set font of last paragraph to "Helvetica"
set last paragraph to return & return & " "
end repeat
print
end tell
repeat while name of window 1 is "Print"
end repeat
close document 1 saving no
if should_close then
quit
end if
end tell
end open
on sort_files(currentfiles)
set sorted_files to item 1 of currentfiles as list
repeat with counter from 2 to count of currentfiles
set make_new to true
repeat with countera in sorted_files
log "filenumber:" & counter
if pathlist of item counter of currentfiles = pathlist of countera then
set filename of countera to filename of countera & ¬
filename of item counter of currentfiles
set make_new to false
end if
end repeat
if make_new then
set sorted_files to sorted_files & item counter of currentfiles as list
end if
end repeat
return sorted_files
end sort_files
on separate_path(pathlist)
set mypath to [] as list
set nextword to ""
repeat with pointer from 2 to (count of characters of pathlist)
if character pointer of pathlist is not equal to "/" then
set nextword to nextword & character pointer of pathlist
else
set mypath to mypath & [nextword]
set nextword to ""
end if
end repeat
set mypath to mypath & [nextword]
set nextword to ""
return mypath (*a list of each folder and filename in the pathlist*)
end separate_path
on makeprintablepathlist(mypath)
set pathlist to ""
set tabs to tab & tab & tab & tab & tab & tab & tab & tab & tab
repeat with counter from 1 to ((count of mypath) - 1)
set pathlist to pathlist & tabs & item counter of mypath & return
end repeat
set filename to tabs & " " & the last item of mypath & return
return [pathlist, filename]
end makeprintablepathlist

Answer 1

Hi sevans4262 and welcome to Apple Discussions!
It's because when you first create the TextEdit document, it doesn't have any paragraphs, so there can't be a "last paragraph", so it can't count it.
Even if there was a paragraph Your script as it stands would also replace the last paragraph with your new text every time you loop.
There are downloadable illustrations of how to manipulate TextEdit documents here. The syntax is basically
tell application "textedit"
tell front document to set text to "Something"
end tell
But...
TextEdit is not particularly rewarding to script The simplest approach I can see that would work would be to concatenate the entire text, drop it into the TextEdit document in one go, and then loop through the paragraphs setting the font and size.
You'll have a much more fruitful experience if you experiment with a freeware text editor like TextWrangler or a shareware product like Tex-Edit Plus. Both have far richer and more manageable scripting abilities than TextEdit, and Tex-Edit Plus in particular is very well documented. IMHO.
H
H