Help with Applescript and Admin Privelages

Question

I just started using Applestript a few months ago and I can't figure out how to give my script Admin rights. Basically, it turns on and off my internet sharing and file sharing through dialog boxes. I copied and pasted the whole code below if you want to test it, but this is the part that is giving me trouble. There are 4 lines similar to this, the actions that turn on or off the services.
do shell script "/bin/launchctl load -w /System/Library/LaunchDaemons/com.apple.InternetSharing.plist" with administrator privileges
I've tried adding "with password _____" and "password_____" but neither worked. Can anyone help me make this script authenticate itself so I don't need to keep typine in my password? I could easily make a keystroke in system events to type it in but it doesn't always ask for it so I don't know how I'd make the script know when it needs to enter the password. any help is much appreciated!
Some things to clarify: The first shell script is there to invoke the "authentication" dialog so I can sign in once I launch the app and get right into the settings. However, I'd like to make it so the script doesn't even need admin permission to run, or make it somehow have my password built in to it. Security is not an issue, its my personal computer that nobody else has access to so I really don't care if my password is written in the code. Also, if you have any tips on how to streamline the Quit/Hide/Resume dialog I'd appreciate that too. Resume is there because there's a chance I won't have to sign in again if the app does not quit, however more often than not I have to sign in anyways. Thanks again in advance, sorry this post is so long but like I said, I'm pretty new to all this so I don't know exactly what you need to be able to help me.
The Whole Script:
-- Variables and Authentication
set done to "n"
set quitapp to "no"
display dialog "Please enter your password to allow Sharing Manager to make changes to your settings." with icon caution
do shell script "/bin/launchctl unload -w /System/Library/LaunchDaemons/com.apple.AppleFileServer.plist" with administrator privileges
delay 0.2
-- Repeats
repeat while quitapp is "no"
          repeat while done is "n"
  -- Choose Setting
                    display dialog "Choose Setting to Edit" buttons {"Internet", "File Sharing", "Exit"} default button 3
                    set the button_pressed to the button returned of the result
                    if the button_pressed is "Internet" then
  -- Commands for Internet Settings
                              display dialog "Internet Sharing" buttons {"On", "Off", "Cancel"} default button 3
                              set the button_pressed to the button returned of the result
                              if the button_pressed is "On" then
                                        do shell script "/bin/launchctl load -w /System/Library/LaunchDaemons/com.apple.InternetSharing.plist" with administrator privileges
                              else if the button_pressed is "Off" then
                                        do shell script "/bin/launchctl unload -w /System/Library/LaunchDaemons/com.apple.InternetSharing.plist" with administrator privileges
                              end if
                    else if the button_pressed is "File Sharing" then
  -- Commands for Sharing Settings
                              display dialog "File Sharing" buttons {"On", "Off", "Cancel"} default button 3
                              set the button_pressed to the button returned of the result
                              if the button_pressed is "On" then
                                        do shell script "/bin/launchctl load -w /System/Library/LaunchDaemons/com.apple.AppleFileServer.plist" with administrator privileges
                              else if the button_pressed is "Off" then
                                        do shell script "/bin/launchctl unload -w /System/Library/LaunchDaemons/com.apple.AppleFileServer.plist" with administrator privileges
                              end if
                    else
                              set done to ""
                    end if
          end repeat
  -- Confirm Quit/Hide
          display dialog "Really quit? You will have to reenter admin info next time." buttons {"Quit", "Hide", "Resume"} default button 1
          if the button returned of the result is "Quit" then
                    set quitapp to ""
          else if the button returned of the result is "Hide" then
                    tell application "System Events"
  keystroke "h" using command down
                    end tell
          else
                    set done to "n"
                    set quitapp to "no"
          end if
end repeat

Answer 1

with respect to general improvements, a couple of points:
If I'm reading this script correctly, it looks like you're putting up an applescript alert and leaving it hanging until it's dismissed.  This is an atypical approach (applescripts aren't really meant to hang around indefinitely waiting for a respons).  If I were doing this I would either go whole-hog and create an applescript application in XCode with a proper interface, or remove the hanging dialog and create a set of toggle scripts that I could use from the script menu.  if you really want to keep the hanging dialog, though, you can streamline it by absorbing the secondary dialogs into the main dialog.  that's like so:
set netSharingStatus to checkService("com.apple.InternetSharing")
set fileSharingStatus to checkService("com.apple.AppleFileServer")
display alert "Current Settings" message "Click to change settings" buttons {"Internet " & netSharingStatus, "File Sharing " & fileSharingStatus, "Exit"} default button 3
-- choose next action based on the button clicked and the status vairable
on checkService(service)
          do shell script "launchctl list"
          if the result contains service then
                    return "On"
          else
                    return "Off"
          end if
end checkService
using handlers like the above can also streamline the rest of your script.  the following construction means you only have to write the do shell script line once, rather than the four times you currently do, and makes for much cleaner reading.
if the button_pressed starts with "Internet" then
          toggleService("com.apple.InternetSharing", netSharingStatus)
else if the button_pressed starts with "File Sharing" then
          toggleService("com.apple.AppleFileServer", fileSharingStatus)
else
  --exit routine
end if
on toggleService(service, currentState)
          if currentState in "On" then
                    set action to "unload"
          else
                    set action to "load"
          end if
          set command to "/bin/launchctl " & action & " -w /System/Library/LaunchDaemons/" & service & ".plist"
          do shell script command user name "adminusername" password "password" with administrator privileges
end toggleService