Help with Applescript to find cell

Question

I'm attempting to convert some Excel Applescripts over to Numbers and can't find a method to "find".
In Excel for example, I have:
set foundCell to (find keyColumn what searchSymbol look at whole look in values search order by rows after (get last cell of keyColumn) search direction search previous without match case)
The applescript dictionary seems feature rich but no find? Unimaginable, so there must be something I'm over-thinking.

Answer 1

I'm guessing you're looking for something like this...
Working with a table something like this:
Symbol
ABC
DEF
JKL
DEF
XYZ
Then a script like this should do what you what you want:
property keyColumn : "A"
property searchSymbol : "DEF"
property targSht : "Sheet 1"
property targTbl : "Table 1"
tell application "Numbers"
  set foundCell to my findLastVal(targSht, targTbl, keyColumn, searchSymbol)'s properties
  --in line above, depending on what you want, substitute name, row, etc for properties
end tell
to findLastVal(tSht, tTbl, kCol, sVal)
  tell application "Numbers" to tell front document's sheet tSht's table tTbl
  repeat with i from row count to 1 by -1
  tell column kCol's cell i
  if its value is sVal then return it
  end tell
  end repeat
  end tell
end findLastVal
To find the first match in a column you would simply remove the negative decrement, something like this:
repeat with i from 1 to row count
If you're working with very long columns it can be more efficient to first read the values into an AppleScript list and look for a match in the list rather than asking Numbers to read a cell and look for a match on each iteration. But the above approach should work well with moderately sized data sets.
SG