Help populating table with applescript

Question

Hi
I'm posting here in the hope that someone can give me a helping hand with an applescript. I myself know very little about applescript. I can create something very basic but thats about it.
I have the following table
Name
Value
Amount
Donald Duck
4
5000
Goofy
10a
7000
George
5
4000
Steve
4
6000
Hank
18
9000
Sue-Ellen
5
9050
John
18
11000
Hector
18
5500
I would like to create an applescript that runs through this table and populates another table, we can call it "Results", that would look something like this
Value 4
Donald Duck
5000
Steve
6000
Value 5
George
4000
Sue-Ellen
9050
A further complication is that this newly populated should only be populated if the following condition exists. The total sum of the newly created table (i.e the value column) should only be populated with posts from the original table as long as the sum of the newly created posts do not exceed the sum of a cell in a third table (we can call this the "sumtable").
To make it clearer. If the sum of the "sumtable" is 24 050 then the newly created table will only create the posts I have made above. These posts must be made using the following values and in the order the values appear. The complete list of values is 3a, 4, 4a, 5, 6, 7, 10, 10a, 12, 13, 18 . So the script would start looking for values in that order and whenever it reaches a total sum that is equal to the sum in "sumtable" it will use those values, and only those, and populate the new table creating the necessary rows needed.
It's possible that this is way to complicated to do. I have tried to make a formula in a table to do this but the problem is I ca never know how many rows are needed in advance.
Hoping for some help or tips, but understanding if this is asking too much considering the amoutn of effort needed.
Thanks

Answer 1

consiglieri_swe wrote:
i.e Goofy only gets part of his debt.
The partial payment complicates the logic a little. Below is a script that can handle that. The usage is the same. Paste it into AppleScript Editor. Run. Paste results into A2 of the Results table and the table expands automatically to the number of rows needed. The Sum formula is in a Footer Row.
The revised script, which now reads the available amount from a cell in a table (easily changed to another table as needed), is below.
SG
--accounts for partial payment of "last" creditor
--reads available amount from a cell in a table
property thePriorities : {"3a", "4", "4a", "5", "6", "7", "10", "10a", "12", "13", "18"}
tell application "Numbers" to tell the front document to tell sheet "Sheet 1"
          tell table "Maximum"
                    set maxAmount to the value of cell "A2"
          end tell
          tell table "Table 1"
                    set {pasteStr, stillAvailable, allDone} to {"", maxAmount, false}
                    repeat with i from 1 to count of thePriorities --cycle through 3a, 4, 4a, etc
                              set priorityBeingTallied to (item i of thePriorities)
                              repeat with j from 2 to count of its rows
                                        tell row j
                                               --get the values in a row
                                                  set thisName to value of its first cell
                                                  set thisPriority to my stripDecimal(value of its second cell)
                                                  set thisAmount to value of its third cell
                                                  if thisPriority is equal to priorityBeingTallied then --if it's in this priority
                                                            if stillAvailable > 0 then --include the row unless no more money
                                                                      set thisAllocation to my lesserOf(thisAmount, stillAvailable)
                                                                      set pasteStr to pasteStr & thisPriority & tab & thisName & tab ¬
                                                                                & thisAllocation & return
                                                                      set stillAvailable to stillAvailable - thisAllocation
                                                            end if
                                                  end if
                                        end tell
                              end repeat --rows
                    end repeat --priorities
          end tell --table
end tell --app
set the clipboard to pasteStr
display notification "Click once in a cell and paste." with title "Numbers"
pasteStr
--handler needed because when asked for a cell value Numbers 3 adds .0
to stripDecimal(val)
          set val to val as string
          set {oTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, "."}
          set s to item 1 of val's text items
          set AppleScript's text item delimiters to oTID
          return s
end stripDecimal
to lesserOf(x, y) --used to calculate partial payment to "last" creditor
          if x < y then return x
          return y
end lesserOf
--end of script