How can i eliminate stackoverflow in this script?

Question

Hey guys first i would like to know whether in applescript a single action that is too complex leads to a stackoverflow or a too long script leads to it. I tried delaying scripts to hopefully free memory for a task that would stack overflow the script but it did not work.
I recently built a script that calculates poker odds in the river of the game, the thing that i encountered however is that when i do not omit the line that contains the info sign, I get a stack overflow, it tries to quicksort a list of 2352 numbers.  Is it only this action that makes it stackoverflow? or how can i solve this? I am sorry that the script i left some modules out like rateallcombos but i can add them whenever you request it. 
It really is strange though because quicksort does work when i pass a list that is 10000 items long or so.
Help is appreciated very much thank you in advance
doriver("10-R", "11-R", "12-R", "13-R", "14-R", "3-H", "14-H")
on doriver(pocket1, pocket2, flop1, flop2, flop3, turn, river)
    set total1 to {"1-S", "2-S", "3-S", "4-S", "5-S", "6-S", "7-S", "8-S", "9-S", "10-S", "11-S", "12-S", "13-S", "14-S", "1-H", "2-H", "3-H", "4-H", "5-H", "6-H", "7-H", "8-H", "9-H", "10-H", "11-H", "12-H", "13-H", "14-H", "1-R", "2-R", "3-R", "4-R", "5-R", "6-R", "7-R", "8-R", "9-R", "10-R", "11-R", "12-R", "13-R", "14-R", "1-K", "2-K", "3-K", "4-K", "5-K", "6-K", "7-K", "8-K", "9-K", "10-K", "11-K", "12-K", "13-K", "14-K"}
    set cardlist to {}
    set the end of cardlist to pocket1
    set the end of cardlist to pocket2
    set the end of cardlist to flop1
    set the end of cardlist to flop2
    set the end of cardlist to flop3
    set the end of cardlist to turn
    set the end of cardlist to river
    set highestscore to rateallcombos(pocket1, pocket2, flop1, flop2, flop3, turn, river)
    set total2 to {}
    repeat with i from 1 to count total1
        if {total1's item i} is not in cardlist then set total2's end to total1's item i
    end repeat
    set a to 1
    set b to 2
    set d to 49
    set e to {}
    repeat 2352 times
        if b is equal to d and b is not equal to 50 then
            set a to a + 1
            set b to a + 1
        end if
        if b is not equal to 50 then
            set bas1 to item a of total2
            set bas2 to item b of total2
            set opposcore to rateallcombos(bas1, bas2, flop1, flop2, flop3, turn, river)
            set the end of e to opposcore
            set b to b + 1
            --efficienter want tablecards?
        end if
    end repeat
    return quicksort(e)
    --set bas to comparteitem(opposcore, highestscore)
    set a to quicksort(e)
    --return bas
end doriver
on quicksort(theList)
    --public routine, called from your script
    script bs
        property alist : theList
        on Qsort(leftIndex, rightIndex)
            --private routine called by quickSort.
            --do not call from your script!
            if rightIndex > leftIndex then
                set pivot to ((rightIndex - leftIndex) div 2) + leftIndex
                set newPivot to Qpartition(leftIndex, rightIndex, pivot)
                set theList to Qsort(leftIndex, newPivot - 1)
                set theList to Qsort(newPivot + 1, rightIndex)
            end if
        end Qsort
        on Qpartition(leftIndex, rightIndex, pivot)
            --private routine called by quickSort.
            --do not call from your script!
            set pivotValue to item pivot of bs's alist
            set temp to item pivot of bs's alist
            set item pivot of bs's alist to item rightIndex of bs's alist
            set item rightIndex of bs's alist to temp
            set tempIndex to leftIndex
            repeat with pointer from leftIndex to (rightIndex - 1)
                if item pointer of bs's alist ≤ pivotValue then
                    set temp to item pointer of bs's alist
                    set item pointer of bs's alist to item tempIndex of bs's alist
                    set item tempIndex of bs's alist to temp
                    set tempIndex to tempIndex + 1
                end if
            end repeat
            set temp to item rightIndex of bs's alist
            set item rightIndex of bs's alist to item tempIndex of bs's alist
            set item tempIndex of bs's alist to temp
            return tempIndex
        end Qpartition
    end script
    if length of bs's alist > 1 then bs's Qsort(1, length of bs's alist)
    return bs's alist
end quicksort

Answer 1

Another issue, the sorting is not done correctly when a string contains a number, you must convert it. like this
set cardnumber1 to (text item 1 of card1) as integer -- convert "6" to 6
example :
set e to {"2", "12", "1", "14", "6", "7", "11"}
quicksort(e)
return e ---> {"1", "11", "12", "14", "2", "6", "7"}
Try this
doriver({"10-R", "11-R", "12-R", "13-R", "14-R", "3-H", "14-H"})
on doriver(cardlist)
     set total1 to {"1-S", "2-S", "3-S", "4-S", "5-S", "6-S", "7-S", "8-S", "9-S", "10-S", "11-S", "12-S", "13-S", "14-S", "1-H", "2-H", "3-H", "4-H", "5-H", "6-H", "7-H", "8-H", "9-H", "10-H", "11-H", "12-H", "13-H", "14-H", "1-R", "2-R", "3-R", "4-R", "5-R", "6-R", "7-R", "8-R", "9-R", "10-R", "11-R", "12-R", "13-R", "14-R", "1-K", "2-K", "3-K", "4-K", "5-K", "6-K", "7-K", "8-K", "9-K", "10-K", "11-K", "12-K", "13-K", "14-K"}
     set highestscore to rateallcombos(cardlist)
     set total2 to {}
     set cardlist2 to {"", ""} & items 3 thru -1 of cardlist
     repeat with i from 1 to count total1
          if {total1's item i} is not in cardlist then set total2's end to total1's item i
     end repeat
     set a to 1
     set b to 2
     set d to 49
     set e to {}
     repeat 2352 times
          if b = d and b ≠ 50 then
               set a to a + 1
               set b to a + 1
          end if
          if b ≠ 50 then
               set item 1 of cardlist2 to item a of total2 -- bas1
               set item 2 of cardlist2 to item b of total2 -- bas2
               set opposcore to rateallcombos(cardlist2)
               set end of e to opposcore
               set b to b + 1
               --efficienter want tablecards?
          end if
     end repeat
     quicksort(e)
     return e
end doriver
on quicksort(theList)
     script o
          property cutoff : 10
          property p : theList
          on qsrt(l, r)
               set i to l
               set j to r
               set v to my p's item ((l + r) div 2)
               repeat while (j > i)
                    repeat while ((my p's item i) < v)
                         set i to i + 1
                    end repeat
                    repeat while ((my p's item j) > v)
                         set j to j - 1
                    end repeat
                    if i ≤ j then
                         set w to my p's item i
                         set my p's item i to my p's item j
                         set my p's item j to w
                         set {i, j} to {i + 1, j - 1}
                    end if
               end repeat
               if j - l ≥ cutoff then qsrt(l, j)
               if r - i ≥ cutoff then qsrt(i, r)
          end qsrt
          on isrt(l, r)
               set x to l
               set z to l + cutoff - 1
               if (z > r) then set z to r
               set v to my p's item x
               repeat with y from (x + 1) to z
                    if (my p's item y < v) then set {x, v} to {y, my p's item y}
               end repeat
               tell my p's item l
                    set my p's item l to v
                    set my p's item x to it
               end tell
               set u to my p's item (l + 1)
               repeat with i from (l + 2) to r
                    set v to my p's item i
                    if (v < u) then
                         set my p's item i to u
                         repeat with j from (i - 2) to l by -1
                              if (v < my p's item j) then
                                   set my p's item (j + 1) to my p's item j
                              else
                                   set my p's item (j + 1) to v
                                   exit repeat
                              end if
                         end repeat
                    else
                         set u to v
                    end if
               end repeat
          end isrt
     end script
     set r to (count theList)
     set l to 1
     if (r > 1) then
          if (r - l ≥ o's cutoff) then o's qsrt(l, r)
          o's isrt(l, r)
     end if
end quicksort
on rateallcombos(cardlist)
     set bas to getcombo(21)
     set points to 0
     repeat with i from 1 to 105 by 5 -- repeat 21 times
          --item a of bas,item b of bas,item c of bas,item d of bas,item e of bas
          set card1 to item (item i of bas) of cardlist
          set card2 to item (item (i + 1) of bas) of cardlist
          set card3 to item (item (i + 2) of bas) of cardlist
          set card4 to item (item (i + 3) of bas) of cardlist
          set card5 to item (item (i + 4) of bas) of cardlist
          RANKER({card1, card2, card3, card4, card5})
          tell the result to if it > points then set points to it
     end repeat
     return points
end rateallcombos
on RANKER(cardlist)
     set suitlist to {}
     set AppleScript's text item delimiters to {"-"}
     repeat with i from 1 to (count cardlist)
          set end of suitlist to text item 2 of item i of cardlist
          set item i of cardlist to (text item 1 of item i of cardlist) as integer -- convert string to integer
     end repeat
     quicksort(cardlist)
     set {card1, card2, card3, card4, card5} to cardlist
     set flush to 0
     set straight to 0
     set points to 0
     --check flush
     set char1 to item 1 of suitlist
     if char1 = item 2 of suitlist and char1 = item 3 of suitlist and char1 = item 4 of suitlist and char1 = item 5 of suitlist then
          set flush to 1
     end if
     --straight
     if (card5 - card4) = 1 and (card4 - card3) = 1 and (card3 - card2) = 1 and (card2 - card1) = 1 then
          set straight to 1
          --works now requires testing
     end if
     --royal flush
     if flush = 1 and straight = 1 and (card1 + card2 + card3 + card4 + card5) = 60 then
          (* card1 = 10 and card2 = 11 and card3 = 12 and card4 = 13 and card5 = 14 *)
          set royalflush to 1000
          set points to 1000
          --does not recognize
     else if flush = 1 and straight = 1 then
          -- straight flush
          set straightflush to 900
          set points to 900
     else if flush = 1 then
          --flush
          set points to 600
     else if straight = 1 then
          --straight
          set points to 500
     else if card1 = card2 and card1 = card3 and card1 = card4 or card2 = card3 and card3 = card4 and card4 = card5 then
          --four of a kind
          set fourofakind to 800
          set points to 800
     else if card1 = card2 and card3 = card4 and card3 = card5 or card1 = card2 and card1 = card3 and card4 = card5 then
          --fullhouse
          set fullhouse to 1
          set points to 700
     else if card1 = card2 and card1 = card3 or card2 = card3 and card3 = card4 or card3 = card4 and card3 = card5 then
          --three of a kind
          set threeofakind to 1
          set points to 400
     else if card1 = card2 and card3 = card4 or card1 = card2 and card4 = card5 or card2 = card3 and card4 = card5 then
          --two pair
          set twopair to 300
          set points to 300
     else if card1 = card2 or card2 = card3 or card3 = card4 or card4 = card5 then
          --pair
          set pair to 200
          set points to 200
     else
          --high card
          set highcard to 100
          set points to 100
     end if
     --ch
     (*royal flush=1000
    straight flush=900<=x<1000
    four of a kind=800<=x<900
    full house=700<=x<800
    flush=600<=x<700
    straight=500<=x<600
    three of a kind=400<=x<500
    two pair=300<=x<400
    one pair=200<=x<300
    high card=100<=x<200
     return points
end RANKER
on getcombo(asbak)
     set totalnocard to {1, 2, 1, 3, 1, 4, 1, 5, 1, 6, 1, 7, 2, 3, 2, 4, 2, 5, 2, 6, 2, 7, 3, 4, 3, 5, 3, 6, 3, 7, 4, 5, 4, 6, 4, 7, 5, 6, 5, 7, 6, 7}
     set finallist to {}
     set t to (count totalnocard)
     repeat with i from 1 to t by 2
          set finallist to finallist & getcardcombos({item i of totalnocard, item (i + 1) of totalnocard})
     end repeat
     return finallist
     -- count finallist is 105 dus klopt want 21*5
end getcombo
on getcardcombos(nocards)
     set finallist to {}
     repeat with i from 1 to 7
          set c to contents of i
          if c is not in nocards then set the end of finallist to c
     end repeat
     return finallist
end getcardcombos
You can take my handler on quicksort(theList) to put it in your script, or use my script.