How can i display a CheckBox in one of the column of ALV?

Question

Hi All,
I want to dispaly a one  column  of CHECKBOXes in my ALV  Report.so i take attribute CHK_BOX TYPE CHECKBOX in the context.when i testing it doesn't showing any checkboxes.just i shows a ordinary column with name checkbox.
How can i resolve it?
Regards,
Ravi

Answer 1

Hi Ravi,
Do the following to set any alv column as Check box .
create an instance of ALV component
  DATA:
    lr_salv_wd_table_usage TYPE REF TO if_wd_component_usage,
    lr_column_settings     TYPE REF TO if_salv_wd_column_settings,
    lr_input_field         TYPE REF TO cl_salv_wd_uie_input_field,
    lr_chk_box             TYPE REF TO cl_salv_wd_uie_checkbox,
    lr_table_settings      TYPE REF TO if_salv_wd_table_settings,
    lr_salv_wd_table       TYPE REF TO iwci_salv_wd_table,
    lr_column              TYPE REF TO cl_salv_wd_column.
  lr_salv_wd_table_usage = wd_this->wd_cpuse_alv( ).
  IF lr_salv_wd_table_usage->has_active_component( ) IS INITIAL.
    lr_salv_wd_table_usage->create_component( ).
  ENDIF.
  lr_salv_wd_table = wd_this->wd_cpifc_alv( ).
  wd_this->alv_config_table = lr_salv_wd_table->get_model( ).
  lr_table_settings ?= wd_this->alv_config_table.
* Set ALV as editable
  lr_table_settings->set_read_only( abap_false ).
* Get Column reference
  CALL METHOD wd_this->alv_config_table->if_salv_wd_column_settings~get_column
    EXPORTING
      id    = 'CURR_ISO'
    RECEIVING
      value = lr_column.
* Create a checkboc
  CREATE OBJECT lr_chk_box
    EXPORTING
      checked_fieldname = 'CURR_ISO'.
* Set the cell editor type to the check box.
  CALL METHOD lr_column->set_cell_editor
    EXPORTING
      value = lr_chk_box.
and to set the check box as editable, do the following.
lr_table~IF_SALV_WD_TABLE_SETTINGS~SET_READ_ONLY( abap_false ).
Hope this helps.
Regards,
Sravan Varagani