How are *Credit Card*--Cash Advances handled?

Question

How are *Credit Card*--Cash Advances handled? Can employees add that to their Expense report?
Example: If the employee takes a $100 cash advance and reconciles the transaction in SAP Expense, we are expected to pay
Credit Card Provider $100.
However, how does the employee account for underutilizing that $100 (e.g. $20 remaining in their pocket).
Does the individual create and link the $80 of expenses to that $100 cash advance and receive a $20 debit to their employee vendor?
Also, we know that currently there is no MCC Code Mapping in the system for Cash Advance.
Is there a work around this.

Answer 1

Hi Rahul,
I had a customer which had this situation. We solved this issue with a BAdI implementation in ERP.
The traveler adds this withdrawal as a normal expense item which is assigned to special account alias code. The BAdI implementation recongnizes this alias code and removes the expenses and charges this costs to the employee.
Example:
Withdrawal        100 USD
Taxi                     80 USD
Bus                        5 USD
Unused                15 USD
Standard posting to FI:
Taxi Costs                           80,00
Bus Costs                            5,00
Withdrawal                          100,00
Employee Vendor                                85,00
Credit Card Account                          100,00
The correct  posting would be:
Taxi Costs                           80,00
Bus Costs                           5,00
Employee                           15,00
Credit Card Account                         100,00
To achieve this posting it is required to
map the withdrawal expense type to a special account alias code (in the coding
example below: ADV)  and  to implement the following coding in BAdI
BADI_DCFL_FIN_IDOC_DATA_TV:
  DATA: lr_item               TYPE REF TO dcfls_preproc_it.
  DATA: lr_vendor_item         TYPE REF TO dcfls_preproc_it.
FIELD-SYMBOLS: <tv_item_adv>  TYPE dcfls_runtime_tv_item.
FIELD-SYMBOLS: <tv_item_emp>  TYPE dcfls_runtime_tv_item.
FIELD-SYMBOLS: <tv_header>    TYPE dcfls_runtime_tv_root.
  DATA: lt_string              TYPE TABLE OF string.
  DATA: ls_string              TYPE string.
  LOOP AT cs_preproc-item REFERENCE INTO lr_item.
    ASSIGN lr_item->bo_specific_item->* TO <tv_item_adv>.
    IF  <tv_item_adv>-tv_category = '03'  "Expense Item
    AND lr_item->ksymb = 'ADV'.
      CLEAR lr_vendor_item.
      LOOP AT cs_preproc-item REFERENCE INTO lr_vendor_item WHERE rtkey_it <> lr_item->rtkey_it.
        ASSIGN lr_vendor_item->bo_specific_item->* TO <tv_item_emp>.
        IF  <tv_item_emp>-tv_category = '01'  "Due Item
        AND <tv_item_emp>-pernr_d IS NOT INITIAL.
          EXIT.
        ELSE.
          UNASSIGN <tv_item_emp>.
        ENDIF.
      ENDLOOP.
      IF <tv_item_emp> IS ASSIGNED.
        <tv_item_emp>-wrbtr = <tv_item_emp>-wrbtr - <tv_item_adv>-wrbtr.
        DELETE cs_preproc-item WHERE rtkey_it = lr_item->rtkey_it.
      ELSE.
        "Create Vendor Item with negative amount
        <tv_item_adv>-tv_category = '01'.
        ASSIGN cs_preproc-bo_specific_root->* TO <tv_header>.
        SPLIT <tv_header>-note AT '/' INTO TABLE lt_string.
        READ TABLE lt_string INTO ls_string INDEX 4.
        IF sy-subrc = 0.
          <tv_item_adv>-pernr_d = ls_string.
        ENDIF.
        CLEAR: lr_item->ksymb,
               <tv_item_adv>-note,
               <tv_item_adv>-zuonr.
        <tv_item_adv>-wrbtr = <tv_item_adv>-wrbtr * -1.
      ENDIF.
    ENDIF.
  ENDLOOP.
  IF  <tv_item_emp> IS ASSIGNED
  and <tv_item_emp>-wrbtr IS INITIAL.
    DELETE cs_preproc-item WHERE rtkey_it = lr_vendor_item->rtkey_it.
  ENDIF.