How can I create Tracking-Areas in Cocoa-Applescript?

Question

How can I create multiple tracking areas that activate handlers that are specific to a certain area, when the mouse enters that area, in Cocoa-Applescript, Xcode 5?

Answer 1

You can use NSTrackingArea to set up the area(s) you want to track.  For example, if you have a view named "myView" that you wanted to use, you can set up a tracking area by specifying the rectangle (I am going to use the entire view) and tracking options with something like:
   set options to (current application's NSTrackingMouseEnteredAndExited as integer) + (current application's NSTrackingActiveInKeyWindow as integer) + (current application's NSTrackingInVisibleRect as integer)
   set trackingArea to current application's class "NSTrackingArea"'s alloc's initWithRect:(myView's frame()) options:options owner:me userInfo:"tracking myView"
   myView's addTrackingArea:trackingArea
The options are a bit wordy, but they determine how things are tracked - you could also just look up what they are in the class headers and use that.  You then need to add NSResponder handlers in the owner class for what you are interested in - for this example, they would be:
  on mouseEntered:theEvent -- cursor has entered a tracking rectangle
    log "mouseEntered"
    log theEvent's userData() -- data specific to a trackingArea
  end mouseEntered:
  on mouseExited:theEvent -- cursor has exited a tracking rectangle
    log "mouseExited"
    log theEvent's userData() -- data specific to a trackingArea
  end mouseExited:
When using multiple tracking areas, you can add some user info that can be retrieved from the event.  In the above example, I used the string "tracking myView", but it can be whatever you want.